behandle mottak via VBa

Er det ikke bedre med "ini.cue"?
Det har jeg i hvert tilfælde haft bedst succes med!

eh.... hæ? ini.cue er ukjent for meg...

Prøv denne her...
-------------------------

Public Sub GetSubject()

    On Error GoTo ErrorHandler
   
    Dim myOlApp As Outlook.Application
    Set myOlApp = Application
   
    Dim myFolder As Outlook.MAPIFolder
    Set myFolder = myOlApp.GetNamespace("MAPI").GetDefaultFolder(olFolderInbox)
   
    Dim myMail As MailItem
    Set myMail = myFolder.Items.GetLast
   
    searchString = "Hello"
    Directory = "F:\Attachments\"
   
    Dim filnavn As String
       
    If TypeName(myMail) = "MailItem" Then
        If ((InStr(1, myMail.Subject, searchString, vbTextCompare)) >= 1) Then
            filnavn = Directory & myMail.Subject & ".msg"
            myMail.SaveAs filnavn, olTXT
        Else
            'Lad den blive i Inbox
        End If
       
    End If
    Exit Sub
   
ErrorHandler:
    Debug.Print Err.Description & " " & Err.Number & " " & Err.Source
    Exit Sub
   
End Sub

--------------------------------

Det eneste problem er at Outlook brokker sig over sikkerheden når man prøver at gemme.....men det må også kunne løses.
Det er ihvertfald en start...

Hvis den skal aktiveres hver gang der kommer en ny mail, skal du placere den i New_mail event koden...

Private Sub Application_NewMail()
    Call Module1.GetSubject("Hello", "F:\Attachments\")
End Sub

rettelse...

Private Sub Application_NewMail()
    Call Module1.GetSubject()
End Sub

Mange takk blackadder. Ting fungerer nå knirkefritt takket være deg.

legg inn som svar, og så er poengene dine :-)

eh, kom på en liten mulig forbedring, blackadder...

kan filene som lagres i "F:\attachments" nummereres stigende? slik at hvis det ligger 3 ".msg" filer der så blir neste hetende "4.msg" osv... ?

Ja, smid denne funktion ind i VB modulet

--------------
Function countFilesInDir(Directory As String) As Long
    Dim i As Integer
    Dim MyFile
    ChDir Directory
    MyFile = Dir(Directory & "*.*")
    i = 0
    While (MyFile <> "")
        i = i + 1
        MyFile = Dir()
    Wend
    countFilesInDir = i
End Function
----------------------------

og opdater GetSubject til...

---------------------

Public Sub GetSubject()

    On Error GoTo ErrorHandler
   
    Dim myOlApp As Outlook.Application
    Set myOlApp = Application
   
    Dim myFolder As Outlook.MAPIFolder
    Set myFolder = myOlApp.GetNamespace("MAPI").GetDefaultFolder(olFolderInbox)
   
    Dim myMail As MailItem
    Set myMail = myFolder.Items.GetLast
   
    Dim Directory As String, searchString As String
   
    searchString = "Hello"
    Directory = "F:\Attachments\"
       
    Dim filnavn As String
       
    If TypeName(myMail) = "MailItem" Then
        If ((InStr(1, myMail.Subject, searchString, vbTextCompare)) >= 1) Then
            filnavn = Directory & countFilesInDir(Directory) + 1 & ".msg"
            myMail.SaveAs filnavn, olTXT
            Debug.Print filnavn
        Else
            'Lad den blive i Inbox
        End If
       
    End If
    Exit Sub
   
ErrorHandler:
    Debug.Print Err.Description & " " & Err.Number & " " & Err.Source
    Exit Sub
   
End Sub

----------------------------

veldig bra. detta kan du :-)

jobber du med vb/vba?

Jeg skrev lidt VBA til Excel/Groupwise/Reflection for en tidligere arbejdsgiver, ellers er det kun her på Eksperten.

Tak for point :-)