[Microsoft][ODBC Driver Manager]

ODBC driver manager kommer med Windows.

Du kan opdatere ved at downloade og installere MDAC.

MySQL ODBC driver kan hentes her:

http://www.mysql.com/downloads/api-myodbc-3.51.html

For stadig fejl.

Kan vi få hele fejl meddelelsen og evt. connection string ?

Her


Microsoft OLE DB Provider for ODBC Drivers error '80004005'

[Microsoft][ODBC Driver Manager] Data source name not found and no default driver specified

/test/database.asp, line 42


<%

' Disse 4 konstanter indeholder opsætningen til din MySQL database
' Adressen til MySQL serveren, f.eks. "localhost"
Const cnstSQLServerAddress = "localhost"
' Navnet på databasen
Const cnstSQLDataBase = "test"
' Det brugernavn du har fået til din database
Const cnstSQLUID = ""
' Den adgangskode du har fået til din database
Const cnstSQLPWD = ""

Dim objConn ' Opret en variabel
            ' der kan bruges til at forbinde til databasen.

Sub OpenDataBase
  ' Denne Sub gør det lettere i ASP koden
  ' at åbne en forbindelse til en Access database.
  ' Syntax :
  ' Call OpenDataBase

  Dim strProvider ' Opret variabel til at indeholde
                  ' vores connection-string til databasen.

  ' Start med at sikre at variablen er tom
  strProvider = ""
  ' Tilføj oplysninger om hvilken database-driver der skal bruges
  strProvider = strProvider & "Driver={MySQL};"
  ' Tilføj oplysning om hvor MySQL serveren befinder sig
  strProvider = strProvider & "Server=" & cnstSQLServerAddress & ";"
  ' Tilføj oplysning om hvad databasen hedder
  strProvider = strProvider & "Database=" & cnstSQLDataBase & ";"
  ' Tilføj brugernavn der har adgang i databasen, vores database login
  strProvider = strProvider & "UID=" & cnstSQLUID & ";"
  ' Tilføj adgangskode der har adgang i databasen, vores database login
  strProvider = strProvider & "PWD=" & cnstSQLPWD & ";"

  ' Opret et ADO Connection objekt
  Set objConn = Server.CreateObject("ADODB.Connection")
  ' Brug connection-string'en fra før til at oprette forbindelsen
  ' til databasen, via driveroplysninger m.v.
  objConn.Open strProvider
  ' Der er nu en åben og aktiv forbindelse til databasen.
End Sub

Sub CloseDataBase
  ' Denne Sub lukker forbindelsen til databasen efter brug.
  ' Bør altid kaldes efter arbejde med databasen,
  ' eller som den sidste funktion i ASP siden.
  ' Syntax :
  ' Call CloseDataBase

  ' Bed Connection objektet om at lukke forbindelsen
  objConn.Close
  ' Fjern Connection objektet fra hukommelsen på serveren.
  Set objConn = Nothing
End Sub

%>

Og test.asp

<!-- #include file="database.asp" -->
<html>
<body>
<%

' Åben en forbindelse til vores database

Call OpenDataBase

Dim objRS ' Opret en variabel der skal indeholde RecordSets fra databasen

Set objRS = objConn.Execute("SELECT * FROM Test ORDER BY Overskrift")
If (Not objRS.BOF) And (Not objRS.EOF) Then ' Sikring mod fejl hvis ingen records blev fundet
  objRS.MoveFirst ' Flyt til første record i vores resultat
  While Not objRS.EOF ' Så længe vi ikke har nået sidste resultat, udfør
    Response.Write objRS("Overskrift") & "<br>" & vbCrLf ' Udskrif overskriften
    objRS.MoveNext ' Flyt til næste record i resultatlisten
  Wend
Else ' Der var ingen resultater
  Response.Write "Ingen records fundet.<br>" & vbCrLf
End If
objRS.Close ' Luk for recordset
Set objRS = Nothing ' Frigør fra hukommelsen på serveren

' Luk forbindelsen til serveren igen

Call CloseDataBase

%>
</body>
</html>

Lukker