Finde en fil via VBA og skabe en kæde til to celler

Hej,

Hvis jeg har forstået dig rigtigt, noget i retning af dette (hvor jeg har genbrugt din fname variabel og antager den indeholder stien til arket):


    Dim wb As Workbook
    Dim ws As Worksheet
    Dim deadlines As Integer
    Dim opgaver As Integer
       
    Set wb = Application.Workbooks.Open(fname)
    Set ws = wb.Worksheets("Konfiguration")
    deadlines = ws.Cells(52, 2).Value ' række 52, kolonne 2
    opgaver = ws.Cells(54, 2).Value ' række 54, kolonne 2
    wb.Close
   
    MsgBox "Der er " & deadlines & " overskredne deadlines og " & opgaver & " opgaver der mangler godkendelse."

Tak for det hurtige svar anlu :)

Der kommer fejl i denne linje: Set wb = Application.Workbooks.Open(fName)

Fejlmeddelelsen: runtime error 1004. "blev ikke fundet.

Stien fname returnerer:
\\.host\Shared Folders\rasmus On My Mac\Dropbox\Produktion\Projektplan 100911.xlsm

Kan du hjælpe?

Her er et andet eksempel på en mulig sti:
C:\Documents and Settings\Administrator\My Documents\yamaha logo.doc

Jeg har rodet lidt med variable og anvendt tekstboksens værdi i en variabel i stedet for at bruge fname direkte, og nu virker de! :)

Jeg vil meget gerne give dig point, anlu - tak for hjælpen :)!

Men... lige en ting. Nu bliver der jo sat en statisk tekst ind og ikke en kæde. Så når projektplanen opdateres, så skal man manuelt opdatere data igen... Kan man gøre det sådan, at der bliver oprettet en kæde i tekstfeltet, så data opdateres når projektplanen bliver ændret? (det kan man... men hvordan :)

Og endnu en lille ting ... kan man diable Save i den projektplan der åbnes? Jeg får en Save dialogbox op, og det er jo ikke nødvendigt...

Du kan angive SaveChanges:=false som parameter til Workbook.Close, dvs.
  wb.Close SaveChanges:=false
så bør den ikke spørge om du vil gemme.

Mht. det med en kæde i tekstfeltet, så er jeg ikke 100% sikker på hvad du vil. Er det i din form at der er en tekst der skal opdateres? Eller? Og hvornår skal opdatering ske mere præcist?

til point

Tak for den med save.

Mht til kæden så er det jeg vil:

1. Brugeren opretter link til en fil via en userform, hvor getopenfilename bruges til at lokalisere sti + fil. Så skal der gemmes en kæde til sti + filnavn + ark + celle1 og sti + filnavn + ark + celle2.

Ligesom hvis man selv havde oprettet en kæde. Udfordringen ligger i, at det er brugeren der selv skal lave kæden, blot ved at vælge en fil. Jeg kender arknavn og celle1 og celle2, så det er sti og filnavn jeg som udvikler ikke kender, så dem skal brugeren oplyse.

Når der så er oprettet en kæde, så vil den celle hvor jeg har gemt referencen til de to celler automatisk blive opdateret!

Giver det mening?

Der skal altså "bygges" to kæder ud fra de oplysninger jeg kender (ark og celle1 + celle2) samt de oplysninger brugeren oplyser (sti og fil).

Så skal de to referencer sættes sammen til een kæde.

Kæden skal så gemmes i en celle.

Jeg poster gerne en skovlfuld point mere på, hvis du kan hjælpe! :)

Jeg har prøvet sådan her, men får "Subscript out of range":

celle1 = Application.Workbooks(fname).Sheets(ws).Range(deadlines)

Jeg tror måske vi er ude i noget a la det her. Igen antager jeg at fname indeholder stien til filen. Det bliver lidt bøvlet fordi vi skal have splittet folder-stien fra selve filnavnet - kan muligvis laves smartere, men jeg kunne ikke lige se hvordan. Er det til at forstå?

    Dim wbName As String
    Dim formel As String
    Dim pathParts As Variant
    Dim folderPath As String
    Dim i As Integer
   
    pathParts = Split(fname, "\")
    folderPath = ""
    For i = LBound(pathParts) To UBound(pathParts) - 1
        folderPath = folderPath & pathParts(i) & "\"
    Next i
    wbName = pathParts(UBound(pathParts))
   
    formel = "='" & folderPath & "[" & wbName & "]Konfiguration'!R52C2"
   
    Range("A1").FormulaR1C1 = formel

Jeg tror, at du er ude i det helt rigtige! Jeg har selv fundet det her:


Retrieving a value from a closed workbook
VBA does not include a method to retrieve a value from a closed workbook file. You can, however, take advantage of Excel's ability to work with linked files. This section contains a custom VBA function (GetValue, which follows) that retrieves a value from a closed workbook. It does so by calling an XLM macro, which is an old-style macro used in versions prior to Excel 5. Fortunately, Excel still supports this old macro system.

Private Function GetValue(path, file, sheet, ref)
'  Retrieves a value from a closed workbook
    Dim arg As String

'  Make sure the file exists
    If Right(path, 1) <> "\" Then path = path & "\"
    If Dir(path & file) = "" Then
        GetValue = "File Not Found"
        Exit Function
End If
'  Create the argument
    arg = "'" & path & "[" & file & "]" & sheet & "'!" & _
        Range(ref).Range("A1").Address(, , xlR1C1)

'  Execute an XLM macro
    GetValue = ExecuteExcel4Macro(arg)
End Function

Men den kræver NETOP, at man skiller sti og fil ad, og der står ikke hvordan man gør det... Jeg prøver din kode og vender tilbage :).

For DÆLEN - det virker! Det er super :).

Det var det svære. Nu mangler jeg (vi) kun:
1. at gøre det for begge de to celler
2. samle dem i en enkelt tekststreng
3. proppe den i en tekstboks i formularen
4. gemme formlen i en celle i mit regneark.

Er det noget i denne stil? (bruger "sti" i stedet for fname)

Dim sti As String
Dim deadlines As String
Dim afventer As String

sti = frmtrs!txtlink.Text

    Dim wbName As String
    Dim formel As String
    Dim formel2 As String
    Dim pathParts As Variant
    Dim folderPath As String
    Dim l As Integer
   
    pathParts = Split(sti, "\")
    folderPath = ""
    For l = LBound(pathParts) To UBound(pathParts) - 1
        folderPath = folderPath & pathParts(l) & "\"
    Next l
    wbName = pathParts(UBound(pathParts))
   
    formel = "='" & folderPath & "[" & wbName & "]Konfiguration'!R52C2"
    formel2 = "='" & folderPath & "[" & wbName & "]Konfiguration'!R55C2"
   
    'Range("A1").FormulaR1C1 = formel
   
    txtdetaljer.Text = formel & " aktiviteter over deadline." & Chr(10) & formel2 & " aktiviteter 'Afventer...'."

Det går fint med at gemme formlen i txtdetaljer tekstboksen.

Men det går galt når jeg forsøger at gemme dennes værdi i en celle:

ActiveCell.Offset(0, 1).Select
Selection.Value = txtdetaljer.Text

Det virker heller ikke med:

ActiveCell.Offset(0, 1).Select
ActiveCell.FormulaR1C1 = txtdetaljer.Text

Jeg opretter et spgm med 200 points til dig når vi er færdige med den her, hvis det er ok :)

Mine & tegn bliver ikke taget med over i tekstboksen, kan jeg se:

='\\.host\Shared Folders\rasmus On My Mac\Dropbox\VILEN konceptudvikling\STYR\Produktion\[Projektplan 100911.xlsm]Konfiguration'!R52C2 aktiviteter over deadline.='\\.host\Shared Folders\rasmus On My Mac\Dropbox\VILEN konceptudvikling\STYR\Produktion\[Projektplan 100911.xlsm]Konfiguration'!R55C2 aktiviteter 'Afventer...'.

Kan dette hjælpe dig?

    formel1 = "'" & folderPath & "[" & wbName & "]Konfiguration'!R52C2"
    formel2 = "'" & folderPath & "[" & wbName & "]Konfiguration'!R54C2"
   
    formel = "=" & formel1 & " & "" aktiviteter over deadline"" & CHAR(10) & " & formel2 & "& "" aktiviteter 'Afventer...'."""
   
    Range("A1").FormulaR1C1 = formel

I stedet for Range("A1") kan du benytte ActiveCell.Offset(0,1) hvis det er den celle du skal have skrevet i.

Bemærk at den celle der skrives i skal have Wrap text slået til i formattering (ved ikke lige hvad det hedder i den danske version).
Og helt fint med 200p :-)

It works :). Sikken omgang - TUSIND tak!

Jeg er meget taknemmelig for hjælpen - det var en nød jeg meget gerne skulle knække i dag.

Jeg opretter straks et spgm med point. Fortsat rigtig god aften :)!

MVH

Rasmus