Så vil jeg prøve at forklare det (med kode):
Først den oprindelige html-form
Filnavn: 2-1.htm
-----------------------8<-------------------
<html>
<head>
<title>JPS2MT.DK - HTML-form til ASP-kurset</title>
</head>
<body bgcolor="#ffffff" text="#000000">
<form action="2-1.asp" method="post">
Navn: <input type="text" name="navn"><br>
Alder: <input type="text" name="alder"><br><br>
<input type="submit" name="B1" value="Send">
</body>
</html>
Så den omskrevne ASP-del, der gemmer navn-alder parrene i en textfil:
Filnavn: 2-1.asp
-----------------------8<-------------------
<%
Navn = Request.Form("navn")
Alder = Request.Form("alder")
sti_til_textfil = Server.MapPath("navnalder.txt") 'Få den fysiske sti til text-filen
Set fso = Server.CreateObject("Scripting.FileSystemObject") 'Objekt til at få adgang til filsystemet
'Åben text-filen (8 = 'for appending') (True = Opret filen, hvis den ikke findes i forvejen)
Set ts = fso.OpenTextFile(sti_til_textfil, 8, True)
ts.WriteLine(Navn & ";" & Alder) 'Skriv linje med "navn;alder" til text-filen
ts.Close 'Luk text-filen
Set ts = Nothing 'Nulstil referencer til Objekter
Set fso = Nothing
Response.Redirect("2-1.htm") 'Gå tilbage til start
%>
Dernæst en ekstra asp-fil, der viser indholdet af tekstfilen:
Filnavn: 2-1vis.asp
-----------------------8<-------------------
<%
sti_til_textfil = Server.MapPath("navnalder.txt") 'Få den fysiske sti til text-filen
Set fso = Server.CreateObject("Scripting.FileSystemObject") 'Objekt til at få adgang til filsystemet
If fso.FileExists(sti_til_textfil) Then 'Hvis der er skrevet i filen
'Åben text-filen for læsning (1) (False = opret ikke filen hvis den ikke findes)
Set ts = fso.OpenTextFile(sti_til_textfil, 1, False)
While Not ts.AtEndOfStream 'Så længe der er mere i tekstfilen
text = ts.ReadLine() 'Læs linje med "navn;alder"
navn_og_alder = Split(text,";") 'Adskil navn og alder (split returnerer et array)
navn = navn_og_alder(0) 'Læs navn fra array
alder = navn_og_alder(1) 'Læs alder fra array
'Udskriv teksten fra tidligere 2-1.asp for hver linje i tekst-filen
Response.Write("Du hedder " & navn & " og du er " & alder(1) & "<br>" & vbCrLf)
Wend 'Afslut While løkken
ts.Close 'Luk text-filen
Set ts = Nothing 'Nulstil reference til Objekt
End If
Set fso = Nothing 'Nulstil reference til Objekt
%>
For en ordens skyld må vi hellere lige liste referencerne:
_Indbyggede OBJEKTER_
Server (MapPath) ->
http://www.activeserverpages.dk/iishelp/iis/htm/asp/intr7838.htm (CreateObject)
Response (Redirect) ->
http://www.activeserverpages.dk/iishelp/iis/htm/asp/intr5sj8.htm_OBJEKTER_
FileSystemObject ->
http://www.activeserverpages.dk/iishelp/vbscript/htm/vsobjFileSystem.htmTextStream ->
http://www.activeserverpages.dk/iishelp/vbscript/htm/vsobjTextStream.htm_FUNKTIONER_
Split ->
http://www.activeserverpages.dk/iishelp/vbscript/htm/vsfctSplit.htm_STATEMENTS_
While - Wend ->
http://www.activeserverpages.dk/iishelp/vbscript/htm/vsstmWhile.htmHåber det giver lidt mening
/mjess