Fade op og fade ud.

Hej Esben,
Skal din \"produkt\".sprite starte med at være usynlig og så fade-in når knappen har fade-out ?

Ja!
Scriptet er tiltænkt en knap som jeg kalder \"proces\". Knappen \"Produkt\" skal faktisk kunne det samme.

Ok så skal der 2 behaviors til. Jeg laver og sender en lille demo så du kan se hvordan det sættes sammen men scriptet skriver jeg her da det sikkert også kan bruges af andre.
mvh geo

--------------denne produkSpriteBehavior styres af knap behavior ------------
--produktSprite og knapSprite skal overlappe hinanden i score
--produktSprite spritespan bør starte mindst 1 frame før knapSprite da den initialiserer den globale variabel --\"produktSprite\"

property mySprite, myTargetBlend,turnedOn
global produktSprite

on beginSprite me
  mySprite = me.spriteNum
  produktSprite = me
  myTargetBlend = 0
  sprite(mySprite).blend = 0  --produktSprite er usynlig i starten
  turnedOn = void
end

on setTargetBlend me, targetBlend
  myTargetBlend = targetBlend
end


on exitFrame me
 
  if myTargetBlend <> integer(sprite(mySprite).blend) then
    fade me
  else
    nothing
  end if
 
end


on fade me
 
  if myTargetBlend > sprite(mySprite).blend then
    change = 1
  else
    change = -1
  end if
  sprite(mySprite).blend = integer(sprite(mySprite).blend + change)
 
  --check on/off status
  if integer(sprite(mySprite).blend) = 100 then
    turnedOn = true
   
  end if
 
 
  if integer(sprite(mySprite).blend) = 0 then
    turnedOn = false
   
  end if
 
end
------------------produktSpriteBehavior slutter her

Den næste behavior er til selve knappen som fader fra 30% til 100% ved rollover og så fader ud efter 2 sek samtidigt med at produktSprite fader ind fra 0% til 30%

--------------knap behavior som styrer en produkt sprite------------

property mySprite, myTargetBlend,myShowTime, myTurnOffTime,turnedOn
global produktSprite

on beginSprite me
 
  mySprite = me.spriteNum
  myTargetBlend = 30 --knappen er 30% synlig til at starte med
  myShowTime = 2 * 60  -- vis i 2 sekunder når den er 100 % synlig før den fader ud igen
  sprite(mySprite).blend = 30
  turnedOn = void
 
end



on exitFrame me
 
  if myTargetBlend <> integer(sprite(mySprite).blend) then
    fade me
  else
    --check if myTurnOffTime has been reached
    if (the timer > myTurnOffTime) and (myTargetBlend = 100) then
      myTargetBlend = 0
      --start produktSprite fade
      setTargetBlend produktSprite,30
      turnedOn = void
    end if
   
  end if
 
end



on mouseEnter me
  myTargetBlend = 100
end



on fade me
 
  if myTargetBlend > sprite(mySprite).blend then
    change = 1
  else
    change = -1
  end if
  sprite(mySprite).blend = integer(sprite(mySprite).blend + change)
 
  --check on/off status
  if integer(sprite(mySprite).blend) = 100 then
    turnedOn = true
    myTurnOffTime = the timer + myShowtime
  end if
 
 
  if integer(sprite(mySprite).blend) = 0 then
    turnedOn = false
    myTurnOffTime = void
  end if
 
end

-----------------knapSpriteBehavior slutter her-------------------------------------

Har sendt en demo fil til dig, og håber at det kan bruges :o)
mvh geo

Mange tak. Jeg kommer først til en computer med Dir i aften eller i morgen. Så kigger jeg lige på det. :)

Tak for point :)