starte en sub i et andet program

Jeg trot bare det er den kode her du mener...


'-------------------------------------- Form1 --------------------------------------
Option Explicit

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function ShowWindow Lib "user32" (ByVal hWnd As Long, ByVal nCmdShow As Long) As Long
Private Declare Function IsIconic Lib "user32" (ByVal hWnd As Long) As Long
Private Declare Function GetForegroundWindow Lib "user32" () As Long
Private Declare Function SetForegroundWindow Lib "user32" (ByVal hWnd As Long) As Long
Private Declare Function BringWindowToTop Lib "user32" (ByVal hWnd As Long) As Long

Private Const SW_SHOW    As Long = 5
Private Const SW_RESTORE As Long = 9

' Her skriver du navnet på dit program som skal stå i vinduet.
Private Const APP_CAPTION As String = "Mit program"

Private Sub Form_Load()
Dim lhwnd As Long
  'PrevInstance vil give true hvis programmet er startet.
  If App.PrevInstance Then
    ' Her setter vi navnet på vinduet (Program start 2) til "$" så vi ikke _
      finde (Program start 1).
    Me.Caption = "$"

    ' Her finder vi det vindue med APP_CAPTION. (Program start 1)
    lhwnd = FindWindow(vbNullString, APP_CAPTION)

    ' Hvis (Program start 1) ikke er i fokus
    If lhwnd <> GetForegroundWindow() Then
      If IsIconic(lhwnd) Then
        ' Hvis (Program start 1) er minimeret
        Call ShowWindow(lhwnd, SW_RESTORE)
          Else
        ' Hvis (Program start 1) er skjult
        Call ShowWindow(lhwnd, SW_SHOW)
      End If
    End If

    ' Løfter (Program start 1) til top og setter det i fokus.
    Call BringWindowToTop(lhwnd)
    Call SetForegroundWindow(lhwnd)

    ' Her afslutter vi (Program start 2) med End og ikke med Unload _
      da Unload ikke er hurtig nok til at afslutte programmet _
      vil den få en halv fokus.
    End
  End If

  ' Hvis PrevInstance give false så er det første gang programmet starter _
    og vi sette navnet på vinduet. (Program start 1)
  Me.Caption = APP_CAPTION
 
  '**** Her fra kan du indtaste rasten af den kode i dit program som skal køre under opstart ****




  '**********************************************************************************************
End Sub
'-------------------------------------- Form1 --------------------------------------

den her skal lyde sådan ;)

    ' Her setter vi navnet på vinduet (Program start 2) til "$" så vi _
      finde (Program start 1 APP_CAPTION).

Spg, 521000. Nice =)