Batch script med argumenter [optional]

Man kunne starte med noget i stil med:

@echo off
setlocal
set SOpt=
set POpt=
set Arg1=

:Start
if [%1]==[] goto Done
set XXX=%1

if %XXX:~0,1%==- (
  if [%XXX:~1,1%]==[s] (
    set SOpt=%XXX:~2%

  ) else (
    if [%XXX:~1,1%]==[p] (
      set POpt=%XXX:~2%
    ) else (
      echo Unknown option: %XXX%
    )
  )
) else (
  if [%Arg1%]==[] (
    set Arg1=%XXX%
  ) else (
    echo Arg1 has been set
  )
)
shift
goto Start

:Done

if not [%SOpt%]==[] echo S: %SOpt%
if not [%POpt%]==[] echo P: %POpt%
if not [%Arg1%]==[] echo Arg1: %Arg1%

Undskyld det sene svar. Det virker lige som det skal! Tak for hjælpen.

Vil du have point, må du lige svare, så skal jeg med glæde give dig dem.

Jeg har lige et lille tillægsspørgsmål:

Jeg har lavet dette script. Formålet med det er, at løbe en tilfældig streng igennem og skriver det pågældende bogstav ud. Problemet er bare, at det ikke virker for strenge med længden 1. Dvs ex "DOpt=1".

Hvordan får jeg den til det?

(Hvor mange flere point vil du have for det?)

@echo off
set DOpt=12
    :dimLoop
    echo %DOpt%
    echo %DOpt:~0,1%
    set DOpt=%DOpt:~1%

    if [%DOpt:~1,1%]==[] (
        echo STOP
        goto stopall
    )
    goto dimLoop
:stopall

Måske:

@echo off
set DOpt=12
:dimLoop
echo %DOpt:~0,1%
if [%DOpt:~0,1%]==[%DOpt%] (
  echo STOP
  goto :stopall
)
set DOpt=%DOpt:~1%
goto dimLoop
:stopall

Jeg samler ikke på point, så mine svar er gratis.

Lækkert. Jamen så vil jeg da bare sige tusind tak. Nu virker det perfekt!!

...og lige et svar -> SE BERTELBRANDER