liste over foldere med størrelse.

Man kunne bruge en bat fil i stil med:
@echo off

for /F "delims=;" %%I in ('dir /b /ad') do call :ProcessFolder "%%I"
goto :eof

:ProcessFolder
pushd %1
set Sum=0
for /F "delims=;" %%Z in ('dir /b "*" 2^>nul') do call :AddFolder %%~zZ
echo %~1 %Sum%
popd
goto :eof

:AddFolder
set /A Sum=%Sum% + %1

Det ser jo fint ud, men der summeres kun filerne i den underliggende folder. Jeg har brug for en sammentælling på hele den underliggende folderstruktur. F.eks har jeg ca 20 foldere på mit c drev og der vil jeg gerne have et et tal pr. folder der dækker alle filer i den bagved liggende folderstruktur.

Endnu et ønske er at listen udskrives til en fil, formatteret så den er til at indlæse i et regne ark.

jo jo, ønsker er der nok af

pft

Hvis det skal være en ; sepereret .csv fil kaldet dirlist.csv:

@echo off
setlocal
set dest=dirlist.csv
if exist %dest% del %dest%

for /F "delims=;" %%I in ('dir /b /ad') do call :ProcessFolder "%%I"
goto :eof

:ProcessFolder
pushd %1
set Sum=0
for /F "delims=;" %%Z in ('dir /S /b /a-d  2^>nul') do call :AddFolder %%~zZ
popd
echo %~1;%Sum% >>%dest%
goto :eof

:AddFolder
set /A Sum=%Sum% + %1

Lige i øjet, læg et svar og der er point.

jeg får sommetider linien "Manglende operator".

Hvad betyder det?

Det er svært at gætte hvad det betyder.
Prøv at slette øverste linie (@echo off) og kør så kommandoen:
batfil.bat >log.txt 2>&1

(batfil.bat er navnet på bat-filen)

Så kan du åbne log.txt i f.ex. notepad og finde det sted hvor den skriver "Manglende operator".
Prøv så at kopiere 10-20 linier fra log.txt omkring det sted hvor den udskriver beskeden og sæt dem ind her, så kan jeg sansynligvis regne ud hvad det betyder.

lukker