Kopiere filer til ftp hvert 20 minut !

Er der slet ingen der har et forslag ??

(Jeg er ellers med på en lytter for noget af det samme...)

Det var dog utroligt.. kan det ikke laves eller er der bare ingen der har forstand på det ???

Standby - vent lige ~24 timer. Finder noget frem iaften... Hvis jeg husker det...

Evt. inspiration herfra: http://www.eksperten.dk/spm/539535

Det lyder bare kanon ;-)

Hmmm... Kører rundt i hovedet...
Skal det være i VB ?

En CMD programfil som ruller rundt ligesom i http://www.eksperten.dk/spm/539535 ???

Med ftp + mput (mulitput) ka' man putte flere file i ét hug, men hvad med subdirs ?

ftp stedet kan' måske "mappes" til et (netværks)drev ? Så vil goe' gamle XCOPY kunne bruges ?

Linket til CMD filen er det samme som dit første link :-)

Ja den skal kunne tage subdirs ellers duer det ikke..

eller måske gør det alligevel for den skal bare kopiere en fil der er navngivet efter dato eks. 14-04-05.csv

At mappe den til et netværks drev vil vel ikke fungere når forbindelsen til internettet er on / off flere gange ??

Jeg har denne kode der bare skal laves en timer på ligesom den af din, og så tilføjes noget ftp... det må da kunne lade sig gøre ???

option explicit
dim targetFolder,sourceFolder

sub log(msg)
    'msgBox msg
end sub

function Chk(sourceFolder,targetFolder)
    chk=true
    if not objFSO.FolderExists(sourceFolder) then
        MsgBox("Kan ikke åbne kilde : "&sourceFolder)
        chk=false
    end if

    if not objFSO.FolderExists(targetFolder) then
        msgBox("Kan ikke åbne destination : "&targetFolder)
        chk=false
    end if
end function

sub Quit()
    MsgBox "Forbindelsen til netværket afbrudt"
    WScript.Quit
end sub

sub doCopy(sourceFolder,targetFolder)
    dim folder,fileCol,folderCol,fil
    Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

    set folder = objFSO.getFolder(sourceFolder)
    set fileCol = folder.Files
    set folderCol=folder.SubFolders

    For Each fil in filecol
        if not objFSO.FileExists(targetFolder&"\"&fil.name) then
            objFSO.CopyFile SourceFolder&"\"&fil.name, targetFolder&"\"&fil.name
            If Err.Number = 0 Then
                log "Copying file: "&sourceFolder&"\"&fil.name
            else
              Quit()
            end if
        end if
    next   
    For Each folder in folderCOl
        if not objFSO.FolderExists(targetFolder&"\"&folder.name) then
            objFSO.CreateFolder(targetFolder&"\"&folder.name)
            If Err.Number = 0 Then
                log "Creating folder: "&sourceFolder&"\"&folder.name
            else
                Quit()
            end if

        end if
        doCopy sourceFolder&"\"&folder.name,targetFolder&"\"&folder.name   
    next   
    set fileCol = nothing
    set folderCol = nothing
    set folder = nothing
end sub

Dim objFSO,cont
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

sourceFolder="c:\source\"
targetFolder="c:\target\"


dim wshShell
Set WshShell = CreateObject("WScript.Shell")
WshShell.Popup "Begynder kopiering", 2, , 0

if (chk (sourceFolder,targetFolder)) then
    doCopy sourceFolder,targetFolder
    WshShell.Popup "Kopiering afsluttet", 2, , 0
end if

Nu har jeg ikke så meget "kørekort" vi VB men en kombination af din kode og "min" kode - andet har jeg ikke lige nu...

Generelt: Det kunne også være smart for dig at der oprettes en LOG fil med info om hvilke mapper/filer der er berørt samt tidspunkt (og om det gik godt) ...

Egentlig har jeg ik det vilde at bruge en log til, det drejer sig om en csv fil der skal uploades fra en bil med længdegrad & breddegrad sådan at man kan finde sin bil ;-)

Hovsa:
Er det samme fil(navn) / mappe der skal behandles hver gang ?
Det vil gøre tingene noget letterer ...

Nej det er datoen der er filnavn feks. idag: 14-04-05.csv

Hvis der IKKE er (nye) (under)mapper der skal copy/checkes men 'kun' løse filer i specifike mapper så er det letterer...

Kommentér lige dette...

Det er fint nok hvis det bare er i en fast mappe, og filnavnet med dato (15-04-05.csv)

så kan jeg altid ændre i koden til mappen hvis det skulle blive nødvendig !

Hmmm... ftp's put/mput vil copy uanset om filen er ændret eller ej...

Altså så skal der checkes om filen er ændret FØR noget som helst ftp 'ting' startes...

De her *.csv file/filer - bliver oprettet automatisk af noget andet SW ? Skriver dette SW til filen - selvom der egentlig ikke er nogen indholdsændring. Dvs ændre 'timestamp' ?

(Jeg ser på dette ind imellem andet tjenstligt arbejde...)

Det gør ikke noget at den uploader filen uanset hvad :-)

Hvis bare du kan lave så den kan uploade filen 15-04-05.csv til en ftp mappe så er det fint nok.

Softwaren skriver KUN til filen hvis der er ændringer

Undskyld forsinkelsen...

"Den skal kun kopiere de filer der er ændret hvis de allerede findes på serveren" - hvad mener du her ?

Dvs. hvis filen/filerne IKKE er ændret (indhold eller "TimeStamp"?) skal der ikke startes en FTP ?

Nej det er lige meget, hvis du mener det er nemmere hvis det kun er en enkelt fil der skal uploades tager jeg bare den løsning.

... ja prøv (alligevel) at rulle videre med hvad du allerede har.
Min evt. løsning bliver noget "kluddertæppe" system...

hva??

Jeg misforstod vist lige lidt - info følger.
Har været igang siden kl 03:00...

Jeg bryggede noget sammen - men det gav følgende spørgsmål/problem:
http://www.eksperten.dk/spm/611384
http://www.eksperten.dk/spm/611389
Har du måske noget på det ?

Kun gennemføre FTP når *.csv filen/filerne er blevet ændret ift. sidste FTP - godt nok...

.. det er tanken at EFTER en tilsyneladende vellykket FTP checke om filen virkelig kom igennem - ved at hente den tilbage og så sammenligne.

Tror ikke jeg har brugt dos til noget konkret programmering inden for de sidste 10 år... såeh, må nok melde pas til det.

Hvad blev der at Visual Basic Scripting ??

Ideén er med at tjekke filen efter upload er en kanon idé ;-)

... ligesom jeg heller ikke har 'kørekort' til VBS ... Selvom det på et eller andet plan (rædselsfuldt udtryk!) ser 'let' ud...

Nåeh ja... det forklarer jo en del ;-)

Så er ver. 0.9 lige ved at være der...

Spørgsmål:
Er det et nyt navn (automatisk?) for hver dag/dato: 15-04-05.csv ?

Og den bliver oprettet/ændret/opdateret automatisk af andet software ? Hver gang der sker en ÆNDRING eller bliver dens TimeStamp bare ændret under alle omstændigheder for hver X tidsenhed.
Det går om jeg skal "måle" på ÆNDRING i filen eller TimeStamp...


(Hvorfor er det altid sådan at noget man laver til andre bedre end det til sig selv ?)

Ja navnet bliver opdateret automatisk efter hvad dag det er.

hvordan softwaren ændrer i filen er jeg ikke lige klar over, men er da sikker på at den bliver x antal bytes større for hver gang ;-)

... det er bare mht. hvilken regel jeg skal bruge for at FTP'en skal rulle igang. Jeg ved godt at du skriver 20 min. men hvis jeg får forærende at gøre det hver gang at filen's indhold bliver ændret ?
Kan evt. også arrangere at FTP rulle hvert 20 min. (eller andet tal) HVIS filen's indhold er ændret ?

Jeg tror at jeg vil gøre sådan:
At hvert 20 min (kan ændres let) checkes om nyeste *.csv fil (kan ændres let) i en specific mappe (kan ændres let) er ændret ifh forrige check. Hvis den er ændret i indhold/størrelse eller for den sags skyld andet navn så rulles en FTP overførsel...

Kommentér lige ...

Jo det lyder meget godt... mappen er baseret på datoen også har jeg lige set, men det kan jo nemt ændres ik ?? (mener det er noget med %date%)

Hvis du kan lave det vil det bare være kanon !!

Nu har jeg selv løst problemet:

sleeptimer.vbs
option explicit
dim SleepTimer, BatchFile, FolderName, FTP, Username, Password, FTP_Folder

FTP = "ftp server"
Username = "account"
Password = "pass"
FTP_Folder = "folder"

SleepTimer = 10 


BatchFile = "ftpconn.bat"
FolderName = "c:\logs\"& Year(now) &"\"& Monthname(Month(now))
SleepTimer = SleepTimer * 1000

sub FtpIT()
      CreateObject("WScript.Shell").Run BatchFile&" "&FTP&" "&Username&" "&Password&" "&FTP_Folder&" "&FolderName&"\*.*", 0, False
end sub
Dim objFSO,cont

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

do
FtpIT
        WScript.Sleep SleepTimer
        Loop

ftpconn.bat:
@echo off
cls
echo open %1>c:\destinatorapps\gps_tracking\tranfer.txt
echo %2>>c:\destinatorapps\gps_tracking\tranfer.txt
echo %3>>c:\destinatorapps\gps_tracking\tranfer.txt
echo binary>>c:\destinatorapps\gps_tracking\tranfer.txt
echo prompt>>c:\destinatorapps\gps_tracking\tranfer.txt
echo hash>>c:\destinatorapps\gps_tracking\tranfer.txt
echo cd %4>>c:\destinatorapps\gps_tracking\tranfer.txt
echo mput %5>>c:\destinatorapps\gps_tracking\tranfer.txt
echo bye>>c:\destinatorapps\gps_tracking\tranfer.txt
echo bye>>c:\destinatorapps\gps_tracking\tranfer.txt
call ftp.exe -s:c:\destinatorapps\gps_tracking\tranfer.txt
del c:\destinatorapps\gps_tracking\tranfer.txt

er der nogen der kan komme med forslag til hvordan man får den til at lade være med at kopiere en fil der allerede er på serveren er de velkomne...

Stadig ikke lukket ;-)

<henriktha>:
Nu troede jeg lige at jeg havde den 99.9% klar - men min version 'dør' efter ~600 loops - læs i tråden her:
http://www.eksperten.dk/spm/611384

Der gik helt sport i det.
Jeg har svar/mulighed for din sidste kommentar - og lidt mere til...

Info følger...

Ja min har kørt siden jeg postede her sidst med 30 sekunders interval, og den kører endnu ;-)

Glæder mig da til at se hvad du har.....

Skal det være en MAPPE eller en FIL med formatet:
DD-MM-YYYY  (eks 24-04-2005)

Det er lettest med DD-MM-YYYY og ikke DD-MM-YY. Så er man også lidt mere sikker på hvad der er hvad når man bare ser tal...

Jeg har gjort det trix med at filer der ER blevet FTP'et OK bliver gemt i anden mappe. Derefter checkes om en given fil HAR været sendt før eller der er ÆNDRING i den ifh sidste FTP process...

Nej det duer ikke da en fil fra samme dato bliver opdateret kontinuerligt !

dd-mm-yy er formatet, det kan ikke ændres da det er fastlagt af programmet der laver csv filerne

Opbygningen af mappesystemet kan du jo se i min kode ovenfor:

c:\logs\yyyy\mmmm\*.csv (hvor * er dd-mm-yy)

... og jeg ka' forvente at ..\logs\yyyy\mmmm\dd-mm-yy altid findes / bliver automatisk oprettet "straks" ved døgnskift ?

Hvis der nu ikke har været FTP kontakt i X dage skal alle dagenes *.csv fil sendes når der opnås kontakt eller til enhver tid bare send den nyeste ?
Så jeg (=programmet) ka' bare 'søge' efter den nyeste *.csv fil under C:\logs\yyyy\mmmm\dd-mm-yy ?

PS: Det er vel C:\logs\yyyy\mm\ mappen hedder med tal - eller er 'mm' (måned) skrevet med bogstaver?

Altså sådan for denne dag C:\logs\2005\april\25-04-05.csv

Så er der 'kun' den med mappe strukturen tilbage...

Skal logfilen for dagen idag skrives som

C:\logs\2005\april\25-04-05.csv
C:\logs\2005\apr\25-04-05.csv
C:\logs\2005\04\25-04-05.csv

US eller DK (eller skal jeg checke for begge kombinationer ?)
Prøver at gøre det så universelt som muligt...

Sådan ser filen med den fulde sti ud for idag: C:\Logs\2005\april\04-25-2005_Log.csv

Det er nok bare den uploader den nyeste !!

Du skal lige DL disse to pakker
http://majsmarken.net/eksperten/607690/sleep.zip
samt
http://majsmarken.net/eksperten/607690/AutoUpload.zip
udpakkes til C:\Logs

@Echo off

REM ======================
REM AutoUpload.cmd
REM Ver 1.0
REM 26. april 2005
REM ======================

REM ======================
REM Variabel set (tilret efter behov)
REM ======================

set VerboseDebug=1

set FTP=ZZ.ZZZ.ZZZ.ZZ
set FTPopen=majsmarken
set FTPkode=XXXX
set FTPFolder=transport

set LoopWait=5
set FTPWait=30
set FTPRetryWait=10

set FilePath=C:\Logs

set FTPToSendFolder=%FilePath%\FtpToSend
set FTPCheckFolder=%FilePath%\FtpCheck
set FTPIsSendFolder=%FilePath%\FtpIsSend

set FTPIncommingFolder=

set FTPCommandFile=%TEMP%\_upload.ftp

set Newest=

set Day=
set Mon=
set MonthName=
set Year4=

REM ======================

CLS
echo ======================
echo AutoUpload running...
echo ======================
echo.

if NOT exist %FilePath%\ (
  echo Mappen %FilePath% blev ikke fundet ?
  goto ERROR
)

if NOT exist %FilePath%\sleep.exe (
  echo Filen/programmet  Sleep.exe  blev ikke fundet ved %FilePath%
  goto ERROR
)

if NOT exist %FTPToSendFolder%\ (
  echo Mappen %FTPToSendFolder% blev ikke fundet ?
  goto ERROR
)

if NOT exist %FTPCheckFolder%\ (
  echo Mappen %FTPCheckFolder% blev ikke fundet ?
  goto ERROR
)

if NOT exist %FTPIsSendFolder%\ (
  echo Mappen %FTPIsSendFolder% blev ikke fundet ?
  goto ERROR
)

REM ======================

:LOOP

REM * Extract dato felter
for /F "tokens=1-3 delims=-" %%A in ("%date%") do set Year4=%%C& set Mon=%%B& set Day=%%A
if %Mon:~0,1%==0 (
  set MM=%Mon:~-1%
) else (
  set MM=%Mon%
)
for /F "tokens=%MM%" %%I in ("Jan Feb Marts April Maj Juni Juli August Oktober November December") do set MonthName=%%I

set FTPIncommingFolder=%FilePath%\%Year4%\%MonthName%

if not exist %FTPIncommingFolder%\ (
  if %VerboseDebug%==1 echo The folder %FTPIncommingFolder% is not found.
  goto WAITLOOP
  )

:CHECKNEW
set Newest=
if %VerboseDebug%==1 echo Checking for NEWEST file in %FTPIncommingFolder%
for /F "tokens=*" %%I in ('dir %FTPIncommingFolder% /D /B /A-D /O-D') do call :Process %%I
if [%Newest%]==[] (
  if %VerboseDebug%==1 echo The folder %FTPIncommingFolder% is empty.
  if %VerboseDebug%==1 echo Do notting.
  goto WAITLOOP
) 
if %VerboseDebug%==1 echo The NEWEST file in %FTPIncommingFolder% is %FTPIncommingFolder%\%Newest%
goto ENDCHECKNEW

:Process
if NOT [%Newest%]==[] goto :eof
set Newest=%1
goto :eof

:ENDCHECKNEW

if %VerboseDebug%==1 echo Checking for a NEW file.
if not exist %FTPIsSendFolder%\%Newest% (
  if %VerboseDebug%==1 echo File %FTPIncommingFolder%\%Newest% IS a new file.
  if %VerboseDebug%==1 echo Has NOT been send before.
  copy %FTPIncommingFolder%\%Newest% %FTPToSendFolder%\%Newest% >nul
  goto FTP_CHECK
)

if %VerboseDebug%==1 echo File %FTPIncommingFolder%\%Newest% has been send before.
if %VerboseDebug%==1 echo Checking for update.
echo n | comp %FTPIncommingFolder%\%Newest% %FTPIsSendFolder%\%Newest% >nul 2>&1
if errorlevel 1 (
  if %VerboseDebug%==1 echo File %FTPIncommingFolder%\%Newest% has been updated since last send.
  copy %FTPIncommingFolder%\%Newest% %FTPToSendFolder%\%Newest% >nul
  goto FTP_CHECK
) else (
  if %VerboseDebug%==1 echo File %FTPIncommingFolder%\%Newest% has NOT been updated since last send.
  if %VerboseDebug%==1 echo Do notting.
)

:WAITLOOP
if %VerboseDebug%==1 echo.
echo Loop %LoopWait% sek.
%FilePath%\sleep.exe %LoopWait%
goto LOOP

:FTP_CHECK
REM ======================
REM Check om der er forbindelse til pågældende FTP server sted
REM ======================
echo Checking Internet connection to FTP-server: %FTP% ...
ping -n 1 %FTP% >nul 2>&1
if errorlevel 1 (
  if %VerboseDebug%==1 echo No response from %FTP%
  if %VerboseDebug%==1 echo Trying again in %FTPWait% sec.
  %FilePath%\sleep.exe %FTPWait%
  goto FTP_CHECK
) else (
  if %VerboseDebug%==1 echo OK response from %FTP%
  goto FTP_DO
)

:FTP_DO
REM ======================
REM Indledende manøvre til FTP afsendelse/modtagelse
REM ======================
if %VerboseDebug%==1 echo Transmiting file %FTPToSendFolder%\%Newest% to FTP-Server: %FTP%
if exist %FTPCheckFolder%\%Newest% del %FTPCheckFolder%\%Newest%
if exist %FTPCommandFile% del %FTPCommandFile%

echo open %FTP%>> %FTPCommandFile%
echo %FTPopen%>> %FTPCommandFile%
echo %FTPkode%>> %FTPCommandFile%
echo verbose>> %FTPCommandFile%
echo hash>> %FTPCommandFile%
echo binary>> %FTPCommandFile%
echo cd %FTPFolder%>> %FTPCommandFile%
echo put %FTPToSendFolder%\%Newest%>> %FTPCommandFile%
echo lcd %FTPCheckFolder%>> %FTPCommandFile%
echo get %Newest%>> %FTPCommandFile%
echo bye>> %FTPCommandFile%

REM ======================
ftp -i -s:%FTPCommandFile%
REM ======================

if exist %FTPCommandFile% del %FTPCommandFile%

REM ======================
REM Check om det er gået godt - sammenligne oprindelige fil med den der blev afsendt og hentet igen.
REM ======================
if %VerboseDebug%==1 echo Checking FTP reslut.
if not exist %FTPCheckFolder%\%Newest% (
  if %VerboseDebug%==1 echo Receive Failed...
  if %VerboseDebug%==1 echo Trying again in %FTPRetryWait% sec.
  %FilePath%\sleep.exe %FTPRetryWait%
  goto FTP_CHECK
)

if %VerboseDebug%==1 echo Comparing transmited file with received file.
echo n | comp %FTPToSendFolder%\%Newest% %FTPCheckFolder%\%Newest% >nul 2>&1
if errorlevel 1 (
  if %VerboseDebug%==1 echo Files NOT identical!!!
  if %VerboseDebug%==1 echo Trying again in %FTPRetryWait% sec.
  %FilePath%\sleep.exe %FTPRetryWait%
  goto FTP_CHECK
) else (
  if %VerboseDebug%==1 echo Files identical.
  goto ALL_DONE
)

REM ======================
REM Alle er glade
REM ======================

:ALL_DONE
if %VerboseDebug%==1 echo.
if %VerboseDebug%==1 echo Transmiting file %FTPToSendFolder%\%Newest% to FTP-Server: %FTP%
if %VerboseDebug%==1 echo * * * DONE * * *
if %VerboseDebug%==1 echo.
if %VerboseDebug%==1 echo Cleaning up...
copy %FTPToSendFolder%\%Newest% %FTPIsSendFolder%\%Newest% >nul
del %FTPToSendFolder%\%Newest%
del %FTPCheckFolder%\%Newest%

goto WAITLOOP

:ERROR
echo.
echo PROGRAM TERMINATED !!!
echo.
pause

REM ======================
REM AutoUpload.cmd
REM Ver 1.0
REM 26. april 2005
REM ======================

Definer efter opgave disse variable
set FTP=XX.XXX.XXX.XX
set FTPopen=(Bruger)         
set FTPkode=(Kode)
set FTPFolder=(Evt.undermappe på FTPServer)

set VerboseDebug=1  Betyder at der vises diverse beskeder under kørsel af programmet til evt. DEBUG
- ellers set VerboseDebug=0


Checker om diverse mapper existere. Kan omdefineres.

Programmet  sleep.exe  skal existere.

Ud fra dagens dato extracter mappe navn ifølge syntaxen
C:\Logs\YYYY\MM\
hvor MM er månednavnet stavet (DK)
lægges i variablen %FTPIncommingFolder%

Checker om der er kommet en NY fil i %FTPIncommingFolder% som ikke har været sendt før - sammenlignet med %FTPIsSendFolder%
Hvis den HAR været sendt før - checker om ændring

Hvis ingen ændring så LOOP i %LoopWait% sekunder

Hvis dermed NY fil eller ændring så copy ønsket fil til %FTPToSendFolder%

Check om der er forbindelse til defineret FTP server %FTP% vha en 'ping'
- hvis ingen forbindelse så prøv igen efter %FTPWait% sekunder.

Hvis forbindelse klargør en FTP kommandofil %FTPCommandFile%

Rul %FTPCommandFile% vha 'ftp -t'
I denne sekvens tilbageføres samme fil vha 'get' til lokal mappe %FTPCheckFolder%

Sammenlign modtaget fil i %FTPCheckFolder% med den afsendte i %FTPToSendFolder%
Hvis ikke ens så gentag ftp processen efter %FTPRetryWait% sekunder

copy %FTPToSendFolder% til %FTPIsSendFolder% så den 'huskes' til næste LOOP

Oprydning...

PYHA - nærlæs README.TXT filen ...

Diverse mapper skal existere - der checkes efter dette.
Disses placering/navn kan evt. (om)definere i *.CMD filen/programmet

...jeg ser først min E-mail sent imorgen aften...

<henriktha>: Øhhh - Hvad endte denne 'tråd' med ???

Sorry du måtte vente så længe, er lige kommet fra ferie Ahh... ;-)

Det ser ud som om det virker, men hva med at få den skjult ??

Hey, du har aldrig smidt et svar her ??? (Det virker sku kanon)

Der er nu en rettelse jeg gerne vil have lavet hvis du har lyst ;-)
(Skal self nok give fler points)

ping...

(Bare kom med det...)

Jo... det ville være kanon hvis man kunne lave så den uploadede alle de filer i mappen der ikke fandtes på serveren, for hvis den ikke har haft ftp forbindelse og der skiftes dato mangler man jo en log fil.

Er det noget du kan lave ??

He he... kunne lige se at du egentlig havde nævnt den funktion i "25/04-2005 18:30:55"

Man blir jo klogere ;-)

Jeg må lige 'grave' sagen frem igen - også fra baggrundslager i hovedet...