FSO se alle filer

Se alle filer med nedenstående
<%

function getFilesInArr(fFolder,fArray,fAmount,fFilter,fSort)
Dim rsFSO, objFSO, objFolder, File, fCount
  Const adInteger = 3
  Const adDate = 7
  Const adVarChar = 200
  redim fArray(6,0)
  Set rsFSO = Server.CreateObject("ADODB.Recordset")
  Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
  Set objFolder = objFSO.GetFolder(server.mapPath(fFolder))
  Set objFSO = Nothing
  With rsFSO.Fields
    .Append "Name", adVarChar, 200
    .Append "Type", adVarChar, 200
    .Append "DateCreated", adDate
    .Append "DateLastAccessed", adDate
    .Append "DateLastModified", adDate
    .Append "Size", adInteger
    .Append "TotalFileCount", adInteger
  End With
  rsFSO.Open()
 
  For Each File In objFolder.Files
    If (Left(File.Name, 1)) <> Exclude Then
      rsFSO.AddNew
      rsFSO("Name") = File.Name
      if instr(File.Name,".") then
          rsFSO("Type") = mid(File.Name,instrrev(File.Name,".")+1)
      else
          rsFSO("Type") = ""
      end if
      rsFSO("DateCreated") = File.DateCreated
      rsFSO("DateLastAccessed") = File.DateLastAccessed
      rsFSO("DateLastModified") = File.DateLastModified
      rsFSO("Size") = File.Size
      rsFSO.Update
    End If
  Next
  if fSort <> "" then
    rsFSO.Sort = fSort
  end if
  if fFilter <> "" then
    rsFSO.Filter = fFilter
  end if
  Set objFolder = Nothing
  rsFSO.MoveFirst()
  fCount = 0
  while not rsFSO.eof and (fCount < fAmount or fAmount=0)
    redim preserve fArray(6,fCount)
    fArray(0,fCount) = rsFSO("name")
    fArray(1,fCount) = rsFSO("Type")
    fArray(2,fCount) = rsFSO("DateCreated")
    fArray(3,fCount) = rsFSO("DateLastAccessed")
    fArray(4,fCount) = rsFSO("DateLastModified")
    fArray(5,fCount) = rsFSO("Size")
    rsFSO.MoveNext
    fCount = fCount + 1
  wend
end function

dim arr

'Hent filer fra bib1
call getFilesInArr("/Experten/787234/Mappe1", arr, 1, "", "DateCreated DESC ")
'Udskriv filerne i arrayet
Response.write "Nyeste fil fra Mappe1<br>"
for f=0 to ubound(arr,2)
  Response.write "<a href=""/Experten/787234/Mappe1/"& arr(0,f) &""">"& left(arr(0,f),instrrev(arr(0,f),".")-1) &"</a><br>"
next