Directory med navnet dd/mm/yy

Det gør du med:
MD %DATE%

Har dog et lille problem da den opretter 2 mapper en der hedder dd/mm/yy og en der hedder ugedag, hvordan slipper jeg for den mappe med ugedagen.

Hvis du kører en dansk Win2k:

for /F "tokens=2" %I in ("%date%") do @md %I

Hvis det er i en .bat fil skal %I erstattes af %%I

Man kan naturligvis også bruge:

md "%date%"

Hvis ugedagen skal indgå i mappenavnet.

Det blev en længere smøre; men dette skulle tage højde for det meste, og returnere datoen i formatet: 02-02-2004 (dd-mm-åååå)

@echo off
if %1/==:/ goto %2
if NOT %1/==/?/ goto Begin
for %%C in (echo. goto:End) do %%C
:Begin --------------------------------------------------------------
echo. | date | FIND "(mm" > NUL
if NOT errorlevel 1 %0 : %OS%Parse MM DD
%0 : %OS%Parse DD MM
:Windows_NTParse ----------------------------------------------------
for /f "tokens=1-4 delims=/.- " %%A in ('date /t') do (
set Dow=%%A&set %3=%%B&set %4=%%C&set YYYY=%%D&goto End)
:Parse --------------------------------------------------------------
for %%C in (md cd) do %%C @tmp@
echo @prompt set _D=$D$_> ~tmp1.bat
%COMSPEC% /e:2048 /c ~tmp1.bat > ~tmp2.bat
call ~tmp2
echo %_D% | FIND "/" > NUL
if NOT errorlevel 1 goto Slash
lfnfor on > "%_D%.-"
ren "%_D%.-" "??? ?? ?? ????"
for %%F in ("??? ?? ?? ????") do set _D=%%F
lfnfor off
:Slash
echo set DOW=%%%3%%>~tmp1.bat
for %%S in ("%3=%%%4%%" "%4=%%YYYY%%" "YYYY=%%1") do echo set %%S>>~tmp1.bat
for %%S in (%_D%) do call ~tmp1 %%S
echo %_D% | FIND "/" > NUL
if errorlevel 1 goto Cleanup
echo @prompt set %4=$%%%4%%$_set YYYY=$%YYYY%$_ > ~tmp1.bat
%COMSPEC% /e:2048 /c ~tmp1.bat > ~tmp2.bat
call ~tmp2
:Cleanup
for %%C in ("set _D=" cd.. "deltree /y @tmp@ > NUL") do %%C
:End ----------------------------------------------------------------
set newdate=%dd%-%mm%-%yyyy%
md %newdate%