Automatisk afsendelse af mail, ved tryk på kontrolknap

Hvilket mailprogram anvender du?

microsoft outlook

Prøv at se her:

http://msdn.microsoft.com/en-us/library/aa203718(office.11).aspx#odc_mailtheselection

hmm.. tror det er det jeg skal bruge..

Jeg får dog en fejl, når jeg sender følgende:

Sub Mail_sheets()
    Dim MyArr As Variant
    Dim last As Long
    Dim shname As Long
    Dim a As Integer
    Dim Arr() As String
    Dim N As Integer
    Dim strdate As String
    For a = 1 To 253 Step 3
        If ThisWorkbook.Sheets("mail").Cells(1, a).Value = "" Then
            Exit Sub
        End
        Application.ScreenUpdating = False
        last = ThisWorkbook.Sheets("mail").Cells(Rows.Count, _
            a).End(xlUp).Row
        N = 0
        For shname = 1 To last
            N = N + 1
            ReDim Preserve Arr(1 To N)
            Arr(N) = ThisWorkbook.Sheets("mail").Cells(shname, a).Value
        Next shname
        ThisWorkbook.Sheets(Arr).Copy
        strdate = Format(Date, "dd-mm-yy") & " " & _
            Format(Time, "h-mm-ss")
        ActiveWorkbook.SaveAs "Part of " & ThisWorkbook.Name _
            & " " & strdate & ".xls"
        With ThisWorkbook.Sheets("mail")
            MyArr = .Range(.Cells(1, a + 1), .Cells(Rows.Count, _
                a + 1).End(xlUp))
        End With
        ActiveWorkbook.SendMail MyArr, ThisWorkbook.Sheets("mail").Cells(1, a + 2).Value
        ActiveWorkbook.ChangeFileAccess xlReadOnly
        Kill ActiveWorkbook.FullName
        ActiveWorkbook.Close False
        Application.ScreenUpdating = True
    Next a
End Sub

Så siger den:

Compile error
Next without For

For a = 1 To 253 Step 3
        If ThisWorkbook.Sheets("mail").Cells(1, a).Value = "" Then
            Exit Sub
        End If  '<<<<<<<<<<<<<<<<< IF MANGLER

som supertekst skrver, tor den at Next hører til Ff, fordi der ikke er en End If. Og så manger der ganske rigtigt en For...

Jeg tjekker i morgen..

Super.. Virker fint. Jkrons smid et svar:-)

Et svar :-)