Avatar billede quak.dk Nybegynder
23. maj 2000 - 16:50 Der er 21 kommentarer og
1 løsning

Menu

Hej jeg skal bruge en menu, som bliver lavet ud fra et DB udtræk...

Det skal være en menu som på http://www.intervarer.dk/

Db som det skal trækkes ud fra ligger på http://www.fuglevig.dk/x-web/db.mdb

Det skal tages fra den tabel der hedder kats...

Hvis der er nogen der kunne lave den komplete løsning kunne det være kanont..


Hvis der er nogen sprøgsmål mail på webmaster@quak.dk eller skriv dem her i dette spørgsmål
Avatar billede tomsommer Juniormester
23. maj 2000 - 18:05 #1
beeep beeep
Avatar billede isdan Nybegynder
23. maj 2000 - 18:20 #2
http://www.intervarer.dk/

Hvor er menuet?
Avatar billede tomsommer Juniormester
23. maj 2000 - 18:57 #3
Jeg kan kun se en scannet.dk side
Avatar billede morpheus Nybegynder
23. maj 2000 - 19:15 #4
Der er da masser at se på den side...
Avatar billede tomsommer Juniormester
23. maj 2000 - 19:19 #5
mærkeligt jeg ikke kan se den :|
Avatar billede sone Nybegynder
23. maj 2000 - 19:24 #6
Der er åbenbart usikkerhed... jeg ser følgende: http://www.sone.dk/intervarer.gif
Avatar billede tomsommer Juniormester
23. maj 2000 - 19:52 #7
Samme her
Avatar billede morpheus Nybegynder
23. maj 2000 - 19:58 #8
Dette er hvad jeg ser:
http://www.d-net.dk/intervare.gif

<//morpheus\\>
Avatar billede tomsommer Juniormester
23. maj 2000 - 20:04 #9
mærkeligt
Avatar billede philiph Nybegynder
23. maj 2000 - 20:47 #10
Ligesom alle de andre har jeg ikke kunnet se hvilken menu du snakker om.

Men anyway, her er et skud:

Læg følgende ASP kode i en asp fil ved siden af databasen.
Du skal også have filen adovbs.inc i samme bibliotek (følger med Microsofts Data Acces components: MDAC_TYP.exe).

<% Option Explicit %>
<!--#include file="adovbs.inc"-->
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<html>
<head>
  <title>Menu</title>
</head>
<body>
<table>
<%
  Const strSQL = "SELECT ID, Kat FROM Kats ORDER BY Kat"
  Dim cn
  Dim rs
 
  Set cn = Server.CreateObject("ADODB.Connection")
  cn.Provider = "Microsoft.Jet.OLEDB.4.0"
  cn.Properties("data source") = Server.Mappath("db.mdb")
  cn.Open
 
  Set rs = Server.CreateObject("ADODB.Recordset")
  rs.CursorLocation = adUseServer
  rs.Open strSQL, cn, adOpenForwardOnly, adLockReadOnly
 
  Do Until rs.EOF
    Response.Write "<tr><td>"
    Response.Write "<a href=""link.asp?ID=" & rs("ID") & """>" & rs("Kat") & "</a>"
    Response.Write "</td></tr>"
    rs.MoveNext
  Loop
 
  rs.close
  Set rs = Nothing
  cn.Close
  Set cn = Nothing
%>
</table>
</body>
</html>

Det burde i hvert fald kunne bruges som udgangspunkt for vidre udvikling.

Philip
Avatar billede quak.dk Nybegynder
23. maj 2000 - 22:35 #11
Hej philiph.. Ja okay, men med det der linker du kun videre.. Der skal også være submenu's

Så det fx bliver
Drikkevarer
- Cola
- Vand
- Juice
- Vin
  - Hvidvin
  - Rødvin

OSV OSV

Der er max 3 menu'er ud...

Kan du klare den...Hvis du kan til imorgen kl. 15:00 er der 400 points i hus..

Og selvfølgelig også andre hvis de kan
Avatar billede quak.dk Nybegynder
23. maj 2000 - 22:36 #12
Ups glemte at skrive noget
Menu'en drikke vare skal først åbne sig når der bliver trykke på den, og det gælder også for de andre kats
Avatar billede philiph Nybegynder
24. maj 2000 - 01:13 #13
Så skulle den være i vinkel. Lad mig dog straks sige at den metode jeg startede med, og derfor er fortsat men ikke er optimal. Hver gang du klikker på et menupunkt, er den ude og vende på serveren. Det kan laves så hele menuen hentes på engang ved brug af <div... og noget java script, men det er jeg ikke så stiv i... endnu.

Du skal lige lave et par giffer for at det ser pænt ud: plus.gif, minus.gif og item.gif (så det kommer til at ligne stifinderen).

<% Option Explicit %>
<!--#include file="adovbs.inc"-->
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<html>
<head>
  <title>Menu</title>
</head>
<body>
<table>
<%
Const strSQLMenu1 = "SELECT ID, Kat FROM Kats WHERE KatID "
Const strSQLMenu2 = " ORDER BY Kat"

Dim cn

Set cn = Server.CreateObject("ADODB.Connection")
cn.Provider = "Microsoft.Jet.OLEDB.4.0"
cn.Properties("data source") = Server.Mappath("db.mdb")
cn.Open

Response.Write MakeMenu(Null,0,False)

cn.Close
Set cn = Nothing

Function MakeMenu(ParentID,Level,FoundID)
  Dim rs
  Dim strSQL
  Dim Menu
  Dim SubMenu
  Dim SubFoundID
  Dim i
 
  Menu = ""
  If IsNull(ParentID) Then
    strSQL = strSQLMenu1 & "Is Null" & strSQLMenu2
  Else
    strSQL = strSQLMenu1 & "=""" & ParentID & """" & strSQLMenu2
  End If
 
  Set rs = Server.CreateObject("ADODB.Recordset")
  rs.CursorLocation = adUseServer
  rs.Open strSQL, cn, adOpenForwardOnly, adLockReadOnly
 
  Do Until rs.EOF
    SubFoundID = False
    SubMenu = MakeMenu(rs("ID").Value,Level+1,SubFoundID)

    Menu = Menu & "<tr><td>"
    For i = 1 To Level
      Menu = Menu & "&nbsp;&nbsp;"
    Next
   
    If SubMenu = "" Then
      Menu = Menu & "<img src=""item.gif"" border=0>&nbsp;<a href=""link.asp?ID=" & rs("ID") & """>" & rs("Kat") & "</a></td></tr>"
    Else
      If Request.QueryString("ID") = rs("ID") Or SubFoundID Then
        Menu = Menu & "<a href=""menu.asp" & ("?ID=" + ParentID) & """><img src=""minus.gif"" border=0>&nbsp;" & rs("Kat") & "</a></td></tr>" & SubMenu
        FoundID = True
      Else
        Menu = Menu & "<a href=""menu.asp?ID=" & rs("ID") & """><img src=""plus.gif"" border=0>&nbsp;" & rs("Kat") & "</a></td></tr>"
      End If
    End If
   
    rs.MoveNext
  Loop
 
  rs.Close
  Set rs = Nothing
 
  MakeMenu = Menu
End Function
%>
</table>
</body>
</html>

Philip
Avatar billede morpheus Nybegynder
24. maj 2000 - 10:04 #14
Kan man downloade adovbs.inc et eller andet sted ?

<//morpheus\\>
Avatar billede isdan Nybegynder
24. maj 2000 - 10:31 #15
Det kan du her

http://www.eb-data.com/adovbs.inc (som text)

http://www.eb-data.com/adovbs.zip (til download / er ikke en zip fil bare rename den til adovbs.inc efter download)
Avatar billede quak.dk Nybegynder
24. maj 2000 - 12:14 #16
Hej Philip.. Jeg for denne fejl er det bare min server der er lidt kold

Der opstod en Microsoft VBScript-kørselsfejl error '800a01b6'
Objektet understøtter ikke denne egenskab eller metode: 'CreateObject'

/menu/menu2.asp, line 16

Avatar billede quak.dk Nybegynder
24. maj 2000 - 12:18 #17
Jeg kom lidt længere nu, jeg fik denne fejl

Der opstod en Microsoft VBScript-kompileringsfejl error '800a0400'

En sætning var ventet

/x-web/menu/menu.asp, line 38

,,,,
^
Avatar billede quak.dk Nybegynder
24. maj 2000 - 12:25 #18
Så nu fik jeg det hele til at virke næsten *s*

med den link.asp, det er godt nok, men hvis man så trykke på en anden menu der skal åbne sig linker den til link, det skal den jo ikk.,.. Den skal åbne den submenu...

Hvordan gør man det?

Du får lige dine point
Avatar billede philiph Nybegynder
24. maj 2000 - 07:08 #19
Det var dog en masse interessante fejl du har fået ;)

Jeg gik ud fra at menuen, når du når et punkt der ikke er underpunkter under, skal linke til en anden side. Jeg har kaldt den link.asp, men du kan kalde den hvad du vil. Evt. smide resultatet til en anden frame, så menuen bliver stående.
Scriptet skulle i hvert fald virke, så når du klikker på et menupunkt der har underpunkter, så foldes menuen ud derunder. Du kan se det virke på:

http://www.1op.dk/dsd/menu/menu.asp

og den adovbs.inc jeg har brugt kan hentes her (der findes flere versioner):
http://www.1op.dk/dsd/menu/adovbs.inc

mvh
Philip

PS: Tak for de dejlige point, men jeg giver ikke op før du er rigtig glad ;)
Avatar billede quak.dk Nybegynder
25. maj 2000 - 15:03 #20
Jeg er rigtig glad nu.... Jeg fandt lige en fejl
Avatar billede philiph Nybegynder
25. maj 2000 - 18:57 #21
Forhåbentligt ikke i MIN kode ;o)
Avatar billede morpheus Nybegynder
26. maj 2000 - 12:11 #22
quak.dk >>>

Findes der en forklaring til strukturen af den database du har linket til ?

Eller findes der en anden version af databasen som passer til scriptet ?

<//morpheus\\>
Avatar billede Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Loading billede Opret Preview
Kategori
Kurser inden for grundlæggende programmering

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester