Udelukke ord

Lidt ala:
If ord = index of ord1, ord2, ord3 replace with censur ?

Du kan lave en replace af dem.:

str = Request.form("besked_til_gæstebogen")
str = Replace(str, "perker", "xxx", 1,-1,1)
str = Replace(str, "luder", "xxx", 1,-1,1)

osv..

arh så du har en liste i en DB..... så kan du lave et loop

SQL = "SELECT * FROM Ukvemsordene"
Set uRS = Conn.Execute(SQL)

str = Request.form("besked_til_gæstebogen")
do while not uRS.EOF
  str = Replace(str, rs("nejtakord_kolonne"), "xxx", 1,-1,1
  uRS.MoveNext
loop

der mangelre en ) til sidst:
str = Replace(str, rs("nejtakord_kolonne"), "xxx", 1,-1,1)

Det med replace (...,1,-1,1); Det sidste 1 gør den ikke er casesenativ så både Luder,luder,LUDER,luDer,mmm fjernes.

OK, tak-
Jeg prøver lige lidt

Måske sjovere hvis du erstatter hvert enkelt ord med et pænere udgave. godt nok mere bøvlet men alligevel.

Jeg synes ikke rigtigt der sker noget ??

Du får lige hele koden her :

Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "PROVIDER=MSDASQL;DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Server.MapPath("gaestebog.mdb") & ";UID=admin;PWD=;"

SQL = "SELECT * FROM ukvemsord"
Set uRS = Conn.Execute(SQL)

str = Request.form("besked")
do while not uRS.EOF
  str = Replace(str, uRS("ord"), "xxx", 1,-1,1)
  uRS.MoveNext
loop

Const adOpenKeyset = 1
Const adLockOptimistic = 3


    Set rs = Server.CreateObject("ADODB.RecordSet")
    strSQL = "Select * From gaestebogen"
    rs.Open strSQL, Conn, adOpenKeyset, adLockOptimistic

      rs.AddNew
      rs("Navn") = Request.form("Navn")
      rs("Email") = Request.form("Email")
      rs("Besked") = Request.form("Besked")
      rs("Dato") = Now()
      rs("IP") = request.servervariables("remote_Addr")
      rs.Update

    rs.Close
    Set rs = Nothing

Conn.Close
set Conn = Nothing

joo, ideen er da god <<schulze

Så skal du rette denne linie:
rs("Besked") = Request.form("Besked")
     

til:
rs("Besked") = str

Eller ligger du det indtasede i databasen og ikke det hvor ordne er fjernet.

joo, nu virker det skam, men !!
den replacer jo også inde midt i et ord..
f.eks: sol
databasen indeholder ukvemsordet: so
altså bliver det til xxxl
hmmm, ikke så godt

Så skal det være noge med regExp som skal bruges til at udskift med:


Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open "PROVIDER=MSDASQL;DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Server.MapPath("gaestebog.mdb") & ";UID=admin;PWD=;"

SQL = "SELECT * FROM ukvemsord"
Set uRS = Conn.Execute(SQL)

str = Request.form("besked")

Set regEx = New RegExp
regEx.Global = true
regEx.IgnoreCase = True

do while not uRS.EOF
  regEx.Pattern = "((^|[^a-z])" & uRS("ord") & "([^a-z]|$))"
  str = regEx.Replace (str, " xxx ")
  uRS.MoveNext
loop
Set regEx = Nothing

Response.Write str

Jamen !! det fungere jo :-)
Nu er det meget lidt jeg har kigget på RegExp.
Hvis du ville give en kort forklaring på hvad der sker:
regEx.Pattern = "((^|[^a-z])" & uRS("ord") & "([^a-z]|$))"


Mange tak for hjælpen

I bund og grund søger denefter det som står i  uRS("ord").
Det førte (^|[^a-z]) betyder at der foran ord ikke må være bogstaver [^a-z] eller det er første ord i linien ^

Det sidste ([^a-z]|$) betyder noget i samme stil. Der må ikke være bogstaver efter det ord man søger på [^a-z], men ordet må godt være det sidste ord i linien $.


Du kan se mere her:
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/script56/html/vspropattern.asp