Billeder ud af Access

Prøv at kikke på dette eks, er det sådan noget du søger:

http://www.activeserverpages.dk/aspdigital/kapitel2/sqlimage.asp

well I would also like to see if this is possoble without having to open the picture in Paint or something and then saving it!

EagleEye ikke lige det script..

Det er det script jeg bruger når jeg viser billederne på siden.. Har prøvet at lege med FSO som du forslog mig i et andet spørgsmål jeg oprettede, men jeg er ikke så hardcore til ASP.. Måske du kan få det til at virke med FSO ?

Jens K

Ja jeg kan godt se det .. men man skal vel lave noget i samme stil, isted for at udskrive det kan man måske skrive det til en Stream og så genne dem som fil??

Jeg vil prøve at kigge på senere idag, aften bliver det nok. Skal lige hjem, men måske der kommer andre som har en god læsning.

Det ville bare være kanon hvis du kan finde en løsning på det...

Jens K

Jeg er kommet hjem og er ved at kigge på det nu, man kan lave det med ADODB.Stream obejct ideen til det jeg laver kan du finde her: http://support.microsoft.com/default.aspx?scid=kb;DA;q258038

Hvordan har du gemt det i db bare BinData og filanv så prøv dette, men det kommer vist an på hvordan man gemmer data!?!?

Jeg er kommet frem til dette. Jeg får godt en en Write Error når den forsøger at gemme filen, men kan du evt prøve det? Du må lige rette til med database navn og kolonne navne.

'Connection string
connStr = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("FileDB.mdb")
Set Conn = Server.CreateObject("ADODB.Connection")
Set rs = Server.CreateObject("ADODB.RecordSet")
Conn.Open connStr

ID = Request.QueryString("ID")  'Enten via querystring eller sæt ID til et kendt billede
'ID = 3
strSQL = "SELECT * FROM Files WHERE ID = " & ID

rs.Open strSQL, Conn, 1
 
if rs.EOF then
  Response.Write "Ingen billede" 
Else
  Set streamObj = Server.CreateObject("ADODB.Stream")
  streamObj.Type = 1 'adTypeBinary
  streamObj.Open
  streamObj.Write rs.Fields("BinData").Value
  streamObj.SaveToFile rs("Filename")
'  streamObj.Write rs.Fields("File Data").Value
'  streamObj.SaveToFile rs("File Name"),2
end if
rs.Close
Conn.Close
Set rs = Nothing
Set Conn = Nothing

arh den skal havde hele siten til filen for den vil gemme..

Ok.. jeg har fået det til at virke efter jeg skrev hele stien i SaveToFile..

Hvad indeholdr Filename og hvor skal filen gemmen?


Sådan her er det så jeg har lagt billederne i c:\inetpub\wwwroot\images og det kræver natuligvis skriverettigher.

<%
connStr = "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & Server.MapPath("FileDB.mdb")
Set Conn = Server.CreateObject("ADODB.Connection")
Set rs = Server.CreateObject("ADODB.RecordSet")
Conn.Open connStr

ID = Request.QueryString("ID")
'ID = 3
strSQL = "SELECT * FROM Files WHERE ID = " & ID
rs.Open strSQL, Conn, 1
if rs.EOF then
  Response.Write "Ingen billede" 
Else
  Set streamObj = Server.CreateObject("ADODB.Stream")
  streamObj.Type = 1 'adTypeBinary
  streamObj.Open
  streamObj.Write rs.Fields("BinData").Value
  streamObj.SaveToFile "c:\inetpub\wwwroot\images" & rs("Filename"),2
  streamObj.Close 
  Set streamObj = Nothing
end if
rs.Close
Conn.Close
Set rs = Nothing
Set Conn = Nothing
%>

Hvad format er dine billeder. HVIS det .bmp skal man af en eller anden grund skippe de første 78 byte.

Dette er vbs fil jeg engang brugte da jeg overtog en gammel database, og ville trække alle billederne ud.
felt(0) er blobfelt med bidledet i
felt(1) er sti + filnavn hvor bmp'erne skal gemmes.

Dim rst
  Dim strCnn
  dim stream
  dim strSave
  set strSave = WScript.createobject("ADODB.Stream")
  set stream = WScript.createobject("ADODB.Stream")
 
  set fso = WScript.createobject("Scripting.FileSystemObject")
  strsave.type = 1
  stream.type = 1
  ' Open compound recordset.
      strCnn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=c:\dokumenter\db2.mdb"

  set rst = WScript.CreateObject( "ADODB.Recordset" )
  rst.Open "SELECT * FROM tabel2 " , strCnn


      Do While Not rst.EOF
        stream.open
        strsave.open
        stream.Write rst.Fields(0).Value
       

        ' Barber de første 78 byte af ????????????
        stream.position = 79
        stream.copyto strsave
        strsave.savetofile  rst.fields(1),2
        stream.close
        strsave.close
        rst.MoveNext
      Loop
      set rst = nothing
      set stream = nothing
      set strSave = nothing

øhh den fso, den hører vist ikke med :o)

niels

jens_k >> hvordan går det

Undskyld jeg ikke svare før nu.. Har været væk fra denne mailkonto et stykke tid..

Har brugt EagleEye´s Script og det virker ganske udemærket.. Så det var da meget rart at få dem ud..

Tak for hjælpen Eksperter..