Glemt kodeord

If Request.ServerVariables("Request_Method") = "POST" Then
        Email = Request.Form("email")

        Set rs = Conn.Execute("Select brugernavn, password, email From bruger Where Email = '" & Replace(Email, "'", "''") & "'")
        If Not rs.EOF Then
            'Send info til brugeren
        Else
            Response.Write "<b>Ingen e-mail adresser matchede!</b><br><br>"
        End If   
    End If   

    Response.Write "Her kan du få hjælp, hvis du har glemt dit brugernavn og/eller password.<br><br><br>"
    Response.Write "<form name='sendinfo' method='post' action='din_side.asp'>"
    Response.Write "<table style='width:500px;'>"
    Response.Write "<tr><td style='width:200px;'><b>E-mail:</b></td><td style='width:300px;'><input type='text' name='email' value='" & Email & "' style='width:300px;'></td></tr>"
    Response.Write "</table><br>"
    Response.Write "<input type='submit' value='Tilsend'></form>"

Hvilken komponent vil/kan du sende e-mails med?

jeg mener ASPmail er med i mit webhotel

Okay - så får du den lige igen her. Husk at rette RemoteHost til din udbyders mailserver-adresse.

*******************************************

    If Request.ServerVariables("Request_Method") = "POST" Then
        Email = Request.Form("email")

        Set rs = Conn.Execute("Select brugernavn, password, email From bruger Where email = '" & Replace(Email, "'", "''") & "'")
        If Not rs.EOF Then

            Set AspMail = Server.CreateObject("SMTPsvg.Mailer")
            AspMail.FromName = "Mail-Robot"
            AspMail.FromAddress = "robot@dit_domaene.dk"
            AspMail.AddRecipient rs("brugernavn"), rs("email")
            AspMail.Subject = "Dine login-oplysninger"
            AspMail.BodyText = "Brugernavn: " & rs("brugernavn") & vbCrlf & "Password: " & rs("password")
            AspMail.RemoteHost = "mail.domaene.dk"
            AspMail.Priority = 3
            AspMail.ContentType = "text/plain"
            AspMail.CharSet = 2
            If AspMail.SendMail Then
                Response.Write "Dine oplysninger er nu sendt til " & Email & "!<br><br>"
            Else
                Response.Write "Der opstod en fejl. Prøv igen!<br><br>"
            End If
            Set AspMail = Nothing
        Else
            Response.Write "<b>Ingen e-mail adresser matchede!</b><br><br>"
        End If   
    End If   

    Response.Write "Her kan du få hjælp, hvis du har glemt dit brugernavn og/eller password.<br><br><br>"
    Response.Write "<form name='sendinfo' method='post' action='din_side.asp'>"
    Response.Write "<table style='width:500px;'>"
    Response.Write "<tr><td style='width:200px;'><b>E-mail:</b></td><td style='width:300px;'><input type='text' name='email' value='" & Email & "' style='width:300px;'></td></tr>"
    Response.Write "</table><br>"
    Response.Write "<input type='submit' value='Tilsend'></form>"

Det er fandme nice, smid lige en besked som svar - du har da fortjent nogle point :)

Vær så god ;)