keyhook?

det er nok værd at sige at mit program kører i traybaren, og kun der...

Det tror jeg ikke man kan.

det burde kunne lade sig gøre, har set det...

hvis jeg nu f.eks. vil have F12 til at aktivere en funktion i mit program

Hvad gør jeg?

Jamen det keyhook skal jo fanges at et window, som ved at der skal sendes en besked videre ned til din applikation i traybaren.

Det kan sagtens lade sig gøre! Ved ikke helt hvordan, men jeg fandt da noget til dig som du måske kan bruge:
http://www.delphipages.com/advancedsearch.cfm?eSearch=keyhook&AO=and

mm hvordan kan man mon gøre det nemmest?

Jeg skal lige være med. Din application ligger i Traybar'en, og har IKKE fokus, men en hvilken som helst anden applikation har fokus ?

jepper laffe, netop..
man kommer ikke til at kunne se min app på prosess linien, men kun i tray

Fandt lige det her:
http://www.lysias.de/source/delphi/KeyHook%20Source.zip

mmm kigger lige på dine links hermandsen

er der andre som har efaring med netop dette?

ja - og det kan godt lade sig gøre. skriv til mig cnt@cnt.dk hvis du ikke får brugbare links, så forklarer jeg dig det

Må vi andre ikke være med ?

jeg kan ikke rigtig komme vidre med de få links jeg har fået her, er der virklig ikke nogle som har arbejdet med hooks i delphi her?

Start med at instalere dette komponent og vend så tilbage :

{------------------------------------------------------------------------------
  Unit    : GlobalHotKey.pas
  Purpose  : System hot key handling
  Status  : Freeware
  Copyright: ©2000 Jens Borrisholt, http://Borrisholt.com
  contact  : Jens@Borrisholt.com
-------------------------------------------------------------------------------

  History:

  Date                By      Comments
  ----                ----    --------
  15 August 2000      JB      Created

}
unit GlobalHotKey;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs, menus;

type
  TGlobalHotKey = class(TComponent)
  private
    FEnabled: Boolean;
    FRegistered: Boolean;
    prOldWndProc: TWndMethod;
    FHotkey: TSHortcut;
    FOnHotKeyPressed: TNotifyEvent;
    prWindow: TWinControl;
    procedure RegisterKey;
    procedure UnRegisterKey;
    { Private declarations }
  protected
    { Protected declarations }
    procedure SetEnabled(const Value: Boolean);
    procedure SetHotKey(const Value: TShortcut);
    procedure NewWindowProc(var Message: TMessage);
    procedure Loaded; override;
  public
    { Public declarations }
    constructor Create(aOwner: TComponent); override;
    destructor Destroy; override;
    property Registered: boolean read FRegistered;
  published
    { Published declarations }
    property Enabled: Boolean read FEnabled write SetEnabled default true;
    property Key: TShortcut read FHotkey write SetHotkey;
    property OnHotKey: TNotifyEvent read FOnHotKeyPressed write FOnHotKeyPressed;
  end;

procedure Register;

implementation


{ TGlobalHotKey }

constructor TGlobalHotKey.Create(aOwner: TComponent);
begin
  inherited;
  FEnabled := True;
  FHotKey := 0;
  FRegistered := false;
  if not (csDesigning in ComponentState) then
  begin
    prWindow := TWinControl.CreateParented(GetDesktopWindow);
    prOldWndProc := prWindow.WindowProc;
    prWindow.WindowProc := NewWindowProc;
  end;
end;

destructor TGlobalHotKey.Destroy;
begin
  if not (csDesigning in ComponentState) then
  begin
    UnRegisterKey;
    prWindow.WindowProc := prOldWndProc;
    prWindow.Free;
  end;
  inherited;
end;

procedure TGlobalHotKey.Loaded;
begin
  inherited;
  if (FEnabled) and (not (csDesigning in ComponentState)) then RegisterKey;
end;

procedure TGlobalHotKey.NewWindowProc(var Message: TMessage);
begin
  case Message.Msg of
    WM_HOTKEY:
    begin
      if assigned(FOnHotkeyPressed) then
        FOnHotKeyPressed(self);
    end;
  end;
  prOldWndProc(Message);
end;

procedure TGlobalHotKey.RegisterKey;
var
  lVKey: word;
  lvShift: TShiftstate;
  lModifier: UINT;
begin
  if not FRegistered then
  begin
    lModifier := 0;
    ShortcutToKey(FHotkey, lvKey, lvShift);

    if ssShift in lvShift  then
      lModifier := lModifier or MOD_SHIFT;

    if ssAlt in lvShift then
      lModifier := lModifier or MOD_ALT;

    if ssCtrl in lvShift then
      lModifier := lModifier or MOD_CONTROL;

    FRegistered := RegisterHotKey(prWindow.Handle, 0, lModifier, LOBYTE(lVKey));
  end;
end;

procedure TGlobalHotKey.SetEnabled(const Value: Boolean);
begin
  FEnabled := Value;
  if FEnabled then
    RegisterKey
  else
    UnregisterKey;
end;

procedure TGlobalHotKey.UnRegisterKey;
begin
  if FRegistered then
  begin
    UnregisterHotKey(prWindow.Handle, 0);
    FRegistered := False;
  end;
end;

procedure TGlobalHotKey.SetHotKey(const Value: TShortcut);
begin
  if Value <> FHotkey then
  begin
    FHotkey := Value;
    if not (csDesigning in ComponentState) then
    begin
        UnRegisterKey;
        if FEnabled then
          RegisterKey;
    end;
  end;
end;

procedure Register;
begin
  RegisterComponents('System', [TGlobalHotKey]);
end;

end.

Jens B

hey jens..
hvorfor skriver den:
[Fatal Error] global.pas(1): Program or unit 'global.pas' recursively uses itself når jeg prøver at installere det komponent?

wil/

Det har ikke noget med mit komponent at gøre

oki, hvad tror du så der er sket?

hvad hedder komponenten når den er blevet installeret?
skal nemlig lige finde den rigtige:-)

Klassen heddet TGlobalhotkey, og ligger under System .. Prøv at luk ALLE ting i din Delphi. Åben mit komponent op og instaler det ...

HUSK uniten skal hede GlobalHotKey.pas

Jens B

fandt den, kunne ikke lige se hvor den skulle være..

nu er det installeret jens, hvad gør jeg så?

vidste bare ikke lige hvor den var lagt på min palette, men har jo fundet den:-)

så sæt den på din form .... i din Object Inspector har du en property der hedder "Key" den sætter du bare ....

Så skriver du blot noget kode i OnHotkey eventet !

Jens B

mmm keyen kan kun være et nummer right? ikke en F12 f.eks.

den skriver en error hvis jeg gør det..

jens:
jeg ved godt det er et newbiee spm, men hvorfor får jeg ikke noget frem ved:
procedure TForm1.GlobalHotKey1HotKey(Sender: TObject);
begin
ShowMessage('tester om borrisholts component virker!');
end;

sætter min key til 8 og mit tag til 8 også..

så sker der intet når jeg compiler, og prøver at aktivere et andet program, så mit ikke er i focus...

hvad gør jeg forkert?

end.

Hmmn .. OKI minor bug på D6 ...

Men et godt WorkArround vil være :

procedure TForm1.FormCreate(Sender: TObject);
begin
  GlobalHotKey1.Key := TextToShortCut('Ctrl+F12');
end;

Jens B

mmm skal jeg så ikke sætte noget i key i object inspectoren?
og TextToShortCut skal det så være min kode der står der eller hvad?

kunne du evt. ikke lige prøve at lave en lille demo som indeholder nogle forskellige koder, som man kan bruge med dit komponent?, skal nok sætte points lidt op så;.)

Det er fuldstendig ligemeget hvad du sætter Key til på Design time ... Altså i Object Inspectoren

Og JA det der TextToshortCut skal du skrive i den kode ..

Jens b

Send mig lige en e-mail

oki doki

mail sendt til jens@borrisholt.dk


wil/

Det er ikke nødvendigt med den komponent, hvis det blot er en simpel tast der skal bruges. Følgende eksempel viser, hvad man kan gøre, hvis man vil have programmet til at reagere på Ctrl + R og Ctrl + Q, og virker med andre taster også, f.eks. F12:
--------------- Kode start ---------------
type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  protected
    procedure hotykey(var msg:TMessage); message WM_HOTKEY;
  end;

var
  Form1: TForm1;
  id,id2:Integer;

implementation
{$R *.DFM}

procedure TForm1.hotykey(var msg:TMessage);
begin
  // Ved Control + Q: Q = 81, Control = MOD_CONTROL
  if (msg.LParamLo=MOD_CONTROL) and (msg.LParamHi=81) then
  begin
    ShowMessage('Ctrl + Q!');
  end;

  if msg.LParamHi=vk_f12 then
  begin
    ShowMessage('F12');
  end;

  if (msg.LParamLo=MOD_CONTROL) and (msg.LParamHi=82) then
  begin
    ShowMessage('Ctrl + R!');
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  id:=GlobalAddAtom('hotkey');
  RegisterHotKey(handle,id,mod_control,81);

  id2:=GlobalAddAtom('hotkey2');
  RegisterHotKey(handle,id2,mod_control,82);

  id3:=GlobalAddAtom('hotkey3');
  RegisterHotKey(handle,id3,0,vk_f12);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  UnRegisterHotKey(handle,id);
  UnRegisterHotKey(handle,id2);
  UnRegisterHotKey(handle,id3);
end;
--------------- Kode slut ---------------

Det blev brugt i et gammelt spørgsmål her også, kan dog ikke lige huske det.

Elv

jeg har fundet lidt kode, er der en som kan se hvorfor den kun kan paste i offline ting( notepad f.eks.) og ikke direkte på nettet:

Kode start:---- 
unit Unit1;
interface
uses  Windows, Messages, SysUtils, Classes, Graphics,
Controls, Forms, Dialogs,  StdCtrls, ClipBrd;
type
TForm1 = class(TForm)
    Memo1: TMemo;
procedure FormCreate(Sender: TObject);
private
{ Private declarations }
procedure WndProc(var Message: TMessage); override;
  public
  { Public declarations }
procedure ToClipbrd(StrValue: string);
end;
var
  Form1: TForm1;
implementation
{$R *.DFM}
procedure TForm1.WndProc(var Message: TMessage);
var
TmpStr : String;
begin
TmpStr := Memo1.Text;
  if (Message.Msg = WM_HOTKEY) and (Message.wParam = IDHOT_SNAPWINDOW)
  then
  begin
  if length(TmpStr) > 0 then
  begin
  ToClipbrd(TmpStr);
  keybd_event(VK_CONTROL, 0, 0, 0);
  keybd_event(VkKeyScan('v'), 1, 0, 0);
    keybd_event(VK_CONTROL, 0,KEYEVENTF_KEYUP,0);
    keybd_event(VkKeyScan('v'), 1, KEYEVENTF_KEYUP, 0);
    end;
    end;
    inherited WndProc(Message);
    end;
    procedure TForm1.ToClipbrd(StrValue: string);
    var
    A: array[0..255] of char;
    begin
    StrPCopy(A, StrValue);
    Clipboard.SetTextBuf(A);
    end;
    procedure TForm1.FormCreate(Sender: TObject);
    begin
      if not (csDesigning in ComponentState) then
      RegisterHotkey(handle,IDHOT_SNAPWINDOW,MOD_CONTROL + MOD_SHIFT,VK_F12);
      end;
      end.
smid en tmemo ind, og så sku det virke...gør det det hos jer?

denne kode fandt jeg via http://www.d-tnt.co.uk/forum/default.asp?ReadMessage=YES&ID=10223

somsagt leder jeg efter fejlen i dette styk kode, hvorfor kan den ikke paste online, men kun offline?


wil/

sætter points lidt mere op:-)

Det er sådan set ganske enkelt, det kommer ikke an på offline eller online, men hvilket program du bruger, og internet explorer (eller netscape eller whatever du bruger) napper din genvejstast ctrl+shift+f12. Det samme gør nogle andre programmer (word etc.), men notepad gør ikke, derfor virker det der. Hvis du ændrer din genvej til rent F12, virker det fint:
    RegisterHotkey(handle, IDHOT_SNAPWINDOW, 0,VK_F12);
så kan du jo rode lidt rundt med det til du finder en genvej der virker overalt :)

kan du ikke lige prøve at lave et projekt og teste det hos dig? og se om det virker?
jeg kan ikke få lortet til at spille:-(

jeg kopierede sådan set bare det kode du skrev, smækkede en TMemo på formen... det virkede dog ikke helt, for du er nødt til lige at dobbeltklikke på formen for at få sat formcreate til at virke.... og så ændrede jeg genvejen til
RegisterHotkey(handle, IDHOT_SNAPWINDOW, 0,VK_F12);
Så virkede det... hvis du stadig ikke kan få det til at virke, kan du smide din mailadresse ind, så kan jeg sende projektet.

prøv lige at smid projektet +source over til mig ( wil@asio.dk )

ved ikke lige hvad problemet er, men min vil ikke som jeg vil...

tak

wil/

Sendt!

det var jo helt lækkert, jeg har nu fået noget der virker:-)
points bliver delt ud nu:-)

Mange tak for hjælpen

wil/

no problem :)

rigtig lækkert det endelig virker:-)