Gå til makro

Sæt denne i arkets modul, den er automatisk.

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Data() As Variant, I As Long
    If Target.Address = "$A$1" Then
        Data = Range("B1:B" & Range("B65536").End(xlUp).Row)
        For I = 1 To UBound(Data)
            If Data(I, 1) = Target.Value Then
                Range("B" & I).Select
                Exit Sub
            End If
        Next
        Target = "Ikke fundet"
    End If
End Sub

Tak for det hurtige svar.

Men jeg er ret ny i det her makro. Når jeg indsætter makroen i VBA så kan jeg ikke "køre makroen" (INTET NAVN ?)

Kan den desuden laves så den kan aktiveres ved at stå i celle A1 og trykke Enter ?

når du står på arket, skal du højreklikke på fanen, vælg vis programkode, der skal den være, og ikke i et modul

Nu fatter jeg hvordan det virker.

Perfekt.

Kom med et svar og tak for hjælpen.

et svar ;-))

Lige et lille bonusspørgsmål nu da jeg har brugt det i praksis.

Når den ikke kan matche værdien til kolonne b, så skriver den Ikke fundet, men så går excel i stå i ca. 10-15 sekunder???

Jeg har ændret så den kun søger til og med række 30.000 men det gør det ikke hurtigere.

Hvorfor gå det i stå når den ikke kan finde værdien ?

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Data() As Variant, I As Long
    If Target.Address = "$A$1" Then
        Data = Range("B1:B" & Range("B65536").End(xlUp).Row)
        For I = 1 To UBound(Data)
            If Data(I, 1) = Target.Value Then
                Range("B" & I).Select
                Exit Sub
            End If
        Next
        Application.EnableEvents = False
        Target = "Ikke fundet"
        Application.EnableEvents = True
    End If
End Sub

Det skulle være ordnet nu.

Du skriver: 'Jeg har ændret så den kun søger til og med række 30.000'

Den finder selv ud af hvor mange rækker du har i kolonne B, så du behøver ikke at rette.

Perfekt

Jeg takker endnu engang for de vise ord.