Finde ud af hvilket OU computeren ligger i via et Script

Det kan du gøre vha. LDAP... prøver lige at finde et ex.

Her er et ex. der let kan modificeres:

http://www.microsoft.com/technet/community/scriptcenter/compmgmt/scrcm12.mspx

Du tilføjer blot en "WHERE Name=din_computer" clause til SELECT sætningen.

Og det kan godt køre fra en klient?

Jeg må desværre sige at det ikke helt virker..

Den viser ikke hvilken OU computer ligger i, men den viser hvad der stå i det felt i AD'en, som hedder Location

Set WshNetwork = CreateObject("Wscript.Network")
Set objTrans = CreateObject("NameTranslate")
strDomain = WshNetwork.UserDomain
strComputer = WshNetwork.computerName

objTrans.Set 3, strDomain & "\" & strComputer & "$"
strComputerDN = objTrans.Get(1)
Set objComputer = GetObject("LDAP://" & strComputerDN)

parentPath = objComputer.Parent
Set parent = GetObject(parentPath)

intParentLength = Len(parent.Name)
intEqualIs = InStr(parent.Name, "=")
intTruncate = intParentLength - intEqualIs
strParentOU = Right(parent.Name, intTruncate)

WScript.Echo strParentOU

tpo > Kan se at det virker, men nu er det sådan at min AD er bygged op med under OU'er, og den viser kun det under OU'en. Hfvis vi nu siger at min ad se sådan her ud.
Domain > Danmark > Fyn > Computer > Computer_name

Mit problem er at den bare viser computer, men jeg vil gerne have at den viser Fyn

Kan ikke selv lige se mig ud af kode, og finde ud af hvordan man gør.

Så håber du vil hjælpe

Set WshNetwork = CreateObject("Wscript.Network")
Set objTrans = CreateObject("NameTranslate")
strDomain = WshNetwork.UserDomain
strComputer = WshNetwork.computerName

objTrans.Set 3, strDomain & "\" & strComputer & "$"
strComputerDN = objTrans.Get(1)
Set objComputer = GetObject("LDAP://" & strComputerDN)

parentPath = objComputer.Parent

WScript.Echo parentPath

OUArray = Split(parentPath, ",", -1, 1)
For i = LBound(OUArray) To UBound(OUArray)
  P = InStr(OUArray(i), "OU=")
  If P >0 Then
    WScript.Echo Right(OUArray(i),Len(OUArray(i))-InStr(OUArray(i), "="))
    OUPath = OUPath & Right(OUArray(i),Len(OUArray(i))-InStr(OUArray(i), "=")) &" "
  End If
Next

OUPath = OUPath & strComputer
WScript.Echo OUPath

Det virker bare som det skal...
Men hvis du lige kan hjælpe med en mere..
Hvad så med en user/bruger??? Har prøvet at rette lidt i det, men kan ikke finde ud af det...
Kan du hjælpe med den også???

Her er lidt at "lege" med


Set oADsRootDSE = GetObject("LDAP://RootDSE")
Set oADsSysInfo = CreateObject("ADSystemInfo")
sADsUser = oADsSysInfo.UserName
sUserPath = "LDAP://" & sADsUser
Set oADsContainer = GetObject(sUserPath)

Fornavn = oADsContainer.givenName
Efternavn = oADsContainer.sn

WScript.Echo Fornavn
WScript.Echo Efternavn
WScript.Echo sADsUser
WScript.Echo sUserPath

OUArray = Split(sUserPath, ",", -1, 1)
For i = LBound(OUArray) To UBound(OUArray)
  P = InStr(OUArray(i), "OU=")
  If P >0 Then
    WScript.Echo Right(OUArray(i),Len(OUArray(i))-InStr(OUArray(i), "="))
    OUPath = OUPath & Right(OUArray(i),Len(OUArray(i))-InStr(OUArray(i), "=")) &" "
  End If
Next

OUPath = OUPath
WScript.Echo OUPath

Set oADsRootDSE = Nothing
Set oADsSysInfo = Nothing
Set oADsContainer = Nothing

Du er jo slet ikke så dum....
Jeg takker mange gange...