Hej,
Jeg har et eksempel på hvordan det kan gøres, du kan se om det kan bruges.
--------------------------------------
<html>
<head>
<title>Fotoalbum</title>
</head>
<body bgcolor="#CCCCCC"><font face="Verdana">
<%
dim strAction
strAction=request("action")
Main
select case strAction
case "search"
Search request("searchstr"), 0
case "category"
Search request("searchstr"), 1
case "show"
ShowImage request("image")
end select
'---------------------
'Funktioner/procedurer
'---------------------
sub Main
%>
<h2 align="center">Fotoalbum</h2>
<p>Søg:
<form action="photoalbum.asp?action=search" method="post">
<input type="text" name="searchstr">
<input type="submit" value="Søg">
</form>
</p>
<p>Eller vælg kategori:<br>
<%
dim strSQL, objRS, arrCategories, i
strSQL = "SELECT category, count(category) as numcat FROM PhotoAlbum " & _
"GROUP BY category"
set objRS = server.createobject("ADODB.Recordset")
objRS.open strSQL, strConnect, adOpenForwardOnly, adLockReadOnly, adCmdText
if not objRS.EOF then
arrCategories = objRS.GetRows
end if
objRS.close
set objRS = nothing
if isArray(arrCategories) then
for i = 0 to ubound(arrCategories,2)
response.write _
" <a href=""photoalbum.asp?action=category&searchstr=" & _
server.urlencode(arrCategories(0,i)) & """>" & _
arrCategories(0,i) & "(" & arrCategories(1,i) & ")</a> "
next
end if
%>
<hr></p><%
end sub
sub Search (strS, intType)
dim strSQL, objRS
if intType = 0 then
strSQL = "SELECT titel, imagename FROM PhotoAlbum " & _
"WHERE titel + beskrivelse + words LIKE '%" & strS & "%'"
end if
if intType = 1 then
strSQL = "SELECT titel, imagename FROM PhotoAlbum " & _
"WHERE category = '" & strS & "'"
end if
set objRS = server.createobject("ADODB.Recordset")
with objRS
.open strSQL, strConnect, adOpenForwardOnly, adLockReadOnly, adCmdText
while not .EOF
response.write _
"<p><a href=""photoalbum.asp?action=show&image=" & _
server.urlencode(.Fields("imagename")) & """>" & _
"<img src=""/images/thumbs/" & .Fields("imagename") & """ border=0>" & _
"</a><br clear=all>" & _
.Fields("titel") & "</p>"
.movenext
wend
.close
end with
set objRS = Nothing
end sub
sub ShowImage (strImageName)
dim strSQL, objRS
strSQL = "SELECT titel, beskrivelse FROM PhotoAlbum " & _
"WHERE imagename = '" & strImageName & "'"
set objRS = server.createobject("ADODB.Recordset")
with objRS
.open strSQL, strConnect, adOpenForwardOnly, adLockReadOnly, adCmdText
if not .EOF then
response.write _
"<h2>" & .Fields("titel") & "</h2>" & _
"<img src=""/images/image/" & strImageName & """>" & _
"<p>" & .Fields("beskrivelse") & "</p>"
else
response.write _
"<p>Kan ikke finde billedet: " & strImageName & "</p>"
end if
.close
end with
set objRS = Nothing
end sub
%>
</font>
</body>
</html>
Ny bruger
Nybegynder
Opret
Preview
