Ændre samme kodelinje i mange excelfiler

Måske dette stykke shareware kan hjælpe dig (har ikke selv erfaringer med det):

http://www.office-excel.com/excel-addins/find-and-replace.html

Det ser ud til at det virker med document properties - ikke med kode. Men tak for buddet :). Det jeg leder efter er en stump kode med en løkke der åbner filer og erstatter en tekstbid i et givent modul - hvis det kan lade sig gøre...

Måske kan du få noget ud af denne side:
http://www.cpearson.com/excel/vbe.aspx

Hej anlu :)

Det ser spændende, svært og helt rigtigt ud, tak! Jeg prøver og vender tilbage...

Hm.. jeg kan ikke se hvordan man ændrer i flere workbooks samtidig...?

De fleste af hans eksempler bruger ActiveWorkbook, men det kan let modificeres til at proceduren tager den workbook der skal rettes i som parameter, fx den der tilføjer en procedure kunne du ændre som foreslået nedenfor.
I en anden procedure kunne du så loope igennem de workbooks du vil have rettet og kalde AddProcedureToModule for hver af dem. Ikke fordi det lige er denne producere du nødvendigvis skal bruge, men kan du følge tankegangen?

Sub AddProcedureToModule(wb as Workbook)
        Dim VBProj As VBIDE.VBProject
        Dim VBComp As VBIDE.VBComponent
        Dim CodeMod As VBIDE.CodeModule
        Dim LineNum As Long
        Const DQUOTE = """" ' one " character

        Set VBProj = wb.VBProject
        Set VBComp = VBProj.VBComponents("Module1")
        Set CodeMod = VBComp.CodeModule
       
        With CodeMod
            LineNum = .CountOfLines + 1
            .InsertLines LineNum, "Public Sub SayHello()"
            LineNum = LineNum + 1
            .InsertLines LineNum, "    MsgBox " & DQUOTE & "Hello World" & DQUOTE
            LineNum = LineNum + 1
            .InsertLines LineNum, "End Sub"
        End With
   
    End Sub

Jep, det kan jeg godt følge. Jeg tror, at hvis du kan hjælpe mig med loop proceduren også, så kan jeg gøre det... Jeg ved ikke hvordan jeg skal skrive en procedure, der åbner alle workbooks i en mappe fx. Jeg kan kun skrive en, der åbner en enkelt workbook... Jeg kan også lede efter en her inde, hvis det du mener det er bedst - så skal du bare smide et svar :)

Her en procedure der looper gennem xls og xlsm filer i en folder. Du skal selvfølgelig rette til så den gør lidt mere end bare skrive navnet i en celle :o)

Public Sub LoopThroughWorkbooks(folderName As String)
    Dim wb As Workbook
    Dim i As Integer
   
   
    Dim fs As FileSystemObject
    Dim dDirs As folder
    Dim fFile As File
    Dim ext As String
   
    Set fs = New Scripting.FileSystemObject
    Set dDirs = fs.GetFolder(folderName)
   
    Application.ScreenUpdating = False
   
    i = 1
    For Each fFile In dDirs.Files
       
        ext = Mid(fFile.Name, InStrRev(fFile.Name, ".") + 1)
        If ext = "xls" Or ext = "xlsm" Then
            ' open workbook
            Set wb = Workbooks.Open(fFile.Path)
            ' do something with workbook
            Sheet1.Cells(i, 1).Value = wb.Name

            ' close workbook
            wb.Close savechanges:=True
            i = i + 1
        End If
    Next
   
    Application.ScreenUpdating = True
End Sub

Mange tak :). Ja, jeg skal jo så bruge koden til at rette i et modul, når hver enkelt workbook åbnes. Kanon hjælp - jeg kan ikke bede om mere! Jeg er klar med points, for en som sædvanlig fyldestgørende løsning...

Hov, jeg glemte lige at skrive at du skal sætte en reference til Microsoft Scripting Runtime for at den fungerer.

Det er noteret :)

Håber det lykkes for dig. Ellers sig til hvis du har behov for mere sparring.

Super cool - thanx - det husker jeg på :)