hoppe til bestemt celle

Ved godt det ikke er VBA, men kan du ikke bruge genvejene.

Ctrl+Home --> springer til øverste venstre hjørne
Ctrl+End --> springer til nederste højre hjørne
End+pilene --> er også meget god til at bevæge sig rundt med, prøv at lege lidt med det.

Hvis det skal være B2, kan du stille dig i B2 og fryse rækker.

du kan også oprette et link i en celle

Gør evt. celle K32 aktiv
Skriv Top
med celle K32 aktiv, klik på 'Indsæt hyperlink'
vælg placer i dette dette dokument
vælg ark
skriv celle

eks. A1

hvis du ikke har knappen 'indsæt hyperlink', kan du finde
den i 'Indsæt' menuen

Tak for svar exelent, men jeg vil gerne have at det er i VBA med en knap..

Vil gerne have at scriptet hopper til cellen uden at skulle angive ark navnet

Indsæt denne kode i et modul. Denne kode laver en toolbar med en op og ned pil som du kan bruge.
Den blive indsat nederst i venstre hjørne af skærmen.
Toolbaren slettes når arket lukkes.
Du skal selv indsætte de to steder du ønsker at hoppe til
Jeg har valgt A1 og AX400

Option Explicit

Sub AddButtons()
Dim NewBtn As CommandBarControl
Dim TBar As CommandBar

  '  Create the toolbar
  On Error Resume Next
  CommandBars("NyToolbar").Delete
  On Error GoTo 0
  Set TBar = CommandBars.Add
  With TBar
      .Name = "NyToolbar"
      .Visible = True
      .Position = msoBarBottom
  End With

  Set NewBtn = CommandBars("NyToolbar").Controls.Add _
                (Type:=msoControlButton)
  With NewBtn
      .BeginGroup = True
      .Style = msoButtonIcon
      .FaceId = 2615
      .OnAction = "GotoTop"
      .Caption = "Gå til top"
  End With


  Set NewBtn = CommandBars("NyToolbar").Controls.Add _
                (Type:=msoControlButton)
  With NewBtn
      .Style = msoButtonIcon
      .FaceId = 2614
      .OnAction = "GotoBottom"
      .Caption = "Gå til bunden"
  End With
End Sub


Private Sub GotoTop()
  Application.Goto ActiveSheet.Range("A1"), True
End Sub

Private Sub GotoBottom()
  Application.Goto ActiveSheet.Range("AX400"), True
End Sub





Indsæt så denne i modulet ThisWorkBook

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    On Error Resume Next
    Application.CommandBars("NyToolbar").Delete
    On Error GoTo 0
End Sub

Private Sub Workbook_Open()
  Call AddButtons
End

Takker.....giv et svar og jeg giver points :-)

ok :-)