Hente en fil direkte på serveren

Ja, du kan bruge WinHTTP komponenten
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/winhttp/http/winhttp_start_page.asp

Her er et eksempel:

<%
Dim whttp
Set whttp = Server.CreateObject("WinHttp.WinHttpRequest.5.1")
whttp.Open "GET","http://www.eksperten.dk/img/elogo.png"
whttp.Send

'# Filen ligger nu i whttp.ResponseBody; vi kan f.eks. udskrive den til vores response
Response.ContentType = "image/png"
Response.BinaryWrite(whttp.ResponseBody)
%>

Her er reference for WinHttpRequest objektet:
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/winhttp/http/winhttprequest.asp

Har kigget lidt på det, man kan ikke se hvordan den skal kunne gemme filen på serveren. Efter hvad jeg kan se, så udskriver dit eksempel blot filen til browseren. Jeg skal have filen gemt på serveren.

Jeg havde forstået at dit problem bestod i at hente filen fra serveren. Når først den er hentet, kan du jo gøre med den hvad du vil. Ændret eksempel, der skriver til fil isf. http response:
<%
const adTypeBinary = 1
const adModeReadWrite = 3
const adSaveCreateOverwrite = 2

Dim whttp, stream
Set whttp = Server.CreateObject("WinHttp.WinHttpRequest.5.1")
whttp.Open "GET","http://www.eksperten.dk/img/elogo.png"
whttp.Send


Set stream = Server.CreateObject("ADODB.Stream")
stream.Type = adTypeBinary
stream.Mode = adModeReadWrite
stream.Open
stream.Write(whttp.ResponseBody)
stream.SaveToFile Server.MapPath("/e.png"),adSaveCreateOverWrite
stream.Close
%>

Læg mærke til at du skal sørge for at ASP/IIS brugerkontoen har skriveadgang til det sted på serveren, du vælger at placere filen. Det er typisk IUSR_maskinnavn.

Takker. Hvad skal adSaveCreateOverwrite stå til hvis den ikke må overskrive filerne, men skal gemme dem under et andet navn?

Du kan bruge adSaveCreateNotExist som parameter hvis du ikke ønsker at overskrive eksisterende filer. Så sker der en fejl hvis du forsøger at overskrive filen, dvs. du er sikker på aldrig at komme til at overskrive filer.

const adSaveCreateNotExist = 1
.
.
.
stream.SaveToFile Server.MapPath("/e.png"),adSaveCreateNotExist


Men du er nødt til selv at kontrollere om filen findes, og evt. vælge et andet navn hvis den gør. Det er der ikke noget indbygget logik til. Det kunne eksempelvis gøres med et Scripting.FileSystemObject