Automatisk URL

Hvis du har [url] omkring kan regular expression bruges:

set regcon = new RegExp
regcon.pattern = "\[url\](.*?)\[\/url\]"
regcon.ignoreCase = true
regcon.Global = true
tekst = regcon.replace(tekst, "<a href=""$1"">$1</a>")


Sprøgsmålet er så om der er http:// i linket eller om det også skal med, eller begge to kan forkomme?
[url]http://www.eksperten.dk[/url]
[url]www.eksperten.dk[/url]

ja.. men vil helst undgå det...
Bruger ellers den version lige nu...

Den kan udvides så den ikke kigger på http:// og selv sætte der ind:


set regcon = new RegExp
regcon.pattern = "\[url\](http:\/\/|)(.*?)\[\/url\]"
regcon.ignoreCase = true
regcon.Global = true
tekst = regcon.replace(tekst, "<a href=""http://$2"">$2</a>")

vil helst ikke have [url] [/url] med

arh på den måde ;)


Du skal havde en function som kan lave links i tekst om til klikbare links:

Der har været en konkurrence på www.netkoders.dk og vinder script er her:
http://www.netcoders.dk/sources.asp?mode=view_source&cat_id=9&id=859&tech_id=1

Runner ups:
http://www.netcoders.dk/sources.asp?mode=view_source&cat_id=9&id=860&tech_id=1


Jeg bruger har selv brugt denne som laver www adresse adresse om til trykbare links.


Function LinkString2(strInput)
Set objRegExpHTTP1 = New RegExp
objRegExpHTTP1.Global = True
objRegExpHTTP1.IgnoreCase = True

objRegExpHTTP1.Pattern = "(http|ftp|https)(:\/\/[\w]+)(.[\w]+)([\w\-\.,@?^=%&:/~\+#]*[\w\-\@?^=%&/~\+#])?"
strOutput = objRegExpHTTP1.Replace(strInput, "<a href='$1$2$3$4' target='_blank'>$1$2$3$4</a>")

objRegExpHTTP1.Pattern = "(^|[^\/])(www)(.[\w]+)([\w\-\.,@?^=%&:/~\+#]*[\w\-\@?^=%&/~\+#])?"
strOutput = objRegExpHTTP1.Replace(strOutput, " $1<a href='http://$2$3$4' target='_blank'>$2$3$4</a>")

set objRegExpHTTP1 = Nothing

LinkString2 = strOutput
End Function

Skal den både lave www og email adresse om til linkse kan det se sådan her ud:


Function LinkString22(strInput)
Set objRegExpHTTP1 = New RegExp
Set objRegExpHTTP2 = New RegExp
Set objRegExpEMail = New RegExp

objRegExpHTTP1.Pattern = "(http|ftp|https)(:\/\/[\w]+)(.[\w]+)([\w\-\.,@?^=%&:/~\+#]*[\w\-\@?^=%&/~\+#])?"
objRegExpHTTP2.Pattern = "(^|[^\/])(www)(.[\w]+)([\w\-\.,@?^=%&:/~\+#]*[\w\-\@?^=%&/~\+#])?"
objRegExpEMail.Pattern = "([\w\._-]+@[\w\._-]+\.[A-Za-z]{2,3}\S*)"

objRegExpHTTP1.Global = True
objRegExpHTTP2.Global = True
objRegExpEMail.Global = True

objRegExpHTTP1.IgnoreCase = True
objRegExpHTTP2.IgnoreCase = True
objRegExpEMail.IgnoreCase = True

strOutput = objRegExpHTTP1.Replace(strInput, "<a href='$1$2$3$4' target='_blank'>$1$2$3$4</a>")
strOutput = objRegExpHTTP2.Replace(strOutput, " $1<a href='http://$2$3$4' target='_blank'>$2$3$4</a>")
strOutput = objRegExpEMail.Replace(strOutput, " <a href='mailto:$1'>$1</a> ")

Set objRegExpHTTP2 = Nothing
set objRegExpHTTP1 = Nothing
Set objRegExpEMail = Nothing

LinkString22 = strOutput
End Function

eagleeyes du mener vel http://netcoders.dk

haha.. ja naturligvis det gik vist lidt for hurtigt :)

takker :)
det virker :)
smid lige et svar :)

Ok ;)