Pivot tabel cacher gamle tabelpost værdier

hvilken xl-version ?

nååe, her er en kode der gør at du ikke er nødt til at genopbygge pivoten
Fjerner missingitems på det aktuelle ark.

Sub CleanPivotItems()

    Dim pt As PivotTable, pf As PivotField, pi As PivotItem
    Dim booShowMsg As Boolean, mbxResult As VbMsgBoxResult, msg As String

    booShowMsg = True
    On Error GoTo ErrorHandler

    For Each pt In ActiveSheet.PivotTables
        For Each pf In pt.PivotFields
            For Each pi In pf.PivotItems
                If pi.RecordCount = 0 And pi.IsCalculated = False Then pi.Delete
            Next pi
        Next pf
    Next pt
    Set pi = Nothing
    Set pf = Nothing
    Set pt = Nothing
    Exit Sub

ErrorHandler:

    If booShowMsg Then
        msg = "Macro kunne ikke slette et emne." & vbCr
        msg = msg & "En grund kunne være at at den engang har været en del af en gruppering," & vbCr
        msg = msg & "eller at det (tom) " & vbCr
        msg = msg & "Click [CANCEL] for at undgå yderligere fejlmeddelelser."
        mbxResult = MsgBox(msg, vbExclamation + vbOKCancel, "Fejl ved sletning")
        booShowMsg = (mbxResult = vbOK)
    End If
    Resume Next
End Sub


hvis du bruger excel-XP eller xl2003 er denne bedst

Sub CleanPivotItems2()
'_______________________________________________________________________
' Note: Denne kode behøver kun at køre een gang.  Efter at .MissingItemsLimit er blevet sat til
' xlMissingItemsNone, vil man kunne nøjes med et alm. REFRESH for at fjerne "døde" emner.

    Dim pt As PivotTable

    For Each pt In ActiveSheet.PivotTables
        pt.PivotCache.MissingItemsLimit = xlMissingItemsNone
        pt.PivotCache.Refresh
    Next pt

    Set pt = Nothing

End Sub

Det er Excel 2003 DK SP1.

Jeg tester i morgen på arb.

Jeg er meget taknemmelig, hvis det er så let!

Husk lige at refreshe pivoten inden du kører makroen

har du fået checkket ?

Sorry - har glemt spm. Det fungerer som en drøm. Smid et svar :-)

oki... bedre sent end aldrig :-)