Avatar billede s_raagaard Nybegynder
07. juni 2000 - 21:55 Der er 4 kommentarer og
1 løsning

Dictionary problem

Hej

Hvordan for jeg skrevet flere sæt i mit dictionary, istedet for kun et når jeg submitter min form.

<% Set Person = CreateObject("Scripting.Dictionary")

Navn=request.querystring("Navn")
Alder=request.querystring("Alder")

Person.add Navn, Alder
%>

  <form name="FormName" action="add.asp" method="get">
  <br>
  <br>
  <input type="text" name="Navn" size="24"><br>
  <br>
  <input type="text" name="Alder" size="24"><br>
  <br>
  <input type="submit" name="submitButtonName">
  </form>
<br><br><br>
<%
strKeysArray = Person.Keys
strItemsArray = Person.Items
For intloop = 0 to Person.Count -1
strThisKey = strKeysArray(intloop)
strThisItem = strItemsArray(intloop)
response.write strThisKey & " = "
response.write strThisItem & "<br><br>"
next
%>

mvh
/søren rågård
Avatar billede philiph Nybegynder
07. juni 2000 - 23:18 #1
Du skal gemme Dictionary variablen i en Session variable.

Følgende virker (er testet):

<% Option Explicit %>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.0 Transitional//EN">
<html>
<head>
  <title>Add</title>
</head>
<body>
<form name="FormName" action="add.asp" method="post">
<br>
<br>
<input type="text" name="Navn" size="24"><br>
<br>
<input type="text" name="Alder" size="24"><br>
<br>
<input type="submit" name="submitButtonName">
</form>
<br><br><br>
<%
Dim Person
Dim intLoop
Dim strNavn
Dim strAlder
Dim strKeysArray
Dim strItemsArray

If IsObject(Session("Person")) Then
  Set Person = Session("Person")
Else 
  Set Person = CreateObject("Scripting.Dictionary")
End If

strNavn = Request.Form("Navn")
If strNavn <> "" Then
  strAlder = Request.Form("Alder")
  Person.Add strNavn, strAlder
End If

strKeysArray = Person.Keys
strItemsArray = Person.Items
For intloop = 0 to Person.Count -1
  Response.Write strKeysArray(intLoop) & " = " & strItemsArray(intLoop) & "<br><br>"
Next

Set Session("Person") = Person
%>
</body>
</html>
Avatar billede s_raagaard Nybegynder
07. juni 2000 - 23:35 #2
Hej Philip....og mange tak

Men det er ikke helt det jeg mener, dette gør det samme som mit....

Det skal være sådan at hver gang jeg submitter skrives der et nyt sæt, således at listen bliver længere og længere, jeg får stadig kun vist et par, som er det sidst indtastede. jeg vil gerne kunne se alle indtastninger i en session.

/søren
Avatar billede s_raagaard Nybegynder
07. juni 2000 - 23:37 #3
Undskyld.....det var mig der var et kvaj, nu virker det.....tak skal du ha'

/søren
Avatar billede lip Nybegynder
08. juni 2000 - 09:16 #4
Hej philiph
vil du tjene nogle ekstra point ved at fortælle mig, hvordan man kan gemme to ens key med hver sit item.
For hvad nu hvis der er to der hedder Hans Hansen, men er henholdsvis 20 og 50. Kan det lade sig gøre at gemme i samme dictionary.
MVH
lip
Avatar billede philiph Nybegynder
08. juni 2000 - 17:24 #5
Det kan man ikke. Dictionary objektet er netop defineret som en liste af unikke keys med en tilhørende værdi. Du må ty til et array, eller bruge collection objektet til at gemme arrays med to elementer.

Hvad var grunden til at du valgte Dictionary?
Avatar billede Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Loading billede Opret Preview
Kategori
Kurser inden for grundlæggende programmering

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester