Ehm...

Her har du noget godt læse stof..:

http://www.devguru.com/Technologies/wsh/quickref/wsh_intro.html

Sådan her skriver du til en fil:
Write to a file
[writefile.vbs]

Dim objFileSystem, objOutputFile
Dim strOutputFile

' generate a filename base on the script name
strOutputFile = "./" & Split(WScript.ScriptName, ".")(0) & ".out"

Set objFileSystem = CreateObject("Scripting.fileSystemObject")
Set objOutputFile = objFileSystem.CreateTextFile(strOutputFile, TRUE)

objOutputFile.WriteLine("Hello world (" & Now & ")")
objOutputFile.Close

Set objFileSystem = Nothing

WScript.Quit(0)



To append to an existing file : [appendfile.vbs]

Dim objFileSystem, objOutputFile
Dim strOutputFile

Const OPEN_FILE_FOR_APPENDING = 8

' generate a filename base on the script name
strOutputFile = "./writefile.out"

Set objFileSystem = CreateObject("Scripting.fileSystemObject")
Set objOutputFile = objFileSystem.OpenTextFile(strOutputFile, OPEN_FILE_FOR_APPENDING)

objOutputFile.WriteLine("Hello world (" & Now & ")")
objOutputFile.Close

Set objFileSystem = Nothing

WScript.Quit(0)



Sådan her læser du fra en fil:

Read a file
[readfile.vbs]

Dim objFileSystem, objInputFile
Dim strInputFile, inputData, strData

Const OPEN_FILE_FOR_READING = 1

' generate a filename base on the script name, here readfile.in
strOutputFile = "./" & Split(WScript.ScriptName, ".")(0) & ".in"

Set objFileSystem = CreateObject("Scripting.fileSystemObject")
Set objInputFile = objFileSystem.OpenTextFile(strOutputFile, OPEN_FILE_FOR_READING)

' read everything in an array
inputData = Split(objInputFile.ReadAll, vbNewline)

For each strData In inputData
    WScript.Echo strData
Next

objInputFile.Close
Set objFileSystem = Nothing

WScript.Quit(0)




Det er i realiteten ikke så svært... bare læs det overstående godt igennem, så skulle du gerne kunne løse dit problem..

Held og lykke..!

//Rune

Thx 4 Poinz

//>Rune