Slet txt filer der ikke indeholder en sætning.

Det skulle nok kunne lade sig gøre.

- skal KRB opfattes som et selvstændigt ord?
- ligger filerne i samme mappe?
- skal der været noget "signal" om filer, der slettes?

Prøv, hvis muligt at sende en kopi af en af filerne til: pb@supertekst-it.dk

-KRB er en del af en sætning.
-Filerne ligger i samme mappe.
-Der behøves intet signal nej, men filerne må gernes flyttes til en undermappe der hedder Slettes, så man manuelt kan slette dem efterfølgende.

Sender lige en kopi af en fil.

jeg kan lave den, hvis supertekst af en eller anden grund ikke kan....

info[a]icode.dk


(som et selvstændig exe-program som du ligger i mappen og eksekverer)

::tjensen - har du office-pakken?

Jep, Office 2003

Ok - filen er ikke modtaget - er den afsendt?

Den burde være sendt ja. Men ellers er den har.
ftp://inkarneret.dk/inkarneret.dk/ftp/hep.txt

www.inkarneret.dk/ftp/hep.txt  ;)

Set!

Forudsætninger:
- I "hovedmappen" er .txt filerne placeret
- Der er oprettet en mappe med navnet "Slettes"
- Der oprettes et Word-dokument i hovedmappen, hvori følgende VBA-kode indlægges - ThisDocument(Alt+F11): - Koden påbegyndes når dokumentet åbnes.

Dim sti
Sub AutoOpen()
    sti = ActiveDocument.Path
    If Right(sti, 1) <> "\" Then
        sti = sti + "\"
    End If

    testFiler
End Sub
Private Sub testFiler()
Dim fs, f, fc, f1, linie
Dim KRBflag As Boolean

    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(sti)
    Set fc = f.Files
    For Each f1 In fc
        KRBflag = False
        If LCase(Right(f1.Name, 4)) = ".txt" Then
       
            Open sti + f1.Name For Input As #1
            While Not EOF(1) And KRBflag = False
                Line Input #1, linie
                KRBflag = findesKRB(linie)
            Wend
           
            Close #1
           
            If KRBflag = False Then
                FileCopy sti + f1.Name, sti + "Slettes\" + f1.Name
                Kill sti + f1.Name
            End If
        End If
    Next
End Sub
Private Function findesKRB(linie)
    If InStr(linie, "KRB") > 0 Then
        findesKRB = True
    Else
        findesKRB = False
    End If
End Function

Det virker jo bare lige efter hensigten!

Lidt underligt det lige er via word. Men alt det VBA
er en verden jeg kun lige er ved at sætte mig lidt ind i.
Så det er en kæmpe hjælp at sciptet netop er der igennem!

Mange tak!

Selv tak - du får et svar.
Det kunne også have været Excel. Jeg har kun Office-pakken hvortil jeg udvikler systemer - så derfor.

Det virker jo også ganske fint, så ingen problem! :)