Hyperlink til tekst

Du kan prøve følgende:

Markér hele kolonnen, hvor Du har dine mail-adresser. ( Lav evt. en kopi til et nyt ark. )

Højreklik .... - Fjern links

Formatér celler -I nyt vindue - "Tal"-fanen - Tekst

Tak for forslaget jernrosen3
Men det giver desværre ikke det ønskede resultat.

Supplerende oplysninger:
Jeg har også prøvet at optage en macro, af den manuelle arbejdsgang, men den registrerer ikke alle handlinger.

i vba kan du prøve at indsætte denne funktion. Der kan derefter bryges i regnearket som alle andre functioner

Function hyperaddress(rg As Range) As String
    hyperaddress = rg.Hyperlinks(1).Address
End Function

fx. =hyperaddress(A15)

Tak bak2

Det kunne godt se rigtigt ud 😊

Men mit VBA er noget rustent...
Kan jeg få dig til at lave et script der fortsætter ned i kolonnen ?

På forhånd tak, hvis det er muligt for dig

Med en fuktion som denne skriver du den bare i første celle og trækker den derefter nedad så langt dine data rækker.
men her er lidt kode hvis det er nemmere :
du sætter lige selv startadressen

Sub filldown()
    Dim rg1 As Range
    Dim cell As Range
   
    Set rg1 = Range("A2:" & Range("A2").End(xlDown).Address)
    For Each cell In rg1
        cell.Offset(, 1).Value = cell.Hyperlinks(1).Address
    Next
End Sub

Mit VBA er nok også lidt rustent. Her er en lidt bedre kode:
StartCell er første celle med hyperlinks.
StartCellOfsetColumn er hvhvilken kolonne ved siden af du ønsker resultatet i.

Sub filldown()
    Dim rg1 As Range
    Dim cell As Range
    Dim StartCell As Range
    Dim EndCell As Range
    Dim StartCellOfsetColumn As Long
   
    Set StartCell = Range("A2")
    StartCellOfsetColumn = 2
   
    Set rg1 = Range("A2:" & Range("A100000").End(xlUp).Address)
    On Error Resume Next
    For Each cell In rg1
        cell.Offset(, 1).Value = cell.Hyperlinks(1).Address
    Next
End Sub

Som jeg læser udfordringen, er det at få opdateret "Tekst, der skal vises", så den også indeholder varenummeret, dvs. al tekst efter "https://webshop.dk/" i hyperlinkets adresse-property.

Hvis min opfattelse er korrekt, så prøv med denne VBA-kode, der gennemløber alle celler med hyperlink i området UsedRange af det aktive ark.

Sub sub_update_hyperlink_TextToDisplay()
    Dim rng_cell As Range
    For Each rng_cell In ActiveSheet.UsedRange.Cells
        With rng_cell
            If .Hyperlinks.Count > 0 Then
                With .Hyperlinks(1)
                    .TextToDisplay = Mid(.Address, InStrRev(.Address, "/", , vbTextCompare) + 1)
                End With
            End If
        End With
    Next rng_cell
End Sub

Tak Bak2
Jeg skal lige hjem og se om din løsning virker for mig.

Tak MaxZpaD
Din løsning virkede med det samme, men overskrev de gamle links...

Jeg finder lige ud af i aften hvem af jer der får points

Nanarsi - vil du både have det gamle hyperlink OG et nyt med varenr., eller hvad er dit ønske-scenarie?  :-)

Jeg havde forstået det sådan, at de gamle links skulle opdateres, så de indeholdt både varenr. og varenavn.

Men andre udfald er selvfølgelig også mulige....

Jeg havde forestille mig at det gamle link ikke blev rørt men at hele linkadressen med nr og navn, kom til at stå i en ny kolonne. ("https://webshop.dk/123456-3m_Grøn_Tube")
Derfra kan jeg trække nr og navn ud i nye kolonner.

Den størst udfordring med dit script er at den tager samtlige links på fanebladet, også nogle der ikke skulle behandles, men det kan jeg arbejde rundt om.
Det ideelle ville være at den tog linket fra kolonne C og lagde teksten i Kolonne D :-)

Hej Nanarsi

Okay - ny makro. Denne gang gennemløbes kun cellerne i kolonne C. Varenummer indsættes i kolonne D og varenavn i kolonne E. Selve linket ændres ikke.

Sub sub_split_hyperlink_address()
    Dim sht As Worksheet
    Dim rng_cell As Range
    Set sht = ActiveSheet
    On Error GoTo exit_sub
    With Application
        .ScreenUpdating = False
        .Calculation = xlCalculationManual
    End With
    For Each rng_cell In sht.Columns(3).Cells
        With rng_cell
            If .Row > sht.UsedRange.SpecialCells(xlCellTypeLastCell).Row Then
                Exit For
            ElseIf .Hyperlinks.Count > 0 Then
                With .Hyperlinks(1)
                    rng_cell.Offset(, 1) = Split(Mid(.Address, InStrRev(.Address, "/", , vbTextCompare) + 1), "-")(0)
                    rng_cell.Offset(, 2) = Split(Mid(.Address, InStrRev(.Address, "/", , vbTextCompare) + 1), "-")(1)
                End With
            End If
        End With
    Next rng_cell
    sht.Columns("D:D").Resize(, 2).AutoFit
exit_sub:
    With Application
        .Calculation = xlCalculationAutomatic
        .ScreenUpdating = True
    End With
End Sub

Mange tak MaxZpaD

Det er helt perfekt, og spare mig for en hel del arbejde 👍😅

også tak for dine bud Bak2