udregning af antal timer mellem to klokkeslæt

Kan du mon bruge datediff...?

fra = "22:50"
til = "00:20"

if fra > til then
  til = formatDateTime(dateadd("d",1,now),1) & " " & til
else
  til = formatDateTime(now,1) & " " & til
end if
fra = formatDateTime(now) & " " & fra

arbejdstidminutter = datediff("n", fra, til)
arbejdetimer = int(arbejdstidminutter / 60)
arbejderminutter = arbejdstidminutter mod 60

Hejsa

hvad med:

<%
AntalTime = datediff("h","27-02-2006 12:30:00","27-02-´2006 14:35:00")
%>

\Dan

Det eksempel du har vist skal det ikke give 1,5 time?

softspot> giver fejl i linie 12 - der er arbejdstidminutter = datediff("n", fra, til)

http://www.1510.dk/abc/test.asp

dan > retunere bare tallet 2

http://www.1510.dk/abc/test2.asp

eagleeye > nej der er overarbejdsbetaling - ej, selvfølgelig skulle det have gøre det, bare mig der er træt vist.

Jeg kan se at jeg har lavet en fejl i den linie der sammensætter fra-datoen, den skal se således ud i stedet for:

fra = formatDateTime(now,1) & " " & fra

soft > stadig samme fejl

Sådan så:

fra = "22:50"
til = "00:20"

if fra > til then
  til = formatDateTime(dateadd("d",1,now),2) & " " & til
else
  til = formatDateTime(now,2) & " " & til
end if
fra = formatDateTime(now,2) & " " & fra

'response.Write fra & "<br>" & til & "<br>"
arbejdstidminutter = datediff("n", fra, til)
arbejdetimer = int(arbejdstidminutter / 60)
arbejdeminutter = arbejdstidminutter mod 60

response.Write "fra: " & fra & "<br>til: " & til & "<br>arbejdstid: " & right("00" & arbejdetimer,2) & ":" & right("00" & arbejdeminutter,2) & "<br>"

Man kunne også bruge denne metode:

fra = "22:50"
til = "00:20"

diff = datediff("n", fra, til)
if diff < 0 then
  diff = diff + 60*24
end if

arbejdetimer = int(diff / 60)
arbejdeminutter = diff mod 60
response.Write "<br><br>arbejdstid: " & right("00" & arbejdetimer,2) & ":" & right("00" & arbejdeminutter,2) & "<br><br>"

kan det passe det bliver noget møg at ligge disse tal sammen? altså de tider man får?

har ændret : til , men når jeg ligger arbejdstiderne sammen nu får jeg en fejl? Microsoft VBScript runtime error '800a000d'
Type mismatch: 'samlettid'

/abc/inc_timesedler.asp, line 106

det lykkeds sgu, soft ligger du et svar?

argh !!

Det giver kun 1:30 - skal jo skrive 1,5 time ...

http://www.1510.dk/abc/test.asp

01:30 er da en halvanden time :)

Det er fordi cygnet gerne vil havde minutterne i 100'dele, er det ikke rigtigt?

Du ganger bare minutterne med (100/60), evt også med int omkring:

arbejdeminutter = int((arbejdstidminutter mod 60) * (100/60))

Det er jo bare et spørgsmål om formatering. Du har jo antallet af minutter der er arbejdet i diff (i det sidste eksempel), så kan du jo bare dividere med det rigtige:

arbejdstid = cdbl(diff / 60)

for at få det som et kommatal.

min løsning blev:

fra = start
til = slut

diff = datediff("n", fra, til)
if diff < 0 then
  diff = diff + 60*24
end if

arbejdetimer = int(diff / 60)
arbejdeminutter = diff mod 60
arbejdeminutter = arbejdeminutter / 60 * 10
arbejdeminutter = Replace(arbejdeminutter, ",", "")

tid = arbejdetimer & "," & arbejdeminutter

smid et svar softsport :p

hvis du bare lige skrive til sidst hvordan det nu er man få 2 decimaler på et til - noget med format number...

Må jeg foreslå denne variation (den er lidt simplere):

fra = start
til = slut

diff = datediff("n", fra, til)
if diff < 0 then
  diff = diff + 60*24
end if

tid = formatNumber(diff/60,2)

wow - må jeg nok sige, den havde jeg ikke lige gennemskuet, og må indrømme jeg heller ikke helt forstår hvad der sker i den stump kode, men virke gør det sgu.

Har du noget dokumention for det der?

Jeps :D

Find først differencen mellem de to tider

    diff = datediff("n", fra, til)

Hvis fra er større end til (f.eks. 22:50 - 00:20) er differencen negativ

    if diff < 0 then

...skal der lægges et døgn til (dvs. det antal minutter der er i et døgn)

      diff = diff + 60*24

Omregn differencen til timer og formatter der tal med 2 decimaler

    tid = formatNumber(diff/60,2)


That's it!

Tak for point iøvrigt :)

tak for den store hjælp

Velbekomme :)