Avatar billede reason Nybegynder
30. juli 1999 - 18:10 Der er 18 kommentarer og
1 løsning

åbning af database

hvad er forskellen på at åbne en database således :

SQL = "SELECT * FROM users WHERE login=ost"
Set RS = DB.Execute(SQL)

og således :

SQL = "SELECT * FROM users WHERE login=ost"
Set RS = Server.CreateObject("ADODB.Recordset")
RS.Open SQL, DB, 3, 3
Avatar billede 127144146281 Nybegynder
30. juli 1999 - 18:20 #1
Den nederst giver flere muligheder for instillinger blandt andet om db skal åbnes som readonly/optimistic/pessimistic, og om det skal åbnes som et keyset/static

Jeg kan tage fejl da det er tager directe fra hukommelsen
Avatar billede reason Nybegynder
30. juli 1999 - 22:53 #2
okey men hvad betyder det? (readonly/optimistic/pessimistic osv.)
Avatar billede s Nybegynder
30. juli 1999 - 23:16 #3
Men hvadpokker er fordelen hved at åbne databasen i readonly? Med mindre der er en MEGET stor fejl i ASP dokumentet kan der jo ikke ske noget ved at åbne den almindeligt.
Avatar billede floffy Nybegynder
30. juli 1999 - 23:21 #4
Når du åbner med den nedeste metode har du mulighed for at navigere cia en "cursor".

Det vil være ideelt ved listningen af "sider" - side 1 og side 2 med hver f.eks. 10 records.

Det giver også mulighed for at opdatere via et record set:

SQL = "SELECT * FROM users WHERE login=ost"
Set RS = Server.CreateObject("ADODB.Recordset")
RS.Open SQL, DB, 1, 3
RS("navn") = request("navn")
RS.Update
RS.Close

i modsætning til øverste metode.
Avatar billede 127144146281 Nybegynder
31. juli 1999 - 00:33 #5
Du kan se en oversigt over hvad de forskeliige ting understøtter på:

http://www.michael-jensen.dk/vis_source.asp?ID=2
Avatar billede reason Nybegynder
31. juli 1999 - 02:12 #6
ok nu er jeg med
Avatar billede hy Nybegynder
01. august 1999 - 10:36 #7
>127144146281
dit link virker ikke ???
Avatar billede 127144146281 Nybegynder
01. august 1999 - 11:05 #8
jo, severen må have været nede
Avatar billede floffy Nybegynder
01. august 1999 - 11:54 #9
127..> Jeg har prøvet mange gange
og jeg får denne fejl hver gang?

error '80072afc'
//global.asa, line 44
Avatar billede reason Nybegynder
01. august 1999 - 12:14 #10
linket virker fint
Avatar billede s Nybegynder
01. august 1999 - 12:29 #11
Linket virker udemærket for mig...
Avatar billede floffy Nybegynder
01. august 1999 - 12:35 #12
Jeg får den hver gang.
Også på http://www.michael-jensen.dk
Både IE50 og NS4.6
Avatar billede reason Nybegynder
01. august 1999 - 13:57 #13
>>127.. køre du noget statistik i global.asa for jeg har før hart et problem med dette script (netcoders.dk)

<! Steffen T. Christensen, 1999 >
<! dolphine@mail.subnet.dk >
<! Dolphine Software >
<! http://dolphine.subnet.dk/ >


<% Set DB = Server.CreateObject("ADODB.Connection")
  DB.ConnectionString = "Driver={Microsoft Access Driver (*.mdb)};" & "DBQ=f:\users\test\www\stat\stat.mdb;" & "DefaultDir=f:\users\test\www\stat\;" & "FIL=MS Access;"
  DB.Open
  SQL = "SELECT * FROM Users;"
  Set RS = Server.CreateObject("ADODB.Recordset")
  RS.Open SQL, DB, 3, 3
    rs.movefirst

        RS.AddNew
        rs("IP") = Request.ServerVariables("REMOTE_ADDR") & " "
        rs("User") = Request.ServerVariables("REMOTE_USER") & " "
        rs("Referer") = Request.ServerVariables("HTTP_REFERER") & " "
        rs("Browser") = Request.ServerVariables("HTTP_USER_AGENT") & " "
        rs("Time") = now
        RS.Update

      Set RS = Nothing
      Set DB = Nothing
%>

hvor folk der brugte image (WOL) og cybercity fik en fejl (det er vist noget cookies elle proxy-server - tro jeg)
Avatar billede s Nybegynder
01. august 1999 - 14:02 #14
Scriptet bruger i hvert fald ikke cookies og så vidt jeg ved skulle en proxy-server da ikke have nogen indvirkning på en database...
Avatar billede reason Nybegynder
01. august 1999 - 14:29 #15
jeg tro faktisk at problemmet ligger i
rs("User") = Request.ServerVariables("REMOTE_USER")
Avatar billede s Nybegynder
01. august 1999 - 14:31 #16
ok... kan tænkes...
Avatar billede 127144146281 Nybegynder
01. august 1999 - 15:30 #17
Ja der er statistik i den (Jeg har lige fjernet lidt af info, så der er ikke nogen der kan hente min DB):

<SCRIPT LANGUAGE="VBScript" RUNAT="Server">

Sub Application_OnStart()

End Sub

Sub Session_OnStart()

Dim Path 'as String
Path = Server.MapPath("Stats.mdb")

If CheckForFile(Path) = True Then
'Connect to database

    '**************************************   
    '*  'Convert IP Address to DNS Name  *
    '**************************************
    Dim ObjDns, StrNam
    'Create Object
    Set ObjDns = Server.CreateObject("Caprock.DNSResolver")
    StrNam = "-"
    'Convert ex: 195.249.81.199 -> ip71.kdnxr2.ras.tele.dk
    StrNam = ObjDns.GetHostNameByAddress(Request.ServerVariables("REMOTE_ADDR"))
    Set ObjDns = Nothing
   
    '**************************************   
    '*  'Session Start                    *
    '**************************************
    Dim StrSessionStart_Time, StrSessionStart_Date
    StrSessionStart_Time = Time()
    StrSessionStart_Date = Date()
   
    If StrSessionStart_Time = "" Then
    StrSessionStart_Time = "-"
    End If
   
    If StrSessionStart_Date = "" Then
    StrSessionStart_Date = "-"
    End If
   
    '**************************************   
    '*  'IP Address                      *
    '**************************************
    Dim StrIPAddress
    StrIPAddress = Request.ServerVariables("REMOTE_ADDR")
   
    If StrIPAddress = "" Then
    StrIPAddress = "-"
    End If

    '**************************************   
    '*  'Browser Info                    *
    '**************************************
    Dim StrBrowserName
    StrBrowserName = Request.ServerVariables("HTTP_USER_AGENT")
   
    If StrBrowserName = "" Then
    StrBrowserName = "-"
    End If
   
    '**************************************   
    '*  'File                            *
    '**************************************
    Dim StrFileName
    StrFileName = Request.ServerVariables("PATH_INFO")

    If StrFileName = "" Then
    StrFileName = "-"
    End If
   
    '**************************************   
    '*  'Referrer                        *
    '**************************************
    Dim StrReferrer
    StrReferrer = Request.ServerVariables("HTTP_REFERER")
   
    If StrReferrer = "" Then
    StrReferrer = "-"
    End IF
   
   
    '---- CursorTypeEnum Values ----
    Const adOpenStatic = 3

    '---- LockTypeEnum Values ----

    Const adLockPessimistic = 2

    '---- CommandTypeEnum Values ----
    Const adCmdTable = &H0002
       
    Dim DB_CONNECTIONSTRING
    DB_CONNECTIONSTRING = "DRIVER={Microsoft Access Driver (*.mdb)};DBQ=" & Path & ";"

    Dim objRecordset
    Set objRecordset = Server.CreateObject("ADODB.Recordset")
    objRecordset.Open "webstats", DB_CONNECTIONSTRING, adOpenStatic, adLockPessimistic, adCmdTable
   
    objRecordset.AddNew
    objRecordset.Fields("SessionStart_Time") = CStr(StrSessionStart_Time)
    objRecordset.Fields("SessionStart_Date") = CStr(StrSessionStart_Date)
    objRecordset.Fields("FileName") = CStr(StrFileName)
    objRecordset.Fields("BrowserName") = CStr(StrBrowserName)
    objRecordset.Fields("IP_Address") = CStr(StrIPAddress)
    objRecordset.Fields("IP_DNS_Name") = CStr(StrNam)
    objRecordset.Fields("Referrer") = CStr(StrReferrer)
    objRecordset.Update

    objRecordset.Close
    Set objRecordset = Nothing

End If

End Sub

Sub Session_OnEnd()
End Sub

Sub Application_OnEnd()
End Sub

Function CheckForFile(Byval FileName)
Set FileSystem = CreateObject("Scripting.FileSystemObject")

    If FileSystem.FileExists(FileName) Then
        CheckForFile = True
    Else
        CheckForFile = False
    End If

Set FileSystem = Nothing
End Function

</SCRIPT>


Avatar billede s Nybegynder
01. august 1999 - 15:44 #18
Hvor har du den komponent fra der hedder Caprock.DNSResolver?
Avatar billede 127144146281 Nybegynder
01. august 1999 - 16:54 #19
Avatar billede Ny bruger Nybegynder

Din løsning...

Tilladte BB-code-tags: [b]fed[/b] [i]kursiv[/i] [u]understreget[/u] Web- og emailadresser omdannes automatisk til links. Der sættes "nofollow" på alle links.

Loading billede Opret Preview
Kategori
Kurser inden for grundlæggende programmering

Log ind eller opret profil

Hov!

For at kunne deltage på Computerworld Eksperten skal du være logget ind.

Det er heldigvis nemt at oprette en bruger: Det tager to minutter og du kan vælge at bruge enten e-mail, Facebook eller Google som login.

Du kan også logge ind via nedenstående tjenester