Siden kan ikke vises: Typer stemmer ikke overens: 'Session'?

Prøv at vise koden i den påg. linie. Det er typisk fordi der er en uoverensstemmelse mellem to typer i en sammenligning, f.eks. hvis du sammenligner en streng med en NULL-værdi (det kunne jo ske hvis et felt i databasen var NULL)...

Linie 8: Session("inne") = True

lidt mere af koden:
<!--#include file="inc_settings.asp" -->
<%
Dim user, password, connect,RSlogin,rsgast,intupdate,rsupdate,strnamn,strurl,stremail,strMeddelande,stranswer,inttabort
user = Request.Form("user")
password = Request.Form("password")
Set RSlogin = connect.Execute("Select * From Login Where user = '"&user&"' And password = '"&password&"'")
If Not RSlogin.EOF Then
Session("inne") = True
end if
if Session("inne") = True then
%>
<%
Response.buffer=True
%>

osv.

Og inc_settings.asp:

<%
Response.buffer=True
Set Connect = Server.CreateObject("ADODB.Connection")
Connect.Open "Driver={Microsoft Access Driver (*.mdb)}; DBQ=" & server.mappath("db.mdb")
%>

db.mdb:
Tabellen login:
User: admin
password: admin

Så alting stemmer, så vidt jeg kan se...

Prøv:

if CBool(Session("inne")) = True then

Kan dog sagtens give en fejl hvis Session("inne") ikke indeholder en valid boolsk værdi...

Hmmm... det hjælper desværre ikke. Måske det har noget med serveren (IIS) at gøre?

Har lige prøvet at rette lidt i din kode og vil bede dig prøve den i stedet for din egen:

<!--#include file="inc_settings.asp" -->
<%
Dim user, password, connect, RSlogin, rsgast
Dim intupdate, rsupdate, strnamn, strurl
Dim stremail, strMeddelande, stranswer, inttabort
Dim sql

on error resume next
Session("inne") = "False"
if err.number <> 0 then
  Response.Write "Fejl under tildeling af Session-variabel: " & err.number & " / " & err.description & "<br>"
  err.clear
end if

user = Request.Form("user")&""
password = Request.Form("password")&""
sql = "Select * " & _
    "From [Login] " & _
    "Where [user] = '"&replace(user,"'","''")&"' " & _
    "And [password] = '"&replace(password,"'","''")&"'"

Response.Write "SQL: " & sql & "<br>"
Set RSlogin = connect.Execute(sql)

if err.number <> 0 then
  Response.Write "Fejl under opslag i databasen: " & err.number & " / " & err.description & "<br>"
  err.clear
else
  If Not RSlogin.EOF Then
    Session("inne") = "True"
  else
    Response.Write "Der fandtes ikke nogen bruger med disse oplysninger.<br>"
  end if
end if

Response.Flush
on error goto 0

if Session("inne") = "True" then
%>


Jeg har lagt nogle ekstra linier fejlhåndtering ind i din kode og så har jeg fjernet den Response.Buffer = True du havde efter din sidste if-sætning, da Response.Buffer, såvidt jeg husker, skal stå før noget som helst output i en ASP-fil - og den står jo allerede i din includefil).

Prøv at kaste ovenstående kode efter din IIS og se (og fortæl) hvad den skriver.

Hvis du bruger en lidt nyere version af Access database, kunne det i øvrigt godt være du skulle udskifte din connectionstring i includefilen med en mere up-to-date version, så det ikke er det der ligger og spøger i kulissen. Du kan f.eks. bruge denne i stedet:

"Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & server.mappath("db.mdb")

softspot:
Well... jeg har ikke lige haft tid til at chekke koden, men umiddelbart ser den fin ud. :-)
Kast venligst et svar herind, og jeg tildeler dig points.

Jamen, så får du et svar her :)

...sorry at jeg har "overset" dig, men jeg har haft ret travlt på det sidste. :-( Det er selvfølgelig ikke personligt ment. Derfor har jeg netop forhøjet points fra 30 til 60, for at understrege dette. :-)

Igen: Tak for hjælpen! :-)

Det skal du ikke tænke så meget over, jeg har ikke ligefrem siddet og trommet i bordet og ventet på at du gav point, ej heller ligget søvnløs (over det). Jeg regner med at folk tildeler point når de har tid... og det fik du da heldigvis (mest for din egen skyld) :)

Tak for point :)