Dynamiske formler i andre felter

Indirekte er nok den funktion du søger.
https://support.office.com/da-dk/article/indirekte-funktionen-474b3a3a-8a26-4f44-b491-92b6306fa261

Hej Thor

Tak for dit svar. Det troede jeg også. Men umiddelbart kan indirekte kun henvise til en anden celle. Ikke løse en lidt mere kompleks formel.

Prøv at specificere lidt mere konkret hvad det er du har af data, og hvad det er du vil ende op med.
Det du har skrevet, er lidt kryptisk, og hænger ikke rigtig sammen!

Hej Ebea
Hvordan uploader jeg et eksempel?

I feltet A1 står formlen =B1&C1 som giver følgende teksstreng: "=SUM.HVISER(Q:Q;P:P;P1)"
Det er en tektsstreng, jeg gerne vil have løst, som den formel den er.
Hvordan gør jeg det?

Mere præcist kan jeg desværre ikke skrive det.

Det tror jeg nok vi har forstået - det vi nok ikke helt forstår er, hvorfor det er nødvendigt at sætte formlen sammen på den måde. Det kan være, at hvis man forstår hvorfor, så kan man finde en lidt anden måde at gøre det samme på.

Eksperten har desværre ikke en upload-funktion, så folk plejer at bruge Dropbox eller tilsvarende. Vær dog opmærksom på person og firma følsomme informationer i den fil du uploader.

Det er nødvendigt, fordi jeg har en sum.hviser med forskellige kriterier. Nogle er blanke i nogle tilfælde. Det er excel ikke glad for. Jeg har derfor stykket sum.hviser-formlen sammen i et hjælpe-ark og concattet dem  i en celle. Det er derfor dynamisk, hvad sum.hviser-formlen skal dække over.

#4  -  Som Thor Østergaard også nævner, så brug www.dropbox.com

Nå, stackoverflow havde en løsning. Den lægger jeg her:

Følgende VBA giver funktionen WM_EVAL(), hvor man lægger sin formel indeni.
Man bør dog være obs på, at formlen SKAL være på engelsk. Så SUM.IFS() i stedet for SUM.HVISER. Men ellers virker det.

''
' Evaluate Formula-Text in Excel
'
Function wm_Eval(myFormula As String, ParamArray variablesAndValues() As Variant) As Variant
    Dim i As Long

    '
    ' replace strings by values
    '
    For i = LBound(variablesAndValues) To UBound(variablesAndValues) Step 2
        myFormula = RegExpReplaceWord(myFormula, variablesAndValues(i), variablesAndValues(i + 1))
    Next

    '
    ' internationalisation
    '
    myFormula = Replace(myFormula, Application.ThousandsSeparator, "")
    myFormula = Replace(myFormula, Application.DecimalSeparator, ".")
    myFormula = Replace(myFormula, Application.International(xlListSeparator), ",")

    '
    ' return value
    '
    wm_Eval = Application.Evaluate(myFormula)
End Function


''
' Replace Whole Word
'
' Purpose  : replace [strFind] with [strReplace] in [strSource]
' Comment  : [strFind] can be plain text or a regexp pattern;
'            all occurences of [strFind] are replaced
Public Function RegExpReplaceWord(ByVal strSource As String, _
ByVal strFind As String, _
ByVal strReplace As String) As String

    ' early binding requires reference to Microsoft VBScript
    ' Regular Expressions:
    ' with late binding, no reference needed:
    Dim re As Object
    Set re = CreateObject("VBScript.RegExp")

    re.Global = True
    're.IgnoreCase = True ' <-- case insensitve
    re.Pattern = "\b" & strFind & "\b"
    RegExpReplaceWord = re.Replace(strSource, strReplace)
    Set re = Nothing
End Function