Avatar billede hanz Nybegynder
12. juli 2000 - 13:30 Der er 12 kommentarer og
1 løsning

URL'er til dynamiske links

Jeg har set flere scripts på nettet med løsningen på at lave tekstlinks om til aktive links. Men jeg kan ikke finde ud af at implementere det i min kode.

Hvor og hvordan skal det implementeres her?

strSQL = "SELECT * FROM Artikel ORDER BY Dato DESC;"
    Set myConn = Server.CreateObject("ADODB.Connection")
    myConn.Open tempConn
    Set rs = myConn.Execute(strSQL)
    If Not (rs.BOF Or rs.EOF) Then
    Do While Not rs.EOF
        Response.Write "<table width='180' align='center' cellspacing='0' cellpadding='4' border='0' bgcolor='#ffffff' style='border-left: 1px solid #999999; border-right: 1px solid #999999; border-top: 1px solid #999999; border-bottom: 1px solid #999999'>"
        Response.Write "<tr>"
        Response.Write "<td class='teaser' width='100%' align='left' valign='top' bgcolor='#F6F6FD'>" & rs("Teaser") & ""
        Response.Write "...&nbsp;<a class='ultrasmall' href='VisArtikel.asp?ID=" & rs("ID") & "'>( læs mere! )</a></td></tr></table><br>"
    rs.MoveNext
    Loop
        Response.Write "<p align='center'><a class='small' href='VisArtikel_multiple.asp' target='_top'>Se alle artikler!</a>"
    Else
        Response.Write "<span class='dato'>Der er endnu ingen Artikler!<br><br></span>"
    End If
    myConn.Close
    Set myConn = Nothing

hanz
Avatar billede lp Nybegynder
12. juli 2000 - 13:46 #1
ehhhmmm, hvilket af disse felter kunne indeholde et link?
Avatar billede hanz Nybegynder
12. juli 2000 - 13:48 #2
........ " & rs("Teaser") & "

hanz
Avatar billede lp Nybegynder
12. juli 2000 - 14:14 #3
En gut der hedder John Watson, lavede engang en ret fed function som erstatter alle hyperlinks og email adresser i en tekststreng til aktive links......du skal inkludere denne function øverst i dit dokument og siden kalde den igen ved at, i dit tilfælde gøre således:

addlinks(rs(Teaser"),"_top") 'hvor som vil smide den oven på eksistrere, kunne evt. være _blank

her er funktionen:

Function addLinks(sInput, sTarget)
    Dim sNew, sPunct
   
    ' Define punctuation characters
    sPunct = "_-+=!?.,;:`~'""*^$%()[]{}<>|"
   
    ' Assign input string to local variable so we don't change the
    ' original string.
    sNew = sInput

    ' Split the string by whitespace: spaces, carriage returns, line feeds,
    ' and tabs.  Then, for each "word" in the string...
    For Each sVal1 in Split(sNew, " ")
    For Each sVal2 in Split(sVal1, vbcr)
    For Each sVal3 in Split(sVal2, vblf)
    For Each sVal4 in Split(sVal3, Chr(9))
        ' Remove beginning and ending punctuation
        bStop = FALSE
        Do While (Not bStop)
            If (Instr(sPunct, Left(sVal4, 1)) <> 0 And Len(sVal4) > 2) Then
                sVal4 = Mid(sVal4, 2)
            Else
                bStop = TRUE
            End If
        Loop
       
        bStop = FALSE
        Do While (Not bStop)
            If (Instr(sPunct, Right(sVal4, 1)) <> 0 And Len(sVal4) > 2) Then
                sVal4 = Left(sVal4, Len(sVal4) - 1)
            Else
                bStop = TRUE
            End If
        Loop

        ' If the word begins with http:// then convert all occurrences
        ' of this word to a hyperlink.
        If (LCase(Left(sVal4, 7) = "http://") Or LCase(Left(sVal4, 4) = "www.")) Then
            If (LCase(Left(sVal4, 4) = "www.")) Then
                If (sTarget = "") then
                    sNew = Replace(sNew, sVal4, "<A HREF=""http://" & sVal4 & """>" & sVal4 & "</A>")
                Else
                    sNew = Replace(sNew, sVal4, "<A HREF=""http://" & sVal4 & """ TARGET=""" & sTarget & """>" & sVal4 & "</A>")
                End If
            Else
                If (sTarget = "") then
                    sNew = Replace(sNew, sVal4, "<A HREF=""" & sVal4 & """>" & sVal4 & "</A>")
                Else
                    sNew = Replace(sNew, sVal4, "<A HREF=""" & sVal4 & """ TARGET=""" & sTarget & """>" & sVal4 & "</A>")
                End If
            End If
        End If
       
        ' If this word looks like an e-mail address then convert all
        ' occurrences into a mailto: link.
        If (Instr(sVal4, "@") >= 2 And Instr(sVal4, ".") <> 0 And Len(sVal4) >= 5) Then
            sNew = Replace(sNew, sVal4, "<A HREF=""mailto:" & sVal4 & """>" & sVal4 & "</A>")
        End If
    Next
    Next
    Next
    Next
   
    ' Return converted string
    addLinks = sNew
End Function
%>

/LP
Avatar billede hanz Nybegynder
12. juli 2000 - 14:25 #4
Hvordan skal funktionen skrives her til " & Replace(Rs("Artikel")& ":


strSQL = "SELECT * FROM ForsArtikel WHERE (ID = " & strID & ")"
    Set myConn = Server.CreateObject("ADODB.Connection")
    myConn.Open tempConn
    Set rs = myConn.Execute(strSQL)
    If Not (rs.BOF Or rs.EOF) Then
        NewWebDato = rs("Dato")
        NewWebDato = FormatDateTime(NewWebDato,vbLongDate) & "&nbsp;,&nbsp; kl. " & FormatDateTime(NewWebDato,vbShortTime)
        Response.Write"<span class='image'><table align='center' border='0' width='700' cellspacing='0' cellpadding='3' style='border-left: 1px solid #999999; border-right: 1px solid #999999; border-top: 1px solid #999999;'>"
        Response.Write"<tr>"
        Response.Write"<td class='dato' width='300' align='left' valign='middle' bgcolor='E3E5EC'>" & rs("Overskrift") & "</td>"
        Response.Write"<td class='dato' width='400' align='right' valign='middle' bgcolor='E3E5EC'>Lagt online d. " & NewWebDato & "</td></tr></table></span>"
        Response.Write"<table width='700' align='center' cellspacing='0' cellpadding='4' border='0' bgcolor='#ffffff' style='border-left: 1px solid #999999; border-right: 1px solid #999999; border-top: 1px solid #999999; border-bottom: 1px solid #999999'>"
        Response.Write"<tr>"
        Response.Write"<td width='100%' valign='top' bgcolor='#ffffff'><span class='Artikel'><div align='right' valign='top'><table align='right' border='0' cellspacing='0' cellpadding='0' style='border-left: 1px solid rgb(0,0,0); border-right: 1px solid rgb(0,0,0); border-top: 1px solid rgb(0,0,0); border-bottom: 1px solid rgb(0,0,0)'><tr><td width='100%' height='100%' align='right' valign='top'><span class='image'><img src='log/baser/grafik/" & rs("Billede") & "'></span></td></tr></table></div>"
        Response.Write Replace(Rs("Artikel") & " ", vbCrLf, "<BR>") & vbCrLf
        Response.Write"</span></td></tr>"
        Response.Write"<tr>"
        Response.Write "<td width='100%' valign='top' bgcolor='#ffffff'><p class='graa' align='right'>Alle artikler af <a class='small' href='VisForfatter.asp?Forfatter=" & rs("Forfatter") & "'>" & rs("Navn") & "</a></td></tr>"
        Response.Write"<tr>"
        Response.Write "<td width='100%' valign='top' bgcolor='#ffffff'><p class='graa' align='right'>Info om <a class='small' href='VisInfo.asp?ID=" & rs("Forfatter") & "'>" & rs("Navn") & "</a></td></tr>"
        Response.Write "<tr><td width='100%' valign='top' bgcolor='#ffffff'><p align='right'><a class='small' href='java script:history.back(1)'>Retur</a></td></tr></table>"
    Else
        Response.Write "<span class='dato'>Der er endnu ingen Artikler!<br><br></span>"
    End If
    myConn.Close
    Set myConn = Nothing

hanz
Avatar billede lp Nybegynder
12. juli 2000 - 15:19 #5
ok, her er den:

strSQL = "SELECT * FROM ForsArtikel WHERE (ID = " & strID & ")"
    Set myConn = Server.CreateObject("ADODB.Connection")
    myConn.Open tempConn
    Set rs = myConn.Execute(strSQL)
    If Not (rs.BOF Or rs.EOF) Then
        NewWebDato = rs("Dato")
        NewWebDato = FormatDateTime(NewWebDato,vbLongDate) & "&nbsp;,&nbsp; kl. " & FormatDateTime(NewWebDato,vbShortTime)
        Response.Write"<span class='image'><table align='center' border='0' width='700' cellspacing='0' cellpadding='3' style='border-left: 1px solid #999999; border-right: 1px solid #999999; border-top: 1px solid #999999;'>"
        Response.Write"<tr>"
        Response.Write"<td class='dato' width='300' align='left' valign='middle' bgcolor='E3E5EC'>" & rs("Overskrift") & "</td>"
        Response.Write"<td class='dato' width='400' align='right' valign='middle' bgcolor='E3E5EC'>Lagt online d. " & NewWebDato & "</td></tr></table></span>"
        Response.Write"<table width='700' align='center' cellspacing='0' cellpadding='4' border='0' bgcolor='#ffffff' style='border-left: 1px solid #999999; border-right: 1px solid #999999; border-top: 1px solid #999999; border-bottom: 1px solid #999999'>"
        Response.Write"<tr>"
        Response.Write"<td width='100%' valign='top' bgcolor='#ffffff'><span class='Artikel'><div align='right' valign='top'><table align='right' border='0' cellspacing='0' cellpadding='0' style='border-left: 1px solid rgb(0,0,0); border-right: 1px solid rgb(0,0,0); border-top: 1px solid rgb(0,0,0); border-bottom: 1px solid rgb(0,0,0)'><tr><td width='100%' height='100%' align='right' valign='top'><span class='image'><img src='log/baser/grafik/" & rs("Billede") & "'></span></td></tr></table></div>"
        Artikel=Replace(Rs("Artikel") & " ", vbCrLf, "<BR>")
        Response.Write addLinks(Artikel, "_blank")
        Response.Write"</span></td></tr>"
        Response.Write"<tr>"
        Response.Write "<td width='100%' valign='top' bgcolor='#ffffff'><p class='graa' align='right'>Alle artikler af <a class='small' href='VisForfatter.asp?Forfatter=" & rs("Forfatter") & "'>" & rs("Navn") & "</a></td></tr>"
        Response.Write"<tr>"
        Response.Write "<td width='100%' valign='top' bgcolor='#ffffff'><p class='graa' align='right'>Info om <a class='small' href='VisInfo.asp?ID=" & rs("Forfatter") & "'>" & rs("Navn") & "</a></td></tr>"
        Response.Write "<tr><td width='100%' valign='top' bgcolor='#ffffff'><p align='right'><a class='small' href='java script:history.back(1)'>Retur</a></td></tr></table>"
    Else
        Response.Write "<span class='dato'>Der er endnu ingen Artikler!<br><br></span>"
    End If
    myConn.Close
    Set myConn = Nothing


/LP
Avatar billede hanz Nybegynder
12. juli 2000 - 15:40 #6
Jamen nu kommer link'sne sku' da frem! Men hvis jeg skriver 2 links efter hinanden, laver den fejl. Også hvis jeg skriver en URL efterfølgt af et <br> går det galt... Hvad skyldes det?

hanz
Avatar billede lp Nybegynder
12. juli 2000 - 15:44 #7
aner det ikke, har du en side hvor jeg kan se det? jeg må indrømme, jeg kan ikke hjælpe yderligere det var et script jeg fandt for længe siden, men har aldrig studeret den nærmere, den skulle dog være ret populær - de tests jeg har lavet virkede upåklageligt.........hvad mener du forresten med efterfølgt af et <br>?
Avatar billede hanz Nybegynder
12. juli 2000 - 15:53 #8
Jeg mener når man trykker "Return" <br> den funktion der står lige over addlinks. Men prøv at kigge på den her: www.halken.dk/VisArtikel.asp?ID=30

hanz
Avatar billede lp Nybegynder
12. juli 2000 - 16:00 #9
ahhhmmm, det er jo din egen fejl, du indsætter jo selv linjemellemrum fremfor at lade den selv gøre det når dokumentet puttes i basen. Den kan ikke rettes, medmindre de der <br> fjernes igen!
Avatar billede hanz Nybegynder
12. juli 2000 - 16:05 #10
Hvad mener du med at jeg indsætter linjemellemrum femfor at lade den selv gøre det når den puttes i basen?
Avatar billede lp Nybegynder
12. juli 2000 - 16:19 #11
ja altså, den der har indtastet det har
trykket
på
enter
da
det
blev
skrevet
ind
og
det
medfører
forkert
output

jeg kan ikke hjælpe dig med det da det er din base der er problemet, men jeg mener også at have svaret på det du spurgte om.........du kan evt. skrive en fire til fem linjer uden de dumme enter og prøve at lade den lave dem om.....det er jeg 100% sikker på at den gør uden problemer....

/LP
Avatar billede lp Nybegynder
12. juli 2000 - 16:20 #12
man trykker jo kun på enter når man vil have 2 linjer til nyt afsnit og ikke efter hver enkelt linje.....vel
Avatar billede hanz Nybegynder
12. juli 2000 - 18:37 #13
Jamen det er jo netop det funktionen gør, laver et nyt afsnit. Men man kunne jo godt forestille sig at, der blev skrevet en URL/E-mail som afslutning på tekststrengen, for derefter at starte på et nyt afsnit. Eller man havde en liste af forskellige links indskrevet i teksten, stående oven på hinanden (delt med enter) men det siger du at den så ikke vil acceptere... Kan man ikke lave det så det kan?

Og jo, du HAR svaret på mit spørgsmål..Kanon, tak for det.
Hvis du har en løsning, er jeg meget interesseret i at høre/se den!

hanz
Avatar billede Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Loading billede Opret Preview
Kategori
Kurser inden for grundlæggende programmering

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester