Macro Kode til Fjernelse af linjer med kriterier på at Dato

Vil du indtaste dato i en pop up, er den i en celle (hvilken?) eller skal den tage f.eks. dags dato?
Hvilken kolonne står din dato i?

Sub DeleteRowsPriorDates()
   
    Dim row As Long
   
    'Generer 100 rækker med dato
    'For row = 1 To 100
    '    Cells(row, 1).Value = Date - 10 + row
    'Next row
   
    'Slet historiske datoer
    For row = 100 To 1 Step -1
        If Cells(row, 1) < Date Then
            MsgBox (row)
            Cells(row, 1).EntireRow.Delete
        End If
    Next row

End Sub

Hej igen, i kan se på dette link (https://flic.kr/p/2mLif9s) hvad det er jeg prøver på. Ved tryk på "Knappen"; Opdatering af Lager, skal den bare fjerne den dato og antal bestilte. (Den skal hertil gøre det automatisk på at datoen under forventer leveringsdato er <(Mindre end) dags dato (Og nej jeg skal ikke bruge en celle hvori jeg skriver hvilken dato der er, den skal bare implicitte tage for dags dato)).

Hvis det er muligt må den også gerne kunne tilføje antal bestilt til lager oversigt før den sletter.

Okay, sådan havde jeg ikke helt forstået opgaven.
Så du vil altså ikke slette hele linjen, hvor datoen er overskredet, men kun indholdet i kolonnerne h og i?
Inden indholdet slettes, så skal kolonne h adderes til kolonne g.

Lad os antage at dit ark (faneblad) hedder ”Ark1” og at dine dele er i række 2-100. Du må selv justere dette i koden.
Husk at tage backup af filen inden du begynder at ændre på det.

Sub OpdaterLagerListe()

    Dim ws As Worksheet
    Dim Rækketæller As Long
    Dim Startrække As Long
    Dim Slutrække As Long
   
    Startrække = 2  'Indtast værdi
    Slutrække = 100 'Indtast værdi
    Set ws = Worksheets("Ark1")    'Indtast navn på faneblad
   
    For Rækketæller = Slutrække To Startrække Step -1
        If IsDate(Cells(Rækketæller, 9)) = True And Cells(Rækketæller, 9) < Date Then        'kolonne i = 9
            'MsgBox ("Dato er overskredet i række: " & Rækketæller)
            'Adderer først værdi fra kolonne h til kolonne g  'kolonne h = 8, kolonne g = 7
            Cells(Rækketæller, 7) = Cells(Rækketæller, 7) + Cells(Rækketæller, 8)
            'Sletter nu indhold i kolonne h og kolonne i    'kolonne h = 8, kolonne i = 9
            Cells(Rækketæller, 8) = ""
            Cells(Rækketæller, 9) = ""
        End If
    Next Rækketæller

End Sub

Mange tak!!! Den virker perfekt!