Avatar billede humlebien Novice
18. april 2000 - 09:16 Der er 13 kommentarer og
1 løsning

Et mærkeligt problem ........

Jeg har oprettet nogle filer "online" ved hjælp af filsystemobjektet, men når man kalder asp-filerne bliver der kun vist en tom browser. Kigger man så på kildekoden via browseren kan man se asp-koderne.... 8o(
Hvad er der galt???????????
Hvis du har en rigtig god løsning smider jeg gerne flere point i din retning.
Avatar billede fumes Nybegynder
18. april 2000 - 09:26 #1
Det er ikke fordi du har glemt <% vel ??
Avatar billede fumes Nybegynder
18. april 2000 - 09:26 #2
Kan man få lov at se eksemplet?
Avatar billede sone Nybegynder
18. april 2000 - 09:27 #3
Har du en adresse hvor vi må kigge?
Avatar billede morpheus Nybegynder
18. april 2000 - 09:44 #4
Eller udskriv venligst "HTML"'en her...

<//morpheus\\>
Avatar billede humlebien Novice
18. april 2000 - 09:47 #5
Her angives filplacering:
--------------------------------
<html>
<head>
  <title>Opret nye poster</title>
</head>

<body>
<center>
  <h2>Opret poster i DB</h2>
  <hr width="200">
 
  <%
    tekst_id = request.form("tekst_id")
    antal = request.form("antal")
    niveau = request.form("niveau")
       
    Set Conn = Server.CreateObject("ADODB.Connection") 
    Conn.Open(Application("xxxxxx"))
    Set rs = Server.CreateObject("ADODB.Recordset") 
    SQL = "SELECT * FROM tekst WHERE tekst_id='" & tekst_id & "';"
    rs.open SQL, Conn, 1, 3, 1
   
    if not rs.eof then
      tabel = Split(tekst_id, ".", -1, 1)
      start = 1+cint(tabel(niveau))
      slut = cint(antal)
     
      '************************************************
      '  opretter strengen før det inkrementerede tal
      '************************************************
      for i = 0 to (niveau-1)
        x = x & tabel(i) & "."
      next
     
      '**************************************************
      '  opretter strengen efter det inkrementerede tal
      '**************************************************
      for i = niveau+1 to 7
        y = y & "." & tabel(i)
      next
     
      '*********************************************
      '  opretter form på siden og udfylder felter
      '*********************************************
      response.write "<form name=opretform method=post action=opretpostcommit2.asp>" & chr(10)
      response.write "<table>" & chr(10)
      submit = false
      j = 1
      i = 1
      while j <= slut
        tekstid = x & i & y
        rs.close
        SQL = "SELECT * FROM tekst WHERE tekst_id='" & tekstid & "';"
        rs.open SQL, Conn, 1, 3, 1
        if rs.eof then
          response.write "<tr><td><input type=hidden name=id value=" & tekstid & ">"
          response.write tekstid & "</td><td><input name=fil type=text size=30 value=" & request.form("sti") & ">.asp</td></tr>" & chr(10)
          j = j+1
          submit = true
        end if
        i = i+1
      wend
      response.write "</table>" & chr(10)
      if submit then
        response.write "<input type=submit value='Opret siderne nu'>" & chr(10)
      end if
      response.write "<input type=hidden name=ejer value=" & request.form("ejer") & ">"
      response.write "<input type=hidden name=sprog value=" & request.form("sprog") & ">"
      response.write "<input type=hidden name=beskrivelse value='" & request.form("beskrivelse") & "'>"
      response.write "<input type=hidden name=titel value=" & request.form("titel") & ">"
      response.write "</form>"
    else
      response.write "Den angivede tekst_id : " & tekst_id & " findes ikke i DB............ bedre held næste gang ;-)"
      rs.close
    end if
  %>
     

</center>
</body>
</html>
Avatar billede humlebien Novice
18. april 2000 - 09:48 #6
Her sammensættes filen
---------------------------
<%
  Set Conn = Server.CreateObject("ADODB.Connection") 
  Conn.Open(Application("xxxxxxx"))
  Set rs = Server.CreateObject("ADODB.Recordset") 
 
  filArray = Split(request.form("fil"), ",", -1, 1)
  filSize = Ubound(filArray)
 
  idArray = Split(request.form("id"), ",", -1, 1)
  idSize = Ubound(idArray)
 
  if filSize = idSize then
    set objFilObject = CreateObject("Scripting.FileSystemObject")
    for i = 0 to filSize
      '*******************
      '  opretter ny fil
      '*******************
      filnavn = "h:\wwwroots\ehs\online-edit\" & ltrim(filArray(i)) & ".asp"
      if not objFilObject.FileExists(filnavn) then
        objFilObject.CreateTextFile filnavn, false, true
      else
        response.write filnavn & " findes allerede"
      end if
     
      '**********************************
      '  fylder skabelonen over i filen
      '**********************************
      if objFilObject.FileExists(filnavn) then
        set objSkabelon = objFilObject.GetFile("H:\wwwroots\ehs\online-edit\include\skabelon.txt")
        set  textStream = objSkabelon.OpenAsTextStream(1, -2)
        set objSkrivFil = objFilObject.OpenTextFile(filnavn, 8, true, -2)
        j = 1
        while textStream.AtEndOfStream <> true
          linie = textStream.readline
          if j = 14 then
            linie = "tekst_id = """ & ltrim(idArray(i)) & """"
          end if
          if j = 50 then
            linie = "<!-- #include file=""" & "../../include/menu_udd-international.inc""" & "-->"
          end if
          objSkrivFil.write linie
          objSkrivFil.writeblanklines 1
          j = j + 1
        wend
        objSkrivFil.close
        response.write "<b>" & filnavn & "</b> er oprettet<br>"
      else
        response.write "Der er noget galt med " & filnavn & "!!!!"
      end if
     
     
      '*************************
      '  opretter en post i DB
      '*************************
      SQL = "SELECT * FROM tekst WHERE tekst_id='" & ltrim(idArray(i)) & "';"
      rs.open SQL, Conn, 1, 3, 1
      if rs.eof then
        rs.AddNew
        rs("tekst_id") = ltrim(idArray(i))
        rs("sprog") = request.form("sprog")
        rs("ejer") = request.form("ejer")
        rs("tekst") = request.form("beskrivelse")
        rs("titel") = request.form("titel")
        rs.update
        rs.close
        SQL = "SELECT side_id FROM tekst WHERE tekst_id='" & ltrim(idArray(i)) & "';"
        rs.open SQL, Conn, 1, 3, 1
        side = rs("side_id")
        rs.close
        SQL = "SELECT * FROM historik;"
        rs.open SQL, Conn, 1, 3, 1
        rs.AddNew
        rs("side_id") = side
        rs("bruger_id") = "IT Center"
        rs("tidsstempel") = FormatDateTime(now)
        rs.update
        response.write "Post med tekst_id: <b>" & ltrim(idArray(i)) & "</b> er oprettet i DB<p>"
      end if
      rs.close
    next
  end if
%>
Avatar billede humlebien Novice
18. april 2000 - 09:51 #7
Her er en "online-skabt" fil
----------------------------------
<!--#include virtual="/lib/auth.inc"-->

<%
  if authenticateUser(user, NTLM, "Net.dk", 0, false) then
    user = lcase(userName(user))
  end if

  Set AU = Server.CreateObject("Persits.AspUser")
  Set Group = AU.GetGroup("webmastergruppe")
  if Not Group.Users(user) Is Nothing Then
    webmaster = true
  end if
       
tekst_id = "9.9.1.9.9.9.9.9"
  url = "http://webtest" + Request.ServerVariables("Path_info")
 
  Set Conn = Server.CreateObject("ADODB.Connection") 
  Conn.Open(Application("xxxxxxx"))
 
  Set rs = Server.CreateObject("ADODB.Recordset") 
  SQL = "SELECT * FROM tekst where tekst_id='" & tekst_id & "';"
  rs.open SQL, Conn, 1, 3, 1
%>

<html>
 
<head>
  <title><%= rs("titel") %></title>
</head>

<!-- #include file="../../include/topmenu.inc" -->

<table border="0" cellspacing="0">
  <tr>
    <td width="230" valign="top">
      <!-- #include file="../../include/menu_kur.inc" -->   
    </td>
    <td width="*%" valign="top">
      <table border="0" cellspacing="0">
        <tr>
          <td>
            <!-- #include file="../../include/webmastercheck.inc" --> 
            <%= rs("tekst") %>
            <!-- #include file="../../include/footer.inc" -->
          </td>
        </tr>
      </table>
    </td>
  </tr>
<!-- #include file="../../include/menu_udd-international.inc"-->
</body>
</html>
Avatar billede knogle Nybegynder
18. april 2000 - 09:58 #8
Måske kan din server ikke køre ASP ?
Avatar billede humlebien Novice
18. april 2000 - 10:00 #9
Knogle >> Jeg kører en NT server med IIS 4.0. De to første filer, der er vist her er asp, så mon ikke også den kan klarer andre asp-filer ;o)
Avatar billede knogle Nybegynder
18. april 2000 - 10:22 #10
oki ;) - sorry :)
Avatar billede sone Nybegynder
18. april 2000 - 10:26 #11
Hvad sker der hvis du henter den genererede fil ind i din editor og gemmer som normalt - kan du så afvikle ASP-filen?
Avatar billede humlebien Novice
18. april 2000 - 10:48 #12
sone >> når jeg henter filen ind i min editor er der nogle mærkelige tegn imellem og der er mellemrum mellem alle tegn. Men hvis jeg åbner filen i notepad, ser det fint ud. Hvis så jeg kopiere koden fra notepad over i editoren og gemmer det, så virker det fint........
Avatar billede sone Nybegynder
18. april 2000 - 15:23 #13
humlebien> Prøv at sende en kopi af den genererede fil til mig (psp@mindpass.com)
Avatar billede sone Nybegynder
19. april 2000 - 11:19 #14
Fejl: Dine filhåndtering er enten default eller direkte valg af unicode - du skal vælge ASCII som filformat.
Avatar billede Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Loading billede Opret Preview
Kategori
Kurser inden for grundlæggende programmering

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester