Timer til film

drop denne behavior på et text eller field member, så viser den dig movietime på din video:

-- MAB videoTime updater v1.1
-- 29-Aug-01 converted to use framesToHMS and allow for QT

property pMember
property pVidSprite

on beginSprite me
  pMember = sprite(me.spriteNum).member
  member(pMember).text = "00:00:00"
end

on exitFrame me
  currTime = sprite(pVidSprite).movieTime
  if currTime mod 60 < 5 and (currTime > 0) then
    -- update just once per second (with some slop tolerance)
    me.mUpdateTime(currTime)
  end if
end

on mUpdateTime me, aTime
  hms = framesToHMS(aTime, 60, 0, 0)
  -- hours:minutes:seconds
  hms = hms.char[2..9]
  -- for only minutes and seconds, comment the line above
  -- and uncomment the line below
  --  hms = hms.char[5..9]
  pMember.text = hms
end

on getPropertyDescriptionList me
  if the currentSpriteNum < 1 then exit
  pList = [:]
  vidList = me.findVideoSprites()
  pList[#pVidSprite] = [#comment:"Video sprite number:"]
  pList[#pVidSprite][#format] = #integer
  pList[#pVidSprite][#default] = vidList[1]
  pList[#pVidSprite][#range] = vidList
  return pList
end


on findVideoSprites
  outList = []
  repeat with i = 1 to the lastChannel
    theType = sprite(i).member.type
    if theType = #digitalVideo or theType = #quickTimeMedia then
      outList.add(i)
    end if
  end repeat
  return outList
end

on getBehaviorDescription me
  tmpTxt = "Drop this onto a text or field member sprite to show the video time." &RETURN
  tmpTxt = tmpTxt &"Requires a quickTime or AVI sprite."
  return tmpTxt
end

ja det skulle vist have været et svar...

Jeg ved ikke lige om det virker da det hele ligger ude på skolen, men nu acceptere jeg :)

Tak skal du have ;)