Avatar billede krogstrup Nybegynder
24. marts 2000 - 12:53 Der er 7 kommentarer og
1 løsning

Vil SELV lave indkøbskurv !!!

Jeg skal igang med at lave en indkøbskurv i asp. Varerne ligger i en Access database og jeg gider IKKE at bruge et eller andet færdiglavet e-commerce system fra et eller andet ligegyldigt ASP-website !!!

Jeg er nået til følgende problematik:

Ved tryk på knappen "KØB" skal der gemmes informationer om varens ID, således at de rigtige varer kan vises på bestillingssedlen. Jeg havde forestillet mig at jeg ville gemme vareID i en SessionVariabel der så skulle være et dictionary.

1) Kan dette lade sig gøre ?

2) Hvordan opretter jeg en SessionVariabel der er et dictionary ?

3) Hvordan gemmer jeg f.eks. vareID i denne SessionVariabel ?

4) Hvordan læser jeg senere de vareID´er jeg har puttet ind i min variabel ?

5) Hvordan sletter jeg vareID´er fra et dictionary ?

Det var vist alt. Jeg håber meget at nogle af jer ASP-ekspterter derude kan hjælpe mig igang !!!

Mvh

David Krogstrup
Avatar billede plinnet Nybegynder
24. marts 2000 - 13:29 #1
Hej David
Her er lige et lille eksempel, meget simpelt

Indkøbskurven.asp :

Sub AddItemToCart(iItemId, iItemCount)    
  if shopcart.Exists (iItemId) then
        shopcart(iItemId) = shopcart(iItemId) + iItemCount
  else
        shopcart.Add iItemId,iItemCount
  end if       
End Sub

Sub RemoveItemFromCart(iItemID)
    If shopcart.Exists(iItemID) Then
        If shopcart(iItemID) <= iItemCount Then
            shopcart.Remove iItemID
        Else
            shopcart(iItemID) = shopcart(iItemID) - iItemCount
        End If
    Else
        Response.Write "Couldn't find any of that item your cart.<BR><BR>" & vbCrLf
    End If
End Sub

Sub RemoveAllFromCart
    For each Key in shopcart
    shopcart.RemoveAll
    Next
End Sub

Sub ShowItemsInCart()
Dim Key
Dim aParameters ' as Variant (Array)
Dim sTotal
   
    sTotal = 0
   
    For Each Key in shopcart
        aParameters = GetItemParameters(Key)
       
        Response.write"<TR vAlign=top>"
        Response.write"<TD ALIGN=left><font size=1 face='Verdana, Arial, Helvetica, sans-serif'>"& Key &"</font></TD>"
        Response.write"<TD ALIGN=Center><font size=1 face='Verdana, Arial, Helvetica, sans-serif'>"&aParameters(1)&"</font></TD>"
        Response.write"<TD ALIGN=Center><font size=1 face='Verdana, Arial, Helvetica, sans-serif'>"&shopcart(Key)&"</font></TD>"
        Response.write"<TD ALIGN=Left><font size=1 face='Verdana, Arial, Helvetica, sans-serif'>"& FormatNumber((shopcart(Key) * CDbl(aParameters(2)))) &"</font></TD>"
        Response.write"<TD ALIGN=Lef><font size=1 face='Verdana, Arial, Helvetica, sans-serif' color='#990000'><a target =hojre href= '../Indkobskurven.asp?action=del&item=" & Key & "&count=1' style='COLOR: #663399'>Slet</a></font>"

        Response.write"</TR>"
       
        sTotal = sTotal + (shopcart(Key) * CDbl(aParameters(2)))
    Next
   
        Response.write"<table width=213 border=0 rules=none height=55 style='HEIGHT: 55px; WIDTH: 213px'>"
        Response.write"<TR>"
        Response.write"<td align=left><font face='Verdana, Arial, Helvetica, sans-serif' size=1><STRONG>Total: </STRONG></font>"
        Response.write"<TD align=Right><font face='Verdana, Arial, Helvetica, sans-serif' size=1>"
        Response.write"<INPUT id=Total name=Total style='HEIGHT: 22px; WIDTH: 139px align: Right' readOnly value="& FormatNumber(sTotal,2)&"> "
        Response.write"</font></TD></td>"
        Response.write"</TR>"
        Response.write"</table>"
   
End Sub



Function GetItemParameters(iItemId)
Dim aParameters
' Obs her er data læst ind manuelt!

    Select case iItemId
    case 2269
    aParameters = Array("2269", "Plade", "129,00")
    case 2240
    aParameters = Array("2240", "CD", "159,00")
    end select

' Return array containing product info.
GetItemParameters = aParameters
End Function

Function GetItemParameters1(iItemId)
Dim aParameters
'Her hentes fra databasen

Dim conn, query, mRS

Set conn = Server.CreateObject("ADODB.Connection")
conn.Open "FILEDSN=demo.DSN"

set mRS=Server.CreateObject("ADODB.Recordset")

query = "SELECT nummer, salgspris, beskrivelse FROM dbo.[Demo Recat$MENU] where nummer = " &"'"  & iItemId &"'"
mRS.Open query, conn, adOpenStatic

aParameters = Array(CStr(mRS("nummer")), CStr(mRS("beskrivelse")), CDbl(mRS("pris")))

' Return array containing product info.
GetItemParameters1 = aParameters

mRS.Close
set mRS = nothing

conn.Close
set conn = nothing

End Function
%>

<HTML>
<head>

<title>Indkobskurven</title>

<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
<meta name="hojre">
</head>

<body bgcolor="#ffffff" background="file://C:\IndkKurve\bigcart2.gif">
<FORM action="AfgivOrdre.asp" method="post" id = ordre name=ordre target = "_parent">

<table height=278 width=205 style="HEIGHT: 278px; WIDTH: 205px"  >
  <TR>
    <td align="left" vAlign=top><font face="Verdana, Arial, Helvetica, sans-serif" size="1"><STRONG>Best.nr.</STRONG></font></td>
    <td align="left" vAlign=top><font face="Verdana, Arial, Helvetica, sans-serif" size="1"><STRONG>Vare</STRONG></font></td>
    <td align="left" vAlign=top><font face="Verdana, Arial, Helvetica, sans-serif" size="1"><STRONG>Antal</STRONG></font></td>
    <td align="left" vAlign=top><font face="Verdana, Arial, Helvetica, sans-serif" size="1"><STRONG>Pris</STRONG></font></td>
  </TR>

  <TR>
    <TD align="left"><font face="Verdana, Arial, Helvetica, sans-serif" size="1"></font></TD>
  </TR>
    <%

Dim total
Dim shopcart
Dim sAction
Dim iItemId
Dim iItemCount

if IsObject(Session("cart")) then
  set shopcart = Session("cart")
else
  set shopcart = Server.CreateObject("Scripting.Dictionary")
end if

sAction = CStr(Request.QueryString("action"))
iItemId = CStr(Request.QueryString("item"))
iItemCount = CInt(Request.QueryString("count"))

' Select action based on user input
Select Case sAction
    Case "add"
        AddItemToCart iItemId, iItemCount
        ShowItemsInCart
       
    'Case "add1"
    '    AddItemToCart iItemId, iItemCount
    '    ShowItemsInCart1
       
    Case "del"
        RemoveItemFromCart iItemID
        ShowItemsInCart
       
    Case "delAll"
        RemoveAllFromCart
        ShowItemsInCart
       
    Case Else
End Select

' Return cart to Session for storage
Set Session("cart") = shopcart

%></table>

<table height=47 width=200>
  <TR>
    <td width = 100 align=left><font size=2 face="Verdana, Arial, Helvetica, sans-serif">
    <a target =hojre href= "../Indkobskurven.asp?action=delAll" style="COLOR: #663399">Slet alt</a></font></td>
    <td width = 100 align=right><font size=2 face="Verdana, Arial, Helvetica, sans-serif">
    <a target ="hovedside" href= "../AfgivOrdre.asp?" style="COLOR: #663399">Bestil</a></font></td>
  </TR>
</table>

</FORM></TABLE>
</body>
</HTML>
Kaldes fra vareformen således:

<a target ="hojre" href= "../Indkobskurven.asp?action=add&item=2269&count=1"><img src="billeder/kurv.gif" width="19" height="16" border=0 alt=""></a>

Hilsen Pia
Avatar billede krogstrup Nybegynder
24. marts 2000 - 13:59 #2
Er der ikke nogen derude som rent faktisk har LÆST mit spørgsmål, som vil svare ?
Avatar billede plinnet Nybegynder
24. marts 2000 - 14:06 #3
1) Ja

2)
  set shopcart = Server.CreateObject("Scripting.Dictionary")

3)shopcart.Add iItemId,iItemCount

4)Se metoden ShowItem...

5)shopcart.Remove iItemID


Læs dog koden mand!
, alle de nødvendige metoder er incl.

Pia
Avatar billede knogle Nybegynder
24. marts 2000 - 14:13 #4
Hej David.

Jeg ville gerne ha' hjulpet, men plinnet har allerede svaret :)
Avatar billede krogstrup Nybegynder
24. marts 2000 - 14:17 #5
Tak Pia - det var mere et svar i den retning jeg søgte.

Hvilken funktion har variablen iItemCount ??? Har det noget at gøre med hvor mange gange den pågældende vare er bestilt ???

/David
Avatar billede plinnet Nybegynder
24. marts 2000 - 14:20 #6
Ja, antal stk. Da det ikke er muligt at lægge samme key, eks bestnr. i et array flere gange. Count kan eks lægge 1 i ad gangen, eller kan sættes til andet end 1

Ok?
Avatar billede krogstrup Nybegynder
24. marts 2000 - 15:31 #7
Hej Pia

TUSIND tak for hjælpen og så beklager jeg mit "sure opstød", men dit svar virkede ikke lige umiddelbart så enkelt at gennemskue. Jeg har fundet ud af logikken i dictionary funktionen nu. Endnu en gang tak for hjælpen - hav en god weekend :-)

Mvh

David Krogstrup
Avatar billede plinnet Nybegynder
24. marts 2000 - 15:41 #8
Hej David

Selv tak - og i lige måde

Pia
Avatar billede Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Loading billede Opret Preview
Kategori
Kurser inden for grundlæggende programmering

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester