løkke i løkke

do until rs.eof
  if rs("subpage") = "false" then
    response.write("<div class='menu'>" & rs("text") & "</div>")
    subid = rs("id")
    rs.movenext
  else
    response.write("<div class='submenu' id='" & subid & ">"
    do while not rs.eof and rs("subpage") = "true"
      response.write rs("text") & "<br>"
      rs.movenext
    loop
    response.write "</div>"
  end if
loop

Det minder meget om mit oprindelige forsøg, som ikke virkede - men jeg afprøver :-)

Koden er ikke 100% det samme, men den giver samme fejl.
Menupunkterne kommer fint frem, men teksten til submenupunkterne skrives ikke.

Hvordan ser din SQL ud (du skal muligvis have [] omkring feltet text i din SQL-sætning...

Det var mig der var fuld jeg opdaterede den forkerte side :-)

Din kode virker til dels.

Dog afsluttes menuen med en fejlmeddelelse.

Hjælpe mig med at hjælpe dig: hvad er fejlmeddelsen? ;-)

Hov! Der sneg sig vist en sprogspasme ind... :D

Aaah OK, prøv lige denne kode i stedet:

do until rs.eof
  if rs("subpage") = "false" then
    response.write("<div class='menu'>" & rs("text") & "</div>")
    subid = rs("id")
    rs.movenext
  else
    response.write "<div class='submenu' id='" & subid & "'>"
    do while not rs.eof and rs("subpage") = "true"
      response.write rs("text") & "<br>"
      rs.movenext
    loop
    response.write "</div>"
  end if
loop

Denne kode giver samme fejl. Menuen vises men afslutningvis står der:
"An error occurred on the server when processing the URL. Please contact the system administrator"

OK, du skal nok lige have slået de der venlige fejlbeskeder fra i din browser. Under antagelse af at det er Internet Explorer, så kan du vist nok finde denne indstilling i menuen Funktioner / Internetindstillinger og så på "avanceret"-fanen skal du lede efter indstillingen: Vis meddelelser om uskadelige HTTP-fejl - denne mener jeg skal være slået til for at få nogle mere beskrivende fejl...

Og hvis den er slået til skal den slås fra :-)

Har prøvet begge dele, men får desværre kun den samme fejlbeskrivelse.

Ville ellers meget gerne have fejlbeskrivelserne ala ie 6.0

Idet sidste post er af typen "subpage" fortsætter den inderste løkke til rs.eof, hvorfor den yderste løkke ikke kan loope - jeg vil tro fejlen er at finde her, men er ikke sikker.

Det er svært at fejlfinde hvis vi ikke har en brugbar fejlmeddelelse, så derfor skal du lige prøve at benytte denne kode i stedet for:

on error resume next
do until rs.eof
  if rs("subpage") = "false" then

      if err.number <> 0 then
        response.write("main.subpage: " & err.number & " - " & err.Description & "<br>")
        err.clear
      end if

    response.write("<div class='menu'>" & rs("text") & "</div>")

      if err.number <> 0 then
        response.write("main.text: " & err.number & " - " & err.Description & "<br>")
        err.clear
      end if

    subid = rs("id")

      if err.number <> 0 then
        response.write("main.id: " & err.number & " - " & err.Description & "<br>")
        err.clear
      end if

    rs.movenext
  else
    response.write "<div class='submenu' id='" & subid & "'>"
    do while not rs.eof and rs("subpage") = "true"

      if err.number <> 0 then
        response.write("sub.subpage: " & err.number & " - " & err.Description & "<br>")
        err.clear
      end if

      response.write rs("text") & "<br>"

      if err.number <> 0 then
        response.write("sub.text: " & err.number & " - " & err.Description & "<br>")
        err.clear
      end if

      rs.movenext
    loop
    response.write "</div>"
  end if

  if err.number <> 0 then
    response.write("loop: " & err.number & " - " & err.Description & "<br>")
    err.clear
  end if
loop

on error goto 0

Med denne kode er resultatet igen menu, men i stedet
sub.subpage: -2147352567 -
sub.text: -2147352567 -
en halv million gange og derefter
"An error occurred on the server when processing the URL. Please contact the system administrator"

igen = ingen

Hvordan ser din SQL-sætning ud?

Hvilke data er der rent faktisk i tabellen du læser fra?

set rs = conn.execute("SELECT * FROM pages WHERE visible='true' ORDER BY orderid")

Pt. er der ikke så meget ved min tabel. Den består af 5 felter.

Name    Type    Length    Decimals    Allow Null    Key
------------------------------------------------------------
id      int      4          0            no            x
orderid  int      4          0            no
subpage  varchar  5          0            no
text    varchar  50        0            no
visible  varchar  5          0            no

Ja det så så ikke så godt ud, men håber du kan forstå :-)

Name    Type    Length    Dec    Allow Null    Key
-----------------------------------------------------------
id    int    4    0    no        x
orderid    int    4    0    no
subpage    varchar    5    0    no
text    varchar    50    0    no
visible    varchar    5    0        no

ja det blev så ikke bedre :-)

Jeg kan løse problemet ved at tilføje en ekstra post i min database med værdien 9999 i orderid.
do until rs.eof
  if rs("subpage") = "false" then
    if rs("orderid") <> "9999" then
      response.write("<div class='menu'>" & rs("text") & "</div>")
      subid = rs("id")
    end if
    rs.movenext
  else
    response.write("<div class='submenu' id='" & subid & "'>")
    do while not rs.eof and rs("subpage") = "true"
      response.write rs("text") & "<br>"
      rs.movenext
      if rs.eof then response.write("</div>")
    loop
    response.write("</div>")
  end if
loop

OK, det er fint lige at se tabeldefinitionen, men jeg var også lidt interesseret i at se selve indeholdet, altså data...

Du kan evt. prøve at rette flg. linie (den der definerer starten af den indre løkke for undermenupunkter):

    do while not rs.eof and rs("subpage") = "true"

til:

    do while (not rs.eof) and (rs("subpage") = "true")

ikke fordi det burde have nogen betydning, men på den anden side, så for at være helt sikker på at det ikke er sådan noget der driller... :-)

Jeg nåede ikke lige at se din løsning fra indlægget: 13/10-2007 16:20:31, så min kommentar omhandler det der ligger inden det tidspunkt...

ja selvfølgelig:
1    5    true    Sub 2.1    true
2    1    false    Side 1    true
3    3    true    Sub 1.2    true
4    4    false    Side 2    true
5    2    true    Sub 1.1    true
6    7    false    Side 3    false
7    6    true    Sub 2.2    true
8    8    false    Side 4    false

do while (not rs.eof) and (rs("subpage") = "true") - har ingen betydning

jeg ville også helst slippe for at have en ekstra post i min tabel.

Jeg tror det har noget at gøre med det jeg skrev 15:21:51

Det jeg foreslår er altså at du ændrer koden til at se således ud:

do until rs.eof
  if rs("subpage") = "false" then
    response.write("<div class='menu'>" & rs("text") & "</div>")
    subid = rs("id")
    rs.movenext
  else
    response.write "<div class='submenu' id='" & subid & "'>"
    do while (not rs.eof) and (rs("subpage") = "true")
      response.write rs("text") & "<br>"
      rs.movenext
    loop
    response.write "</div>"
  end if
loop

Din egen løsning, vil jeg mene, giver et </div> for meget i slutningen af den sidste undermenu (hvis det er den sidste række i resultatet af udtrækket). Min løsning vil altid sørge for at lukke undermenuerne med et </div>, så det er ikke nødvendigt at tilføje den betingede indsættelse.

Men din kode blive HTML kildekoden
<div class='menu'>Side 1</div>
<div class='submenu' id='2'>Sub 1.1<br>Sub 1.2<br></div>
<div class='menu'>Side 2</div>
<div class='submenu' id='4'>Sub 2.1<br>Sub 2.2<br>
An error occurred on the server when processing the URL. Please contact the system administrator

Hvor for jeg ændrede lidt på kode. Hvorfor jeg tilføjede: if rs.eof then response.write("</div>").
HTML kildekoden bliver så
<div class='menu'>Side 1</div>
<div class='submenu' id='2'>Sub 1.1<br>Sub 1.2<br></div>
<div class='menu'>Side 2</div>
<div class='submenu' id='4'>Sub 2.1<br>Sub 2.2<br></div>
An error occurred on the server when processing the URL. Please contact the system administrator

Ad 13/10-2007 16:39:57: Ja, men det er fordi der opstår en fejl på det tidspunkt, så menuen ikke bliver genereret færdig. Så vi skal nok lige have luset fejlen på serveren ud inden vi afluser fejl i outputtet... :-)

Ad 13/10-2007 16:31:05: Nej, det tror jeg ike, da der ikke er nogen flytning af cursoren i resultatet, mellen det sidste kald til rs.movenext og det loop som bevirker at do until rs.eof terminerer løkken, så det synes jeg er ret usandsynligt at det har noget med det at gøre...

Jeg kunne godt tænke mig at du lige prøvede at ændre din SQL til:

set rs = conn.execute("SELECT id, subpage, [text] FROM pages WHERE visible='true' ORDER BY orderid")

NÆH! Man kan jo ikke checke på et felt i en tom række! Dumme mig! :'(

Prøv lige denne rettelse:

do until rs.eof
  if rs("subpage") = "false" then
    response.write("<div class='menu'>" & rs("text") & "</div>")
    subid = rs("id")
    rs.movenext
  else
    response.write "<div class='submenu' id='" & subid & "'>"
    do while not rs.eof
      if rs("subpage") = "true" then
        response.write rs("text") & "<br>"
        rs.movenext
      else
        exit loop
      end if
    loop
    response.write "</div>"
  end if
loop

hvis jeg ændre min SQL sætning får jeg kun fejlmeddelelsen.

Sludder, det hedder da exit do!

do until rs.eof
  if rs("subpage") = "false" then
    response.write("<div class='menu'>" & rs("text") & "</div>")
    subid = rs("id")
    rs.movenext
  else
    response.write "<div class='submenu' id='" & subid & "'>"
    do while not rs.eof
      if rs("subpage") = "true" then
        response.write rs("text") & "<br>"
        rs.movenext
      else
        exit do
      end if
    loop
    response.write "</div>"
  end if
loop

min børn havde lige brug for noget opmærksomhed. :-)

16:53:17 virker perfekt. :-)

Smider du et svar?

Sådan er det med børn ;-)

Tak for hjælpen :-)

Tak for point :)