Styre sidelayout på rapport vha VBA

Hej Susanne,

Okay, du skal lægge følgede kode i et modul (ikke i en rapport eller en formular, men et modul):
'***** Rapport-definnitioner *****
Type str_DEVMODE
    RGB As String * 94
End Type

Type type_DEVMODE
    strDeviceName As String * 16
    intSpecVersion As Integer
    intDriverVersion As Integer
    intSize As Integer
    intDriverExtra As Integer
    lngFields As Long
    intOrientation As Integer
    intPaperSize As Integer
    intPaperLength As Integer
    intPaperWidth As Integer
    intScale As Integer
    intCopies As Integer
    intDefaultSource As Integer
    intPrintQuality As Integer
    intColor As Integer
    intDuplex As Integer
    intResolution As Integer
    intTTOption As Integer
    intCollate As Integer
    strFormName As String * 16
    lngPad As Long
    lngBits As Long
    lngPW As Long
    lngPH As Long
    lngDFI As Long
    lngDFr As Long
End Type


Herefter lægger du følgede kode på en knap eller lign:

Private Sub cmdUdskriv_Click()
    'On Error Resume Next
    Dim n As Integer
    Dim rpt As Report
    Const DM_PORTRAIT = 1
    Const DM_LANDSCAPE = 2
    Dim DevString As str_DEVMODE
    Dim DM As type_DEVMODE
    Dim strDevModeExtra As String
   
    DoCmd.OpenReport "DinRapport", acViewDesign
    Set rpt = Reports("DinRapport")   
   
    If Not IsNull(rpt.PrtDevMode) Then
        strDevModeExtra = rpt.PrtDevMode
        DevString.RGB = strDevModeExtra
        LSet DM = DevString
        DM.lngFields = DM.lngFields Or _
        DM.intOrientation    ' Initialize fields.
       
        DM.intOrientation = DM_LANDSCAPE 'her sætter du orientation

        Debug.Print DM.strDeviceName
        LSet DevString = DM            ' Update property.
        Mid(strDevModeExtra, 1, 94) = DevString.RGB
        rpt.PrtDevMode = strDevModeExtra
    End If

    DoCmd.RunCommand acCmdSave
    DoCmd.OpenReport rpt.Name, acViewPreview

End Sub

Objektet DM styrer det hele.

Mht valg af printer, så er den lidt speciel.
DM.strDeviceName giver dig den aktuelle printer, men det er 32 bit kode, som f.eks. kan se således ud: "??????4??‰???  "
Derfor er du nødt til manuelt at skifte printer og så aflæse DM.strDeviceName og gemme det i en constant, således at du derefte kan bruge denne konstant til at skifte mellem printerne.

/Thomas

PS: Det var faktisk dig selv, der bragte mig på sporet da du omtalte prtMip. Så var det bare at side og bladre lidt frem og tilbage i hjælpen. Men jeg skulle stadig selv lige regne den med Printeren ud og i det hele taget var forklaringen i hjælpen meget sparsom.

btw Dim N as Integer kan du godt fjerne....den er blot en rest fra et forsøg.

>whoa hold your horses for en kode G****

ok prøver lige at implementere :)

>thomas
simpelthen smukt arbejde :o)

Virker perfekt på diverse printere.

- takker for din hjælp..... :)

mhh egentlig utroligt alle de ting man kan finde en løsning på hvis man har kendskab nok til programmering :)

ja...som udgangspunkt kan man jo alt!
I praksis er der faktisk kun få ting, man IKKE kan.

Det er jo vidunderligt :o)