Slette filer via vbs

Der findes ikke et directory der hedder "C:\Cognosdata\Temp" ?!

Det gør der, det er netop den som skal tømmes ;-)

/dan

Prøv at printe  overmappe.Name  lige inden linie 15

Hvad mener du?
Dette her er ikke lige min stærke side :-)

sæt en "print overmappe.Name" før linie 15

Hvad skal jeg nøjagtigt gøre?
Hvis jeg skriver: print overmappe.Name = Variable is undefined: 'print'
Hvis jeg skriver: "print overmappe.Name" = Expected statement

/dan

Ahh. man skal lære noget nyt hver dag :)


Wscript.Echo overmappe.Name

Ja, det skal man :)

Output = navnet på 1. mappe i C:\Cognosdata\Temp
(som skal slettes)

/dan

Den skulle køres fra C:\Cognosdata\Temp

Prøv denne...

'--------------------
option explicit

dim strPath, objFSO, objFolder
dim objSletMappe, objSletFil

dim objOverMappe, overmappe

strPath = "C:\Cognosdata\Temp" ' ret stien til mappem med "e"-mapperne, UDEN "\" til sidst

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(strPath)

' slet mapper i "e"-mapperne:
for each overmappe in objFolder.subfolders
    wscript.echo " > " & strPath & "\" & overmappe.Name
    set objOverMappe = objFSO.GetFolder(strPath & "\" & overmappe.Name)

    For Each objSletMappe In objOverMappe.SubFolders
    wscript.echo " >> " & strPath & "\" & overmappe.Name & "\" & objSletMappe.Name
      objFSO.DeleteFolder strPath & "\" & overmappe.Name & "\" & objSletMappe.Name,True
    Next
next

' slet filer i "e"-mapperne:
for each overmappe in objFolder.subfolders
    set objOverMappe = objFSO.GetFolder(strPath & "\" & overmappe.Name)

    For Each objSletFil In objOverMappe.files
        objFSO.DeleteFile strPath & "\" & objOverMappe.Name & "\" & objSletFil.Name,True
    Next
next

set objFSO = nothing
set objFolder = nothing

msgbox "Kode udført" ' beskeden kan ændres eller fjernes

Filer i mapperne er slettet.
Men jeg læser det som om at mapperne samt filer i selv temp-mappen også slettes. (hvilket ikke er tilfældet)

Er det korretkt?

/dan

Det script du har her "renser" undermapperne til temp for filer og mapper i 1 og kun 1 niveau. Det fjerner ikke de mapper der er i temp.

Du har ikke sagt hvad det er du gerne vil. Andet end at have scriptet til at virke :)

'Du har ikke sagt hvad det er du gerne vil. Andet end at have scriptet til at virke'
Det er korrekt!!!!

Men min forståelse af scriptet er, at den tømte (i dette tilfælde) temp-mappen totalt.
Da det ikke sker vil jeg selvfølgelig gerne have det lavet sådan.

Altså opgaven består i, at få temp-mappen helt tømt.
På forhånd tak.

/dan

'--------------------
option explicit

dim strPath, objFSO, objFolder
dim mappe

strPath = "C:\Cognosdata\Temp"

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(strPath)

for each mappe in objFolder.subfolders
    objFSO.DeleteFolder strPath & "\" & mappe.Name,True
next
set objFSO = nothing
set objFolder = nothing

msgbox "Kode udført" ' beskeden kan ændres eller fjernes

Hov glemte filerne !

'--------------------
option explicit

dim strPath, objFSO, objFolder
dim mappe, fil

strPath = "C:\Cognosdata\Temp"

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(strPath)

for each mappe in objFolder.subfolders
    objFSO.DeleteFolder strPath & "\" & mappe.Name,True
next

For Each fil In objFolder.files
    objFSO.DeleteFile strPath & "\" & fil.Name,True
Next

set objFSO = nothing
set objFolder = nothing

msgbox "Kode udført" ' beskeden kan ændres eller fjernes

Mange tak.
Lige et spm. kan nedenstående lade sig gøre?

'*** Script Start ***
option explicit

dim strPath, objFSO, objFolder
dim mappe, fil

strPath = "C:\Cognosdata\Temp"

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFolder = objFSO.GetFolder(strPath)

for each mappe in objFolder.subfolders
    objFSO.DeleteFolder strPath & "\" & mappe.Name,True
next

For Each fil In objFolder.files
    objFSO.DeleteFile strPath & "\" & fil.Name,True
Next

set objFSO = nothing
set objFolder = nothing
'*** Script Slut ***


'*** Script Start ***
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate,(Shutdown)}!\\.\root\cimv2")
Set colOperatingSystems = objWMIService.ExecQuery ("SELECT * FROM Win32_OperatingSystem")
For Each objOperatingSystem in colOperatingSystems
objOperatingSystem.Reboot()
Next
'*** Script Slut ***

/dan

I samme fil selvfølgelig :-)

Med de 3 her i toppen skulle det kunne køre.
Hvis koden ellers er ok? Jeg vil ikke lige køre den her:)

dim objWMIService
dim colOperatingSystems
dim objOperatingSystem

Den nederste script (genstart) kører på serverne hver søndag kl. 12 uden problemer, pga. oprydning vil jeg gerne, at den øverste script (slette indhold i temp) kører først, inden der genstartes.

Vil flytte linier og tester så på søndag.

/dan