Jeg savner noget i Excel-VBA

hvad med

Function MyAddToArray(UserNameData As Variant) As Variant
    Dim Uddata As String, I As Long

    For I = 1 To UBound(UserNameData, 1)  ' looper igennem mine data
        If UserNameData(I) = "dit" Or UserNameData(I) = "dat" Then
            Uddata = Uddata & UserNameData(I) & ","
        End If
    Next
   
    MyAddToArray = Split(Uddata, ",")
End Function

Hvad med string-variabel og split-funktion m.v.?

Den er god nok, folj, med din MyAddToArray - vil bare lige vise ændringer der opfylder flere krav

'()' i føste parameter skal smides væk - en variant kan indefolde et arrray og på den måde kan man gå fra empty til et array med første element - og:

variant er default, så 'as variant' som type angivelse er overflødig - og en variant kan også endeholde en strengværdi - dermed

Function MyAddToArray(MyArray, Addition)
...

Så er der det med at kalde med en variabel der intet indeholder endnu - sådan en variant er empty

Function MyAddToArray(MyArray, Addition)
  If IsEmpty(MyArray) Then MyArray = Array()
 
  'rest of lines
end function


Vi kan teste med:


Sub testit()
    Dim arr 'VIGTIGT ikke '()' bag
    arr = MyAddToArray(arr, "Kurt ")
    arr = MyAddToArray(arr, "korte ")
    arr = MyAddToArray(arr, "starkt")
    Debug.Print Join(arr, "")
End Sub

Men! du arbejder i dine vba liner med MyArray - der er ingen grund til at returnere den og efterfølgende tildele - den har allerede værdien! - dermed er function overkilled

Sub MyAddToArray(MyArray, Addition)

  Dim ArrayCount As Integer
  If IsEmpty(MyArray) Then MyArray = Array()
 
  ArrayCount = UBound(MyArray, 1)

  ReDim Preserve MyArray(ArrayCount + 1) ' tilføjer en ekstra plads i MyArray
  MyArray(ArrayCount + 1) = Addition ' smider værdi ind i den nu oprettede plads
End Sub

Som så skal anvendes således:

Sub testit()
    Dim arr
    MyAddToArray arr, #12/31/2015#
    MyAddToArray arr, " Kurt "
    MyAddToArray arr, "korte "
    MyAddToArray arr, 150
    Debug.Print Join(arr, "")
End Sub


Eller blot, sorry

Sub MyAddToArray(MyArray, Addition)
  If IsEmpty(MyArray) Then MyArray = Array() ' herefter er ubound(MyArray)=-1
  ReDim Preserve MyArray(UBound(MyArray) + 1)
  MyArray(UBound(MyArray)) = Addition
End Sub

Vi kan putte alle simple typer i array'et, men hvad med objekter?

Denne test giver fejl

Sub test2()
    Dim arr, dic As New Dictionary
    dic.Add "fornavn", "Kurt"
    MyAddToArray arr, dic
End Sub

Med mindre vi ændrer sidste linie - og dermed endligt får:

Sub MyAddToArray(MyArray, Addition)
  If IsEmpty(MyArray) Then MyArray = Array()
  ReDim Preserve MyArray(UBound(MyArray) + 1)
  If IsObject(Addition) Then Set MyArray(UBound(MyArray)) = Addition Else MyArray(UBound(MyArray)) = Addition
End Sub

Sub test3()
    Dim i, arr, dic As New Dictionary
    dic.Add "fornavn", "Kurt"
    dic.Add "efternavn", "Hansen"
   
    For Each i In Array(Null, 1, 1, 1.1, 1.1, #12/31/2015#, "Kurt", False, dic)
        MyAddToArray arr, i: Next

'https://msdn.microsoft.com/en-us/library/office/gg278470.aspx

    For Each i In arr
        Debug.Print TypeName(i), VarType(i): Next
    Debug.Print arr(UBound(arr)).Item("fornavn") & " " & _
                arr(UBound(arr)).Item("efternavn")
End Sub

Nu nåede jeg endligt til at få afprøvet Jeres forslag...

@supertekst:
Jeg forstår odt dit forsøg på at lave en kommasepareret tekststreng , og så udnytte funvctionen split(9) til at få det smidt ind i et array.Jeg kan bare i9kke få det til at spille.

Når jeg forsøger atfølge din tankegang, og analyserer koden, så ka jeg heller ikke se hvordan den skal håndtere hvis det er et allerede eksisterende array den skal tilføje en post til.


Jeg ved godt at du er helt oppe på status af guru, og det har du også vist overfor mig ved flere lejligheder.
Så jeg behøves vel ikke at spørge om du selv har testet funktionen?


bvirk:
Jeg kan ikke få dit forslag til at spille...

Rem Demo
Dim element As String, tabel As Variant
Private Sub Worksheet_Activate()
    element = ""
    tabel = ""

    tilføjElement "AAA"
    tilføjElement "BBB"
    tilføjElement "CCC"
    tilføjElement "DDD"
   
    tabel = Split(element, "|")

Rem Vis fra tabel (eksempel)
    MsgBox tabel(0) & tabel(UBound(tabel) - 1)
End Sub
Private Sub tilføjElement(tekst)
    element = element & tekst & "|"
End Sub

Hej igen
Jeg forstår ikke hvorfor det ikke virker hos dig  - at du ikke får et array retur !

Før 1. kald af MyAddToArray ligger eksekveringsmæssigt intet - med andre ord udtrykket: isempty(arr) har vædien true

synes lidt der er hugget i runer at arr, nu under navnet MyArray, herefter bliver til et array med:
If IsEmpty(MyArray) Then MyArray = Array()

Hvis du kan følge min ide, så prøv at  singlesteppe og chekke hvad der ikke lykkedes.

Du er vil ops på ikke at efterstille '()' hverken i dim eller parametertype erklæring. Du mikser vel ikke min kode med din egen, uden at være ops på forskelle?

Hvis du sætter et breakpoint på linien:
If IsEmpty(MyArray) Then MyArray = Array()

sætter markøren på linin med sub testit - trykker F5 - maker variabel navnet MyArray, som nu lyser gult, og trækker det til et værdikontroludtryk vindue (som du har puttet tilstede først hvis ikke det var der) -  så skal det fremgå at dens værdi er empty

Ved efterfølgende tastetryk F5 er værdien af MyArray: variant(0 to x) 

Det skal virke og er smart!

@supertekst:
Når jeg afvikler din procedure Worksheet_Activate(), så udskriver den i en msgbox "AAADDD".

Var det det du ville opnå?

Det var jo kun en demo med illustration af noget, der måske kunne hjælpe.