OnMouseLeave

Hvis ikke du kan få det her til at virke, har jeg desværre ikke andre forslag:
http://www.gnomehome.demon.nl/uddf/pages/mouse.htm#mouse0

prøv det her

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls, Buttons;

type
  TForm1 = class(TForm)
    Image1: TImage;
    ListBox1: TListBox;
    procedure FormCreate(Sender: TObject);
  private
    FOldWndProc : TWndMethod;
    procedure ImageWnd(var Message: TMessage);
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

type
  TImageAccess = class(TImage);

procedure TForm1.ImageWnd(var Message : TMessage);
begin
  FOldWndProc(Message);

  if Message.Msg = CM_MOUSELEAVE then
    Beep;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FOldWndProc := Image1.WindowProc;
  Image1.WindowProc := ImageWnd;
end;

end.

tak det virker nu..

nico22> ligger du et svar??

:)

btw - slet lige:

type
  TImageAccess = class(TImage);

det bruges ikke til noget :)

Du laver et nyt component der bygger på TImage hvor der er tilføjet følgende events: OnMouseEnter og OnMouseLeave.

Du laver en unit med følgende indhold:

//******************************************************
unit MyImageunit;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls;

type
  TEntrarEvent = procedure(Sender: TObject) of object;
  TSalirEvent = procedure(Sender: TObject) of object;
  TMyImage = class(TImage)
  private
    { Private declarations }
    FOnEnter: TEntrarEvent;
    FOnExit: TSalirEvent;
    procedure CMMouseEnter(var msg: TMessage); message CM_MOUSEENTER;
    procedure CMMouseLeave(var msg: TMessage); message CM_MOUSELEAVE;
  protected
    { Protected declarations }
  public
    { Public declarations }
  published
    { Published declarations }
    property OnMouseEnter: TEntrarEvent read FOnEnter write FOnEnter;
    property OnMouseLeave: TSalirEvent read FOnExit write FOnExit;

  end;

procedure Register;

implementation

procedure TMyImage.CMMouseEnter(var msg: TMessage);
begin
  inherited;
 
  if Assigned(FOnEnter) then FOnEnter(Self);
end;

procedure TMyImage.CMMouseLeave(var msg: TMessage);
begin
  inherited;
  if Assigned(FOnExit) then FOnExit(self);
end;

procedure Register;
begin
  RegisterComponents('Additional', [TMyImage]);
end;

end.
//******************************************************
Denne unit gemmer du og registrerer som et nyt component.
Når det er installeret har du et component der hedder TMyImage som findes under Additional, Det fungerer fuldstændigt som TImage bortset fra de 2 nye events

//Erik

Tak for alle jeres svar!