Avatar billede stoffer Nybegynder
02. februar 2000 - 12:23 Der er 6 kommentarer og
1 løsning

Excel spg.

Jeg har en excel kommando her

=100*((1+IA(F22:F142,0.02))^4-1)

det jeg ikke kan finde ud af er funktionen "IA"


------------------- her er lidt fra excels hjælp --------------

Eksempler

Antag, at du vil åbne en restaurant. Du skønner, at det vil koste kr 700.000 at starte forretningen og forventer at tjene følgende i de første fem år: kr 120.000, kr 150.000, kr 180.000, kr 210.000 og kr 260.000. B1:B6 indeholder følgende værdier: kr -700.000, kr 120.000, kr 150.000, kr 180.000, kr 210.000 og kr 260.000.

Sådan beregnes investeringens interne afkast efter fire år:

IA(B1:B5) er lig med -2,12 procent

Sådan beregnes det interne afkast efter fem år:

IA(B1:B6) er lig med 8,66 procent

For at beregne det interne afkast efter to år skal beregningen indeholde et gæt:

IA(B1:B3;-10%) er lig med -44,35 procent



-----------------------------------------------------------------------------


er der nogen kloge hoveder der kan lave en funktion i ASP der kan det samme som IA - Så vil du få mange point for en sådan :)




Avatar billede stoffer Nybegynder
02. februar 2000 - 16:31 #1
hmmm, der var ikke mange kloge hoveder her...
Avatar billede stoffer Nybegynder
02. februar 2000 - 16:32 #2
Hvis nogle har lyst til at svare er de velkomne
Avatar billede mjess Nybegynder
03. februar 2000 - 11:36 #3
Her er et bud.

<%

Dim values

'=====================================
'Funtion NV beregner nutidsværdien
'NV tager 2 argumenter:
'r: renten - 0.08 ~ 8%
'arr: array af indtaægter og udgifter,
'hvor arr[0] er indtægter-udgifter til
'start,.
'arr[1] er indtægter-udgifter efter 1.
'periode, arr[2] til 2. periode osv.
'=====================================
Function NV(r, arr)
  Dim temp, a
  temp = 0

  ' Nutidsværdien beregnes som summen af: post[n]/((1+rente)^n), hvor n er antallet af poster
  For a = 0 to UBound(arr)
    temp = temp + arr(a)/((1+r)^a)
  Next

  NV = temp
End Function

'=====================================
'Funtion IA beregner det interne afkast
'af en række pengestrømme med faste
'intervaller
'IA tager 2 argumenter:
'arr: array af indtaægter og udgifter,
'hvor arr[0] er indtægter-udgifter til
'start,.
'arr[1] er indtægter-udgifter efter 1.
'periode, arr[2] til 2. periode osv.
'guess: gæt på afkastet på decimaltals-
'form (0.1 ~ 10%)
'=====================================
Function IA(arr, guess)
  Dim r1, r2, dx, dy, a, b
  Dim lr, sr, lres, sres
  Dim t,tn,gn

  t = 0.00001            'Præcision på resultatet
  tn = 0.000000001        'Til brug ved beregning af tangenten
  gn = 0            'antal gæt
  r1 = guess            'Første gæt
  r2 = r1            'Husk gættet, så vi kan se forskellen

  lr = r1 - tn            'to variable til beregning af tangent
  sr = r1 + tn

  g = NV(r1, arr)        'resultat for første gæt

  lres = NV(lr, arr)        'to variable til beregning af tangent
  sres = NV(sr, arr)

  dx = sr - lr            'to variable til beregning af tangent
  dy = sres - lres

  a = dy/dx            'tangentens hældning

  b = g - (a*r1)        'tangentens skæring m. x-aksen

  r1 = -b/a            'næste gæt

'----så længe gættet afviger fra sidste gæt med mere end præcisionen
'----og så længe vi ikke har prøvet 20 gange
  Do While Abs(r1 - r2) > t AND gn < 20       
    r2 = r1            'Husk gættet, så vi kan se forskellen

    lr = r1 - tn        'to variable til beregning af tangent
    sr = r1 + tn

    g = NV(r1, arr)        'resultat for første gæt

    lres = NV(lr, arr)        'to variable til beregning af tangent
    sres = NV(sr, arr)

    dx = sr - lr        'to variable til beregning af tangent
    dy = sres - lres

    a = dy/dx            'tangentens hældning

    b = g - (a*r1)        'tangentens skæring m. x-aksen

    r1 = -b/a            'næste gæt

    gn = gn + 1            'opdater tæller
  Loop

  If gn < 20 Then
    IA = FormatPercent(r1,10,-1)    'r1 indeholder kommatallet, vi formaterer til procent m. 10 decimaler
  Else
    IA = ""
  End If

End Function

values = Array(-700000,120000,150000,180000,210000,260000)    'svarer til eksemplet i excel

%>
<html>
<head>
<title>IA</title>
</head>
<body>

<%=IA(values,0.1)%>

</body>
</html>
Avatar billede stoffer Nybegynder
03. februar 2000 - 15:14 #4
Wow!

Super duper...... (bøjer sig i respekt :) )


Jeg skal lige have lidt tid til at tjekke det igennem, hvis det virker får du 200 point .....
Avatar billede stoffer Nybegynder
03. februar 2000 - 15:15 #5
Hvilket firma arbejder du for?
Avatar billede stoffer Nybegynder
03. februar 2000 - 15:21 #6
email mig på munck@mondo.dk
Avatar billede stoffer Nybegynder
13. april 2000 - 14:18 #7
Hej mjess, jeg håber du har tid til at hjælpe igen :)

se: http://www.eksperten.dk/spm.asp?id=15118
Avatar billede Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Loading billede Opret Preview
Kategori
Kurser inden for grundlæggende programmering

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester