Indsæt datoer automatisk

Hej Jens

Jo... Næsten automatisk

Jeg har lavet en funktion, du kan paste ind i din database.

Den kaldes på flg. måde:

YearAdd 2000, \"tblTabel\", \"fldDato\"

2000 er det år du vil fylde tabellen med datoer fra.

tblTabel er navnet på den tabel du vil fylde

fldDato er navnet på det felt du vil skrive datoen i. (Feltet skal være et dato felt).

--- Kode Start ---

Public Function YearAdd(nYear As Integer, strTabel As String, strField As String)
   
    Dim rstYear As Recordset
    Dim dtDate As Date
    Dim dtStart As Date
    Dim dtEnd As Date
   
    Set rstYear = CurrentDb.OpenRecordset(strTabel)
    dtStart = DateSerial(nYear, 1, 1)
    dtEnd = DateSerial(nYear, 12, 31)
       
    For dtDate = dtStart To dtEnd
        rstYear.AddNew
        rstYear(strField) = dtDate
        rstYear.Update
    Next dtDate
         
End Function

--- Kode Slut ---

Håber at ovenstående løser dit problem, ellers skriv igen.

Med venlig hilsen

LKP

Hej Ikp

Nu er jeg ikke den store haj til Access - hvor skal jeg paste denne kode henne ?

Bare et lille tillægsspørgsmål - kunne man lave din kode sådan at den kun lagde datoer ind i arbejdsdage ? - altså ikke lørdag og søndag.

Hilsen
Jens

Hej Jens

Koden kan laves så den kun tager arbejdsdage med. Se koden nedenfor.

Den nye funktion kaldes på flg måde:

YearAdd2 2000, true ,\"tblTest\",\"Dato\"

Stort set det samme som før, dog angiver true at du kun vil tilføje arbejdsdage, hvis du vil have alle dage med, skal du istedet skrive false.

For at benytte koden, skal du oprette et nyt modul og kopiere koden ind i dette.

Når du skal eksekvere koden kan du enten ligge koden bag f.eks. en knap på en form, eller du kan trykke ctrl+g for at få imediate vinduet frem. Her skriver du linjen YearAdd2 2000... osv., og trykke enter.

--- Kode Start ---

Public Function YearAdd2(nYear As Integer, blWorkWeek As Boolean, strTabel As String, strField As String)
   
    Dim rstYear As Recordset
    Dim dtDate As Date
    Dim dtStart As Date
    Dim dtEnd As Date
   
    Set rstYear = CurrentDb.OpenRecordset(strTabel)
    dtStart = DateSerial(nYear, 1, 1)
    dtEnd = DateSerial(nYear, 12, 31)
       
    For dtDate = dtStart To dtEnd
        If (Weekday(dtDate) <> vbSaturday And Weekday(dtDate) <> vbSunday) Or blWorkWeek = False Then
            rstYear.AddNew
            rstYear(strField) = dtDate
            rstYear.Update
        End If
    Next dtDate
         
End Function

--- Kode Slut ---

Håber at ovenstående hjælper dig videre, ellers skriv igen.

Med venlig hilsen

LKP

Håber at ovenstående

Hej LKP

Tak for hjælpen :-)

Hilsen
Jens