Forms (uden header)

ja da. Under Properties for din form skulle der gerne være noget ala BorderStyle, den sætter du bare til none

mcgoat ja i vb.. men ikke i vba ;)

men vi kan nok fuske den alivel.. :D


' Husk en CommandButton1

Option Explicit

Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
    (ByVal hWnd As Long, ByVal nIndex As Long) As Long

Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
    (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long

Private Declare Function SetWindowPos Lib "user32" (ByVal hWnd As Long, _
    ByVal hWndInsertAfter As Long, ByVal x As Long, ByVal y As Long, _
    ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _
    ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Const GWL_STYLE = (-16)
Private Const WS_CAPTION = &HC00000

Private Const SWP_FRAMECHANGED = &H20
Private Const SWP_NOMOVE = &H2
Private Const SWP_NOZORDER = &H4
Private Const SWP_NOSIZE = &H1

Private Sub CommandButton1_Click()
  Unload Me
End Sub

Private Sub UserForm_Initialize()
Dim hWnd As Long
Dim lStyle As Long
  Me.Caption = "VBA HIDDEN CAPTION"
  hWnd = FindWindow(vbNullString, Me.Caption)
  lStyle = GetWindowLong(hWnd, GWL_STYLE)
  lStyle = lStyle And Not WS_CAPTION
  Call SetWindowLong(hWnd, GWL_STYLE, lStyle)
  Call SetWindowPos(hWnd, 0, 0, 0, 0, 0, SWP_FRAMECHANGED _
  Or SWP_NOMOVE Or SWP_NOZORDER Or SWP_NOSIZE)
End Sub

ahh så ikke det var vba :)

cool