Avatar billede jens Nybegynder
18. juli 1999 - 14:19 Der er 13 kommentarer og
1 løsning

Insert into probs. mangeler lidt starthjælp

Hej !

Er der en hjælpsom sjæl der kan give mig en Skabelon/noget kode

- det drejer sig faktisk bare om noget kode ( SQL="INSERT INTO artikler (dato, forfatter, overskrift, indhold, osv... )
der sætter data fra en form ind i en DB,, lidt banalt, men jeg har  rodet længe med det uden held :-(

Det skal gerne være noget med en conneting til DB som sådan her:

set conn = server.createobject("ADODB.connection")
path = Server.MapPath("database.mdb")
conn.Open "DBQ="& path &";DefaultDir="& path & ";Driver={Microsoft Access Driver (*.mdb)}"

Hvis du kan forsyne mig med både form-kode og asp kode så vil jeg være dig meget taknemlig....

Håber du kan hjælpe mig, da jeg er ved at være træt af det som jeg forsøgt mig med hele dagen ( giver hele tiden fejl, så nu vil jeg gerne prøve forfra )


På forhånd tak :-)

Du må gerne sende på følgende mail jensk@post1.tele.dk - og poste her i eksperten.....

MVH
Jens




Avatar billede boomer Nybegynder
18. juli 1999 - 14:34 #1
Hele 30 point for en relativ stor mængde kode??

WOW!
Avatar billede 127144146281 Nybegynder
18. juli 1999 - 14:38 #2
Skal det være med INSERT INTO, for der er nemlig også en anden måde at gøre det på (nemere)
Avatar billede jens Nybegynder
18. juli 1999 - 14:41 #3
30 point 60 point eller 3000 point er for mig lige meget boomer, skal du have mere så sig til.....

- Jens
Avatar billede jens Nybegynder
18. juli 1999 - 14:42 #4
Hej 127144146281


Nej det skal ikke nødvendigvis være med insert into, hvis der findes en nemmer måde så er jeg med på den - så passer det også bedre til de 30 point ;-)

Tak for hurtig svar .-)

Jens
Avatar billede 127144146281 Nybegynder
18. juli 1999 - 14:51 #5
Jeg har ikke tid til at lave det til specielt dit formål, men her er noget kode jeg selv bruger (Skule være let at rette til)


<%@ Language=VBScript %>
<%
    '---- CursorTypeEnum Values ----
    Const adOpenForwardOnly = 0
    Const adOpenKeyset = 1
    Const adOpenDynamic = 2
    Const adOpenStatic = 3
       
    '---- LockTypeEnum Values ----
    Const adLockReadOnly = 1
    Const adLockPessimistic = 2
    Const adLockOptimistic = 3
    Const adLockBatchOptimistic = 4

    '---- CommandTypeEnum Values ----
    Const adCmdUnknown = &H0008
    Const adCmdText = &H0001
    Const adCmdTable = &H0002
    Const adCmdStoredProc = &H0004
    Const adCmdFile = &H0100
    Const adCmdTableDirect = &H0200

    '---- Connection to Database ----
    Dim DB_CONNECTIONSTRING
    DB_CONNECTIONSTRING = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Server.Mappath("127144146281_members_1271444146281.mdb") & ";"
   
    '***************************************
    '******* Get data from request *********
    '***************************************
    Dim Member_Name, Show_Member_Details, Member_Homepage, Member_Email
    Dim Member_Message, Member_Real_Name, Member_ICQ, boolShow_Member_Details

    Member_Name = Request.Form("brugernavn")
    Show_Member_Details = Request.Form("show_detail")
    Member_Homepage = Request.Form("hp")
    Member_Email = Request.Form("email")
    Member_Message = Request.Form("beskrivelse")
    Member_Real_Name = Request.Form("realnavn")
    Member_ICQ = Request.Form("icq")
   
    If Show_Member_Details = "" Then
    boolShow_Member_Details = False
    Else
    boolShow_Member_Details = True
    End If
    If Member_Homepage = "" Then : Member_Homepage = "Ingen" : End If
    If Member_ICQ = "" Then : Member_ICQ = "Ingen" : End If
    If Member_Message = "" Then : Member_Message = ":-)" : End If
    '***************************************
    '***** Get data from request End *******
    '***************************************
    If Member_Name = "" Then
    Response.Redirect "members_add.asp"
    Response.End
    End If
   
    If Member_Email = "" Then
    Response.Redirect "members_add.asp"
    Response.End
    End If
   
    If Member_Real_Name = "" Then
    Response.Redirect "members_add.asp"
    Response.End
    End If
   
        Dim Recordset
        Set Recordset = Server.CreateObject("ADODB.Recordset")
        Recordset.Open "Members", DB_CONNECTIONSTRING, adOpenStatic, adLockPessimistic, adCmdTable
       
        Recordset.AddNew
        Recordset.Fields("Member_Name") = CStr(Member_Name)
        Recordset.Fields("Show_Member_Details") = boolShow_Member_Details
        Recordset.Fields("Member_Homepage") = CStr(Member_Homepage)
        Recordset.Fields("Member_Email") = CStr(Member_Email)
        Recordset.Fields("Member_Password") = CStr(StrPassword)  '//Lav random rutine her!
        Recordset.Fields("Member_Message") = CStr(Member_Message)
        Recordset.Fields("Member_Level") = CStr("Almindelig Medlem")
        Recordset.Fields("Member_Real_Name") = CStr(Member_Real_Name)
        Recordset.Fields("Member_ICQ") = CStr(Member_ICQ)
        Recordset.Update
   
        Recordset.Close
        Set Recordset = Nothing       
       
%>
Avatar billede 127144146281 Nybegynder
18. juli 1999 - 14:54 #6
Jeg har dog fjernet lidt ASP kode som ikke er nødvendigt i dit tilfælde i ASP scriptet ovenover

Og selve HTML siden man skal udfylde;


<%@ Language=VBScript %>
<HTML>
<HEAD>
<META NAME="GENERATOR" Content="Microsoft Visual Studio 6.0">
</HEAD>
<BODY>
<P align=center><FONT face=Arial size=6><U>..:: Tilføj Bruger ::..</U></FONT></P>
<P align=center><FONT face=Arial>Husk
at udfylde alle de felter du kan! (besked dog undtaget)<BR><BR></FONT></P>


<form action="members_add_new_user.asp" METHOD="POST" id=form1 name=form1>
<TABLE align=center border=1 cellPadding=1 cellSpacing=1 width="75%">
    <TR>
        <TD width=150><FONT face=Arial>Bruger Navn: <BR></FONT></TD>
        <TD><FONT face=Arial><input name="brugernavn" size="50" maxlength="15">&nbsp;<FONT
      color=#ff3300 size=4><STRONG>¤</STRONG></FONT></FONT></TD>
    </TR>
    <TR>
        <TD width=150><FONT face=Arial>Rigtigt Navn: <BR></FONT></TD>
        <TD><FONT face=Arial><input name="realnavn" size="50" maxlength="150">&nbsp;<FONT
      color=#ff3300 size=4><STRONG>¤ </STRONG></FONT> *</FONT></TD>
    </TR>
        <TR>
            <TD width=150><FONT face=Arial>Hjemmeside: <BR></FONT></TD>
            <TD><FONT face=Arial><input name="hp" size="50" maxlength="200"> *</FONT></TD>
        </TR>
        <TR>
            <TD width=150><FONT face=Arial>Email: <BR></FONT></TD>
            <TD><FONT face=Arial><input name="email" size="50" maxlength="50">&nbsp;<FONT
      color=#ff3300 size=4><STRONG>¤</STRONG></FONT> *</FONT></TD>
        </TR>
        <TR>
            <TD width=150><FONT face=Arial>ICQ UIN: <BR></FONT></TD>
            <TD><FONT face=Arial><input name="icq" size="50" maxlength="25"> *</FONT></TD>
        </TR>
    <TR>
        <TD width=150 valign=top><FONT face=Arial>Besked: <BR></FONT></TD>
        <TD><FONT face=Arial><TEXTAREA cols=50 name=beskrivelse rows=8></TEXTAREA></FONT></TD>
    </TR>
    <TR>
        <TD width=150><FONT face=Arial>(Vis felter med * til alle)<BR></FONT></TD>
        <TD><FONT face=Arial><input type="checkbox" name="show_detail" checked>Ja</FONT></TD>
    </TR>
</TABLE>

<br><br>
<P align=center>
<input type="submit" id=submit1 name=submit1 value="Tilføj Bruger">
<input type="reset" value="Start Forfra">
</P>
</form>

<P align=center><FONT face=Arial>Felter med <FONT color=#ff3300 size=4><STRONG>¤
</STRONG></FONT>SKAL Udfyldes (Ellers vil du blive sendt tilbage
hertil)</FONT></P>


</BODY>
</HTML>
Avatar billede 127144146281 Nybegynder
18. juli 1999 - 15:00 #7
Ellers så send databasen til den addresse der står under mit brugernavn, og jeg skal rette den til så det passer, men det kan først blive om ca. en ½ time
Avatar billede jens Nybegynder
18. juli 1999 - 16:22 #8
Hej 127144146281

Ja så har jeg rodet 1/2 time med det,, og du havde ret, den er noget nemmer at rette til - det virker !!

Lige et tillægs-spg. Hvis jeg vil have en dags dato automatisk indsat i DB når brugeren sender formen, kan det så lade sig gøre ??

Men ellers vil jeg da bare sig tak for koden,,, tusind tak :-)))

Hilsen
Jens
Avatar billede jens Nybegynder
18. juli 1999 - 16:24 #9
eehhh !

127144146281 kan du ikke lige give mig et svar ( bare et eller andet ), så jeg kan give dig point !

- Jens
Avatar billede 127144146281 Nybegynder
18. juli 1999 - 16:40 #10
Det er der flere måder man kan gøre på:

1) Lave et felt i DB'en som f.eks hedder dato af typen Tekst (Text), skriv så :

Now()

som standart værdi, og du behøver ikke give den en værdig når du tilføjer ligesom med ID (autonummer)

2) Lave et felt i DB'en som f.eks hedder dato af typen Tekst (Text)
og skriv så:

Recordset.Fields("Dato") = CStr(Now())

Begge dele skulle gerne virke, jeg ville dog bruge den øverste
Avatar billede 127144146281 Nybegynder
18. juli 1999 - 16:40 #11
og nu glemte jeg at svare
Avatar billede jens Nybegynder
18. juli 1999 - 16:45 #12
Du er en knag 12714 osv. ;-)

Jeg har nu fået det prob. at jeg får "kode" gemt som kode i DB'en...

Det er ligemeget hvad jeg skriver i tekstboksen - så står der kode i DB'en,,, er det noget du har oplevet ??

Her er min tilrettede kóde - hvis du da har tid ;-)

<%@ Language=VBScript %>
<%
    '---- CursorTypeEnum Values ----
    Const adOpenForwardOnly = 0
    Const adOpenKeyset = 1
    Const adOpenDynamic = 2
    Const adOpenStatic = 3
       
    '---- LockTypeEnum Values ----
    Const adLockReadOnly = 1
    Const adLockPessimistic = 2
    Const adLockOptimistic = 3
    Const adLockBatchOptimistic = 4

    '---- CommandTypeEnum Values ----
    Const adCmdUnknown = &H0008
    Const adCmdText = &H0001
    Const adCmdTable = &H0002
    Const adCmdStoredProc = &H0004
    Const adCmdFile = &H0100
    Const adCmdTableDirect = &H0200

    '---- Connection to Database ----
    Dim DB_CONNECTIONSTRING
    DB_CONNECTIONSTRING = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Server.Mappath("guside.mdb") & ";"
   
    '***************************************
    '******* Get data from request *********
    '***************************************
    Dim overskrift, mail, tekst, valg
    Dim pris, by, kode, billede
   
    overskrift = Request.Form("overskrift")
    mail = Request.Form("mail")
    tekst = Request.Form("tekst")
    valg = Request.Form("valg")
    pris = Request.Form("pris")
    by = Request.Form("by")
    kode = Request.Form("kode")
    billede = Request.Form("billede")

   
 
  If overskrift = "" Then : overskrift = "Ingen" : End If
  If tekst = "" Then : tekst = "Ingen" : End If
  If pris = "" Then : pris = "Ingen pris, det må være gratis ;-)" : End If
    '***************************************
    '***** Get data from request End *******
    '***************************************
 
   
        Dim Recordset
        Set Recordset = Server.CreateObject("ADODB.Recordset")
        Recordset.Open "gulesider", DB_CONNECTIONSTRING, adOpenStatic, adLockPessimistic, adCmdTable
       
        Recordset.AddNew
        Recordset.Fields("overskrift") = CStr(overskrift)
        Recordset.Fields("mail") = CStr(mail)
        Recordset.Fields("tekst") = CStr(tekst)
        Recordset.Fields("valg") = CStr(valg)
        Recordset.Fields("pris") = CStr(pris) 
        Recordset.Fields("by") = CStr(by)
        Recordset.Fields("kode") = CStr("kode")
        Recordset.Fields("billede") = CStr(billede)
        Recordset.Update
   
        Recordset.Close
        Set Recordset = Nothing       
       
        Response.Redirect "indsat_tak.htm"

       
Tak igen :-)))

- Jens
Avatar billede 127144146281 Nybegynder
18. juli 1999 - 16:51 #13
Du har skrevet :
Recordset.Fields("kode") = CStr("kode")

Prøv med
Recordset.Fields("kode") = CStr(kode)
Avatar billede 127144146281 Nybegynder
18. juli 1999 - 16:55 #14
Det der står øverst kan godt laves lidt om:

Før:
    '---- CursorTypeEnum Values ----
    Const adOpenForwardOnly = 0
    Const adOpenKeyset = 1
    Const adOpenDynamic = 2
    Const adOpenStatic = 3
       
    '---- LockTypeEnum Values ----
    Const adLockReadOnly = 1
    Const adLockPessimistic = 2
    Const adLockOptimistic = 3
    Const adLockBatchOptimistic = 4

    '---- CommandTypeEnum Values ----
    Const adCmdUnknown = &H0008
    Const adCmdText = &H0001
    Const adCmdTable = &H0002
    Const adCmdStoredProc = &H0004
    Const adCmdFile = &H0100
    Const adCmdTableDirect = &H0200


Efter:
    '---- CursorTypeEnum Values ----
    Const adOpenStatic = 3
       
    '---- LockTypeEnum Values ----
    Const adLockPessimistic = 2

    '---- CommandTypeEnum Values ----
    Const adCmdTable = &H0002
Avatar billede Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Loading billede Opret Preview
Kategori
Kurser inden for grundlæggende programmering

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester

IT-JOB

Capgemini Danmark A/S

Principal AI Architect

Collectia A/S

Cyber Security Engineer

Politiets Efterretningstjeneste

DevOps engineer til dataanalyse i PET

Banedanmark

Forretningsanalytiker

Netcompany A/S

IT Consultant