Navndata fra fil

prøv om denne virker efter hensigten

<%

Function FindFaktura(nummer)
    foldername = "sti til mappe"  ' brug evt. Server.MapPath("sti")

    Set regex = New RegExp
    regex.IgnoreCase = True
    regex.Pattern = "^(.*)-(.*)-(" & nummer & ").pdf$"

    set result = Nothing

    Set fso = Server.CreateObject("Scripting.FileSystemObject")
    Set folder = fso.GetFolder(foldername)

    For Each file in folder.Files

        If regex.Test(file) Then
            '
            ' faktura fundet
            '

            Set result = Server.CreateObject("Scripting.Dictionary")

            Set m = regex.Execute(file)(0)

            result.Add "bilagsnavn", Mid(m.SubMatches(0), Len(foldername)+2)
            result.Add "bilagnummer", m.SubMatches(1)
            result.Add "kundenummer", m.SubMatches(2)

            Exit For
        End If

    Next

    Set fso = Nothing
    Set FindFaktura = result
End Function


'find faktura
Set faktura = FindFaktura("456652")

If Not faktura Is Nothing Then
    Response.Write "Bilagsnavn: " & faktura("bilagsnavn") & "<br>"
    Response.Write "Bilagnummer: " & faktura("bilagnummer") & "<br>"
    Response.Write "Kundenummer: " & faktura("kundenummer") & "<br>"
Else
    Response.Write "Fakturaen blev ikke fundet"
End If

%>

Tak for dit forslag.

Scriptet finder en faktura som er tilknyttet kundenummeret, men hvis der er flere fakturaer eller kreditnotaer tilknyttet samme kundenummer, skal den gerne vise dem alle.

Kan du hjælpe her... :)

Har du fundet en løsning? Ellers er her en lille hurtig omskrivning:

<%
Sub FindFaktura(nummer)
    foldername = "sti til mappe"  ' brug evt. Server.MapPath("sti")

    Set regex = New RegExp
    regex.IgnoreCase = True
    regex.Pattern = "^(.*)-(.*)-(" & nummer & ").pdf$"

    Set fso = Server.CreateObject("Scripting.FileSystemObject")
    Set folder = fso.GetFolder(foldername)

    For Each file in folder.Files

        If regex.Test(file) Then
            '
            ' faktura fundet
            '

            Set m = regex.Execute(file)(0)

        Response.Write "Bilagsnavn: " & Mid(m.SubMatches(0), Len(foldername)+2) & "<br>"
        Response.Write "Bilagnummer: " & m.SubMatches(1) & "<br>"
        Response.Write "Kundenummer: " & m.SubMatches(2) & "<br><hr>"

        End If

    Next

    Set fso = Nothing
End Sub


'find faktura
FindFaktura("456652")
%>

Det fungerer super!

Smid lige et svar...

np