Random dato

her er en kode der laver en checkbox med 10 uger som beskrevet. Samtidig vælger den et bestemt tidspunkt i en bestemt uge.

<%
function FirstDateInWeek(AYear, AWeek)
  ' Find første dato i uge 1 i år
  VD = DateSerial(AYear, 1, 1)
  ' Da DatePart uge 1 starter den 01-01-Year så kør frem til uge 2
  do while DatePart("ww", VD) <> 2
    VD = DateAdd("d", 1, VD)
  loop
  ' Gå en uge tilbage og vi har første dato i uge 1
  VD = DateAdd("ww", -1, VD)
  ' Adder antallet uger og vi har første dato i uge: AWeek
  VD = DateAdd("ww", AWeek - 1, VD)
  ' Korriger for ugestart fra Søndag til Mandag
  FirstDateInWeek = DateAdd("d", 1, VD)
end function

' Lav select-box med 10 uger i
TheYear = 2002
TheWeek = 1
FirstDate = FirstDateInWeek(TheYear, TheWeek)
LastDate = DateAdd("ww", 1, FirstDate - 1)

Response.Write("<select>" & vbCrLf)
for Uge = 1 to 10
  Response.Write "<option value=" & Uge & ">" & FirstDate & " " & LastDate & "</option>"  & VbCrLf
  FirstDate = DateAdd("ww", 1, FirstDate)
  LastDate = DateAdd("ww", 1, FirstDate - 1)
next
Response.Write("</select><br>" & vbCrLf)

' Find et tilfældigt tidspunkt i en bestemt uge
function RndMellem(Fra, Til) ' find et tilfældigt tal melle Fra og Til. Begge tal inklusive
  randomize
  til = til + 1
  RndMellem = int((Til - Fra) * rnd) + Fra
end function

H = RndMellem(0, 23) ' Find tilfældig time
M = RndMellem(0, 59) ' Find tilfældig minut
S = RndMellem(0, 59) ' Find tilfældig sekund
D = RndMellem(0, 6) ' Find tilfældig dag i ugen

TheYear = 2002
TheWeek = 2 ' Bestem ugen
RndTime = FirstDateInWeek(TheYear, TheWeek)
Response.Write("Tilfældig tidspunkt i uge: " & TheWeek & " " & RndTime & " " & DateAdd("ww", 1, RndTime - 1) & "<br>")

RndTime = DateAdd("d", D, RndTime) ' Bestem den tilfældig dag i ugen
RndTime = CDate(CStr(RndTime) & " " & H & ":" & M & ":" & S & "")
Response.Write("Tidspunkt: " & RndTime & "<br>")

%>

Håber du kan bruge det.

Du er eddermame skarp ;-)
Det er første gang jeg benytter denne side - hvordan giver jeg dig point??

Jeg har lige et sidste spørgsmål - kan det lade sig gøre at den reloader når man har valgt uge - så den finder den tilfældige dato for den uge man har valgt ?? -

Det kan man godt. Når man vælger uge og siden reloader skal man sørge for at disse linier:

TheYear = 2002
TheWeek = 2 ' Bestem ugen

ændres i henhold til det man har valgt.

TheYear = 2002
TheWeek = Request.Form("selectbox") ' Bestem ugen

Hvor selectbox er navnet på select-boxen, som jeg har glemt at give et navn:

Response.Write("<select name='selectbox'>" & vbCrLf)

Jeg ved ikke hvordan man giver point - men jeg tror man vælger et svar og lukker. ???