Udskrive i en tabel af 3x3

Her er noget kode som kan det, det skal lige rettes til at passe med din database:

<%
intPage = Request("page")
If isNumeric(intPage) = False Or intPage < 1 Then
    intPage = 1
End If

Set rs = Server.CreateObject("ADODB.RecordSet")
strDSN = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ="& Server.Mappath("db1.mdb")

strSQL = "SELECT * FROM tablenavn "
rs.Open strSQL, strDSN, 3

antalPrRow = 3 'Antal pr. række
antalRows = 3  'Antal rækker på siden
If Not (rs.BOF Or rs.EOF) Then
  rs.PageSize = antalPrRow * antalRows
  rs.AbsolutePage = intPage
  intRecCount = rs.PageSize
  intPageCount = rs.PageCount

  response.write "<table>"

  no_pr_row = 0 'Tæller som bruges til at tælle antal kolonner pr række
  Do While Not rs.EOF And intRecCount > 0
    if no_pr_row = 0 then
      response.write "<tr>"
    end if

    'Udskriv data her
    Response.Write "<td>" & rs("kolonnenavn") & "</td>"

    no_pr_row = no_pr_row + 1
    if no_pr_row = antalPrRow then
      no_pr_row = 0
      response.write "</tr>"
    end if
    intRecCount = intRecCount - 1
    rs.MoveNext
  Loop
  if no_pr_row > 0 then
    response.write "</tr>"
  end if
  response.write  "</table>"
End If
rs.Close
Set rs = Nothing


If Clng(intPage) > 1 Then
  Response.Write "<a href=""?page=" & intPage - 1 & """>Næste</a>"
Else
  Response.Write "Næste"
End If

Response.Write "&nbsp;&nbsp;"
For intNum = 1 To intPageCount
  Response.Write "<a href=""?page=" & intNum & """>" & intNum & "</a> "
Next

Response.Write "&nbsp;"
If Clng(intPage) < Clng(intPageCount) Then
  Response.Write "<a href=""?page=" & intPage + 1 & """>Forrige</a>"
Else
  Response.Write "Forrige"
End If
%>

Undskyld jeg først lukker nu, men havde helt glemt det. I mellemtiden har jeg dog selv fundet ud af hvordan den klares, men du får lige dine velfortjente point ;)

Tak for hjælpen ;)